Дополнить макрос мигания ячеек с отрицательными значениями

Sub BlinkingCell()
 
   Static intCalls As Integer  ' Счетчик количества миганий
    ' Если ячейка мигала менее 10 раз, то изменим _
    в очередной раз ее цвет
   If intCalls < 10 Then
      intCalls = intCalls + 1
      ' Определение, какой цвет необходимо установить
      If Range("A1").Interior.Color <> RGB(255, 0, 0) Then
         ' Цвет ячейки не красный, так что теперь назначим _
          именно красный цвет
         Range("A1").Interior.Color = RGB(255, 0, 0)
      Else
         ' Назначим ячейке зеленый цвет
         Range("A1").Interior.Color = RGB(0, 255, 0)
      End If
 
      ' Эту процедуру необходимо вызвать через 5 секунд
      Application.OnTime Now + TimeValue("00:00:05"), "BlinkingCell"
   Else
      ' Хватит мигать
      Range("A1").Interior.ColorIndex = xlNone
      intCalls = 0
   End If
End Sub

Sub BlinkingCell()
 
   Static intCalls As Integer  ' Счетчик количества миганий
   Static r As Range, c As Range
   If r Is Nothing Then
      For Each c In Selection
        If c < 0 Then
          If r Is Nothing Then Set r = c Else Set r = Union(r, c)
        End If
      Next
      If r Is Nothing Then
        MsgBox "В выделенном диапазоне нет отрицательных чисел!", vbExclamation
        Exit Sub
      End If
    End If
    ' Если ячейка мигала менее 10 раз, то изменим _
    в очередной раз ее цвет
   If intCalls < 10 Then
      intCalls = intCalls + 1
      ' Определение, какой цвет необходимо установить
      If r.Interior.Color <> vbRed Then
         ' Цвет ячейки не красный, так что теперь назначим _
          именно красный цвет
         r.Interior.Color = vbRed
      Else
         ' Назначим ячейке зеленый цвет
         r.Interior.Color = vbGreen
      End If
 
      ' Эту процедуру необходимо вызвать через 5 секунд
      Application.OnTime Now + TimeValue("00:00:05"), "BlinkingCell"
   Else
      ' Хватит мигать
      r.Interior.ColorIndex = xlNone
      intCalls = 0
      Set r = Nothing
   End If
End Sub

Sub BlinkingCell()
 
   Static intCalls As Integer  ' Счетчик количества миганий
   Static r As Range, c As Range
   If intCalls = 0 Then
      For Each c In Selection
        If c < 0 Then
          If r Is Nothing Then Set r = c Else Set r = Union(r, c)
        End If
      Next
      If r Is Nothing Then
        MsgBox "В выделенном диапазоне нет отрицательных чисел!", vbExclamation
        Exit Sub
      End If
    End If
    ' Если ячейка мигала менее 10 раз, то изменим _
    в очередной раз ее цвет
   If intCalls < 10 Then
      intCalls = intCalls + 1
      ' Определение, какой цвет необходимо установить
      r.Interior.Color = IIf(intCalls Mod 2, vbRed, vbGreen)
 
      ' Эту процедуру необходимо вызвать через 5 секунд
      Application.OnTime Now + #12:00:05 AM#, "BlinkingCell" 'вводить #0:0:5#
   Else
      ' Хватит мигать
      r.Interior.ColorIndex = xlNone
      intCalls = 0
   End If
End Sub