Word: объединение ячеек таблицы

@hexadecimal · Регистрация: 04.01.2013

Author24 — интернет-сервис помощи студентам

С помощью макроса добавляю таблицу в TextBox на страницу.
Дальше пытаюсь объединить ячейки.
В столбцах отличных от первого ячейки объединяются. В первом столбце появляется ошибка "Запрашиваемый номер семейства не существует"

Макрос

Visual Basic

Sub Макрос11()
'
' Макрос11 Макрос
'
'
     ' Shape
     Dim shp As Shape
     ' Добавляем текстовое поле
     Set shp = ActiveDocument.Shapes.AddShape(1, _
                                    MillimetersToPoints(20), _
                                    MillimetersToPoints(25), _
                                    MillimetersToPoints(100), _
                                    MillimetersToPoints(45))
     
    ' Таблица
    Dim tbl As Table
    Dim rng As Range
    
    ' Range тектосвого поля
    Set rng = shp.TextFrame.TextRange
    ' Добавляем таблицу
    Set tbl = ActiveDocument.Tables.Add(Range:=rng, _
                                        NumRows:=4, _
                                        NumColumns:=8)
    ' Range для ячеек таблицы
    Dim rngTbl As Range
    
    ' Выделяем. Объединяем
    ' 4 столбец. 2+3 ячейки
    Set rngTbl = tbl.Cell(2, 4).Range
    rngTbl.End = tbl.Cell(3, 4).Range.End
    rngTbl.Cells.Merge
    ' 3 столбец. 2+3 ячейки
    Set rngTbl = tbl.Cell(2, 3).Range
    rngTbl.End = tbl.Cell(3, 3).Range.End
    rngTbl.Cells.Merge
    ' 2 столбец. 2+3 ячейки
    Set rngTbl = tbl.Cell(2, 2).Range
    rngTbl.End = tbl.Cell(3, 2).Range.End
    rngTbl.Cells.Merge
    ' 1 столбец. 2+3 ячейки
    Set rngTbl = tbl.Cell(2, 1).Range
    rngTbl.End = tbl.Cell(3, 1).Range.End
    rngTbl.Cells.Merge ' !!!!ОШИБКА!!!! "Run-time error 5941. Запрашиваемый номер семейства не существует"
     
End Sub

Подскажите, в чем ошибка.

Добавлено через 53 минуты
Такой вариант работает.
Выделение происходит правильно.
Только ошибка все равно непонятная.

Visual Basic

Set rngTbl = tbl.Cell(2, 1).Range
rngTbl.End = tbl.Cell(3, 1).Range.End
rngTbl.Select
Selection.Cells.Merge

Скрипт · 27.01.2013, 14:50

hexadecimal, ваш код нелогично работает, хотя и работает.

В этом случае:

Visual Basic

1 2	Set rngTbl = tbl.Cell(2, 4).Range rngTbl.End = tbl.Cell(3, 4).Range.End

диапазон "rngTbl" содержит ячейки от второй ячейки в четвёртом столбце до третьей ячейки (включительно) в чётвёртом столбце. Т.е. вы думаете, что работаете с двумя ячейками, а задействуете девять ячеек. Это можно проверить, если узнать количество ячеек с помощью команды:

Visual Basic

1	rngTbl.Cells.Count

Я не буду вникать, в чём ошибка, которая у вас появляется, а предложу свой вариант (код просто показывает принцип):

Кликните здесь для просмотра всего текста

Visual Basic

Sub Procedure_4()
 
    Dim myTextFrame As Word.TextFrame
    Dim myTable As Word.Table
    
    Set myTextFrame = ActiveDocument.Shapes(1).TextFrame
    
    Set myTable = myTextFrame.TextRange.Tables(1)
    
    myTable.Cell(2, 1).Merge MergeTo:=myTable.Cell(3, 1)
    
End Sub

Примечание

В некоторых случаях, когда в таблице есть объединённые ячейки, нельзя обратиться к ячейке по номеру строки и столбца: Cell(2, 1). Нужно что-то другое придумывать.

@hexadecimal · 27.01.2013, 15:03 **[ТС]**

Спасибо. То, что и было нужно

@hexadecimal 6 / 5 / 2 Регистрация: 04.01.2013 Сообщений: 56
	27.01.2013, 15:03 [ТС]	3
	Спасибо. То, что и было нужно 0