Сравнение 2 массивов, с последующим выделением в цвета ячеек

Sub Procedure_1()
 
    Dim myF() As Variant, myG() As Variant
    Dim myColors(1 To 10) As Long
    Dim i As Long, j As Long, k As Long
    
    'В массиве "myColors" будут номера цветов.
        'В программе "Excel" есть 56 цветов, которым даны порядковые
        'номера (в справке по запросу "colorindex" можно найти раздел
        '"ColorIndex Property", в которым есть перечень этих цветов).
    'Все подряд цвета не получится использовать, т.к. некоторые цвета
        'повторяются, а некоторые неудобные - чёрный, белый.
    myColors(1) = 3
    myColors(2) = 4
    myColors(3) = 5
    myColors(4) = 6
    myColors(5) = 7
    myColors(6) = 8
    myColors(7) = 9
    myColors(8) = 10
    myColors(9) = 11
    myColors(10) = 12
 
    '1. Быстрее работать с VBA-массивами, чем с ячейками Excel-листа.
    'Поэтому помещаем данные в VBA-массивы.
    'Берём все ячейки - и "F1" - чтобы массив точно соответствовал
        'ячейкам Excel-листа, т.к. нужно будет производить окрашивания ячеек.
    myF() = Range("F1:F35").Value
    myG() = Range("G1:G35").Value
    
    'В цикле с "i" двигаемся по массиву "myF".
    For i = 5 To 35 Step 1
    
        'Если в элементе массива "myF" пусто, то
            'переходим к следующему элементу.
        If myF(i, 1) = Empty Then
            GoTo metka_1
        End If
        
        'В цикле с "j" двигаемся по массиву "myG".
        For j = 5 To 35 Step 1
        
            'Если в элементе массива "myG" пусто, то
                'переходим к следующему элементу.
            If myG(j, 1) = Empty Then
                GoTo metka_2
            End If
            
            '3. Смотрим, на сколько число в массиве "myG"
                'отличается от числа в массиве "myF".
            'За 100% принимается число в массиве "myF".
            'myG(j) / myF(i) - находим, сколько процентов
                'составляет число из массива "myG" в массиве "myF"
                '(без умножения на 100).
            '-1 - находим разницу по процентам между двумя числами.
            'Abs - используется, т.к. число в массиве "myG"
                'может быть и меньше и больше числа в массиве "myF".
            If Abs(myG(j, 1) / myF(i, 1) - 1) <= 0.01 Then
            
                'Переменная "k" используется для выбора цвета.
                k = k + 1
                
                '4. Окрашиваем ячейки.
                'Позиции чисел в массивах "myF" и "myG" совпадают
                    'с позициями ячеек на Excel-листе.
                Cells(i, "F").Interior.ColorIndex = myColors(k)
                Cells(j, "G").Interior.ColorIndex = myColors(k)
                
                '5. Обнуляем значение в массиве "myG", чтобы
                    'это число больше не учитывалось.
                myG(j, 1) = Empty
                
                '6. Выходим из просмотра массива "myG",
                    'чтобы перейти к следующему элементу в массиве "myF".
                Exit For
                
            End If
        
metka_2:
        
        Next j
        
metka_1:
 
    Next i
 
End Sub