Поиск совпадений в 2х столбцах и добавление пустой строки

Sub Procedure_1()
 
    'Подключите библиотеку:
        'Tools - References... - Microsoft Scripting Runtime.
    
    Dim myDictionary As Scripting.Dictionary
    Dim arrBCD() As Variant
    Dim myLastRow As Long
    Dim i As Long
    
    
    '1. Если что-то вставляем или удаляем на Excel-листе,
        'то нужно обязательно отключить обновление монитора.
        'Это ускорит работу кода.
    Application.ScreenUpdating = False
    
    
    '2. Создаём объект "Dictionary" (далее - словарь) и даём ему VBA-имя "myDictionary".
        'Через это VBA-имя будем обращаться к словарю.
    'Словарь удобно использовать для написания кода,
        'если нужно работать с повторяющимися данными.
    Set myDictionary = CreateObject(Class:="Scripting.Dictionary")
    
    
    '3. Быстрее работать с VBA-массивом, чем с ячейками,
        'поэтому помещаем данные из Excel-ячеек в массив.
    '3.1. Определяем, сколько строк взять в массив.
        'Для этого двигаемся по столбцу "A" до первой пустой ячейки.
        'Двигаемся со второй строки, т.к. в первой строке находится заголовок.
    myLastRow = 2
    Do While IsEmpty(Cells(myLastRow, "A")) = False
        'Переход к следующей строке.
        myLastRow = myLastRow + 1
    Loop
    '3.2.Корректируем данные, т.к. пустая строка нам не нужна.
    myLastRow = myLastRow - 1
    '3.3. Помещаем данные в массив из Excel-листа.
        'Помещу данные из столбцов "B:D", данные
        'из столбца "B" мне не нужны, просто нужен столбец
        'в массиве, в который я буду помещать нужные мне данные.
        'Беру данные с первой строки, чтобы порядковые
        'номера строк массива совпадали с порядковыми номерами
        'строк Excel-листа, чтобы было удобно писать код.
    arrBCD() = Range("B1:D" & myLastRow).Value
    '3.4. Очищаем первый столбец от данных.
    For i = 1 To UBound(arrBCD, 1) Step 1
        arrBCD(i, 1) = Empty
    Next i
    
    
    '4. Помещаю данные из VBA-массива в словарь.
    'Если такие же данные уже будут в словаре, то в
        'первом столбце массива буду делать пометку, что
        'эта строка повторяется.
    For i = 1 To UBound(arrBCD, 1) Step 1
        'Соединяем данные из второго и третьего столбцов.
        'Если такой элемент уже есть в словаре.
        If myDictionary.Exists(arrBCD(i, 2) & arrBCD(i, 3)) = True Then
            '4.1. Делаем пометку в первом столбце массива.
            arrBCD(i, 1) = True
        '4.2. Если такого элемента ещё нет в словаре, то создаём такой элемент.
        Else
            'Item - нам не нужно, но для создания команды "Add" необходимо
                '(такой синтаксис).
            myDictionary.Add Key:=arrBCD(i, 2) & arrBCD(i, 3), Item:=""
        End If
    Next i
    
    
    '5. Словарь нам больше не нужен и очищаем его, чтобы
        'освободить оперативную память (это делать необязательно, т.к.
        'оперативной памяти в современных компьютерах очень много,
        'а после завершения процедуры словарь и так удалится в данном случае).
    myDictionary.RemoveAll
    
    
    '6. Сначала сделаем порядковую нумерацию, чтобы было проще писать код,
        'а затем вставим строки.
    '6.1. Помещаем данные во вторую строку массива.
    arrBCD(2, 1) = 1
    'Двигаемся с третьей строки массива.
    For i = 3 To UBound(arrBCD, 1) Step 1
    
        '6.2. Если в элементе массива "True", то вставляем число "1".
        If arrBCD(i, 1) = True Then
            arrBCD(i, 1) = 1
        '6.3. Если не "True", то продолжаем нумерацию.
        Else
            arrBCD(i, 1) = arrBCD(i - 1, 1) + 1
        End If
        
    Next i
    
    '6.4. Переносим порядковые номера на Excel-листа.
    For i = 2 To UBound(arrBCD, 1) Step 1
        Cells(i, "B").Value = arrBCD(i, 1)
    Next i
    
    
    'Двигаемся по первому столбцу массива "arrBCD"
        'снизу вверх (когда добавляем или удаляем строки на Excel-листе,
        'то удобнее писать код, если добавлять или удалять с конца,
        'т.к. порядковые номера у строк меняются).
    '7. Во второй строке будет число "1", но вставлять строку не надо.
    For i = UBound(arrBCD, 1) To 3 Step -1
        'Если в элементе массива "1".
        If arrBCD(i, 1) = 1 Then
            'Номера строк в VBA-массиве сопвадает с номерами строк
                'на Excel-листе.
            'Вставляем пустую строку на Excel-лист.
            Rows(i + 1).Insert
        End If
    Next i
    
    
    '8. Включаем то, что отключали.
    Application.ScreenUpdating = True
    
End Sub

