Поздравление с 8 марта

Dim objADSysInfo
Dim objWShell, strAddress, strCommand
Dim strDomain, strUserDN, strUser
Dim objFS, strSource, strHTML
Const strExclude = "Администратор;Инженер;"
strHTML = "page.html"
On Error Resume Next
Set objADSysInfo = CreateObject("ADSystemInfo")
If Err.Number = 0 Then
    strUserDN = objADSysInfo.UserName
    If Err.Number = 0 Then
        If InStr(1, strUserDN, "OU=Мужики,", vbTextCompare) = 0 Then
            strUser = GetObject("LDAP://" & strUserDN).cn
            If InStr(1, strExclude, strUser & ";", vbTextCompare) = 0 Then
                strDomain = objADSysInfo.DomainDNSName
                If Err.Number = 0 Then
                    strSource = "\\" & strDomain & "\NETLOGON"
                    Set objFS = CreateObject("Scripting.FileSystemObject")
                    If objFS.FolderExists(strSource) Then
                        strAddress = strSource & "\" & strHTML
                        If objFS.FileExists(strAddress) Then
                            If objFS.FileExists("C:\Program Files\Mozilla Firefox\firefox.exe") Then
                                strCommand = """C:\Program Files\Mozilla Firefox\firefox.exe """ & strAddress
                            Else
                                strCommand = "iexplore.exe " & strAddress
                            End If
                            Set objWShell = CreateObject("WScript.Shell")
                            objWShell.Run strCommand, 1, True
                            Set objWShell = Nothing
                            If Err.Number <> 0 Then Err.Clear
                        End If
                    End If
                    Set objFS = Nothing
                Else
                    Err.Clear
                End If
            End If
        End If
    Else
        Err.Clear
    End If
Else
    Err.Clear
End If
Set objADSysInfo = Nothing
WScript.Quit 0