Sub Procedure_1()
 
    'Подключите библиотеку:
        'Tools - References... - Microsoft Scripting Runtime.
    
    Dim myDictionary As Scripting.Dictionary
    Dim arrCD() As Variant
    Dim arrIndexes() As Variant
    Dim myLastRow As Long
    Dim i As Long
    
    
    '1. Если что-то вставляем или удаляем на Excel-листе,
        'то нужно обязательно отключить обновление монитора.
        'Это ускорит работу кода.
    Application.ScreenUpdating = False
    
    
    '2. Создаём объект "Dictionary" (далее - словарь) и даём ему VBA-имя "myDictionary".
        'Через это VBA-имя будем обращаться к словарю.
    'Словарь удобно использовать для написания кода,
        'если нужно работать с повторяющимися данными.
    Set myDictionary = CreateObject(Class:="Scripting.Dictionary")
    
    
    '3. Быстрее работать с VBA-массивом, чем с ячейками,
        'поэтому помещаем данные из Excel-ячеек в массив.
    '3.1. Определяем, сколько строк взять в массив.
        'Для этого двигаемся по столбцу "A" до первой пустой ячейки.
        'Двигаемся со второй строки, т.к. в первой строке находится заголовок.
    myLastRow = 2
    Do While IsEmpty(Cells(myLastRow, "A")) = False
        'Переход к следующей строке.
        myLastRow = myLastRow + 1
    Loop
    '3.2.Корректируем данные, т.к. пустая строка нам не нужна.
    myLastRow = myLastRow - 1
    '3.3. Помещаем данные в массив из Excel-листа.
        'Помещу данные из столбцов "C:D".
        'Беру данные с первой строки, чтобы порядковые
        'номера строк массива совпадали с порядковыми номерами
        'строк Excel-листа, чтобы было удобно писать код.
    arrCD() = Range("C1:D" & myLastRow).Value
    
    '4. Формиуруем массив, в котором будут порядковые номера
        'и информация, на основе которой будут вставляться пустые строки.
    'В первом столбце будут порядковые номера.
    'Во втором столбце будут отметки: ставить пустую строку или нет.
    ReDim arrIndexes(1 To UBound(arrCD, 1), 1 To 2)
    
    '5. Помещаю данные из VBA-массива в словарь.
    'Если такие данные уже будут в словаре, то во
        'втором столбце массива "arrIndexes" буду делать пометку, что
        'эта строка повторяется.
    For i = 1 To UBound(arrCD, 1) Step 1
        'Соединяем данные из второго и третьего столбцов.
        'Если такой элемент уже есть в словаре.
        If myDictionary.Exists(arrCD(i, 1) & arrCD(i, 2)) = True Then
            '4.1. Делаем пометку в втором столбце массива.
            arrIndexes(i, 2) = True
        '4.2. Если такого элемента ещё нет в словаре, то создаём такой элемент.
        Else
            'Item - нам не нужно, но для создания команды "Add" необходимо
                '(такой синтаксис).
            myDictionary.Add Key:=arrCD(i, 1) & arrCD(i, 2), Item:=""
        End If
    Next i
    
    
    '5. Словарь нам больше не нужен и очищаем его, чтобы
        'освободить оперативную память (это делать необязательно, т.к.
        'оперативной памяти в современных компьютерах очень много,
        'а после завершения процедуры словарь и так удалится в данном случае).
    myDictionary.RemoveAll
    
    
    '6. Сначала сделаем порядковую нумерацию, чтобы было проще писать код,
        'а затем вставим пустые строки.
    '6.1. Чтобы не использовать несколько раз функцию "UBound"
        '(может это ускорит работу кода), поместим данные в
        'переменную "myLastRow". Хотя в переменной "myLastRow"
        'находятся нужные данные, но вдруг код будет дорабатываться
        'и в переменной "myLastRow" будут другие данные.
    myLastRow = UBound(arrCD, 1)
    '6.2. Помещаем данные во вторую строку массива "arrIndexes".
    arrIndexes(2, 1) = 1
    
    'Двигаемся с третьей строки массива.
    i = 3
    
    'Повторяем цикл, пока не просмотрим все строки в массиве.
    Do While i <= myLastRow
    
        'Если в элементе массива "True".
        If arrIndexes(i, 2) = True Then
        
            '6.3. Вставляем число "1" в текущий элемент.
            arrIndexes(i, 1) = 1
            
            '6.4. Вставляем число "1" в следующий элемент.
            'Смотрим снчала, не закончился ли массив.
            '6.4.1. Переходим к следующей строке массива.
            i = i + 1
            '6.4.2. Смотрим, есть ли такая строка в массива.
            If i > myLastRow Then
                'Выходим из цикла.
                Exit Do
            'Если есть такая строка в массиве.
            Else
                arrIndexes(i, 1) = 1
            End If
        
        '6.3. Если не "True", то продолжаем нумерацию.
        Else
            arrIndexes(i, 1) = arrIndexes(i - 1, 1) + 1
        End If
        
        'Переход к следующей строке в массиве.
        i = i + 1
        
    Loop
    
    '6.4. Переносим порядковые номера на Excel-лист.
    For i = 2 To UBound(arrIndexes, 1) Step 1
        Cells(i, "B").Value = arrIndexes(i, 1)
    Next i
    
    
    '7. Вставка пустых строк.
    'Двигаемся по первому столбцу массива "arrCD"
        'снизу вверх (когда добавляем или удаляем строки на Excel-листе,
        'то удобнее писать код, если добавлять или удалять с конца,
        'т.к. порядковые номера у строк меняются).
    'Во второй строке будет число "1", но вставлять строку не надо.
    For i = UBound(arrIndexes, 1) To 3 Step -1
        'Если в элементе массива "1".
        If arrIndexes(i, 2) = True Then
            'Номера строк в VBA-массиве сопвадает с номерами строк
                'на Excel-листе.
            'Вставляем пустую строку на Excel-лист.
            Rows(i + 1).Insert
        End If
    Next i
    
    
    '8. Включаем то, что отключали.
    Application.ScreenUpdating = True
    
End Sub