Excel VBA макрос, добавляющий записи к таблице через Inputbox

Sub Procedure1()
 
    'Создаём на пластинке оперативной памяти поименованную область - переменную.
    'Long означает, что в переменной могут быть только целые числа (есть ещё дробные).
    Dim lLastRow As Long
    'String означает, что в переменной может быть только текст.
    Dim sResponse As String
    Dim i As Long
    
    'Определяем последнюю заполненную строку на листе,
    'чтобы знать, куда заносить очередные данные.
    
    'Rows.Count - это количество строк на листе.
    'End(xlUp) - это то же самое, что нажать в Excel сочетание клавиш
    'Ctrl + стрелка вверх, что означает переход к первой заполненной ячейке.
    'С помощью Row берём номер строки, первой заполненной ячейки.
    
    'Т.е. следующий код вручную через Excel делается так:
    'делаете активной ячейку в последней строке листа в столбце "A"
    '(последняя строка на листе 65000 или 1000000) и нажимаете
    'сочетание клавиш Ctrl + стрелка вверх. Затем читает номер строки,
    'куда перешла рамка выделения.
    lLastRow = Cells(Rows.Count, "A").End(xlUp).Row + 1
    
    'Вводим на активный лист Excel данные.
    
    'For ... To ... Step ... Next - называется циклом и используется,
    'чтобы делать одно и то же действие заданное количество раз.
    'В нашем случае - это 5 раз.
    
    For i = 1 To 5 Step 1
    
        'С помощью InputBox помещаем в переменную sResponse данные.
        'Если пользователь нажмёт в InputBox "Cancel" или крестик, то в переменную
        'поместится текст: "" (пустая строка), что будет сигналом,
        'что нужно завершить цикл.
        sResponse = InputBox("Введите Товар")
        
        'If ... Then ... End If - используется для выбора действия.
        If sResponse = "" Then
            'Выходим из цикла.
            Exit For
        End If
        
        Cells(lLastRow, "A").Value = sResponse
        
        sResponse = InputBox("Введите Количество")
        If sResponse = "" Then
            Exit For
        End If
        Cells(lLastRow, "B").Value = sResponse
        
        sResponse = InputBox("Введите Цену")
        If sResponse = "" Then
            Exit For
        End If
        Cells(lLastRow, "C").Value = sResponse
        
        'Четвёртный столбец подсчитаем с помощью кода.
        Cells(lLastRow, "D").Value = Cells(lLastRow, "B").Value * Cells(lLastRow, "C").Value
        
        'Чтобы записывать данные в следующую пустую строку.
        lLastRow = lLastRow + 1
    Next
 
    'Сообщение, что работа кода завершена.
    MsgBox "Работа кода завершена!", vbInformation
    
End Sub

Sub Procedure2()
 
    'Переменная oBook - это имя, которое будет даваться книгам
    'во время выполнения кода. Через это имя будем манипулировать листами.
    Dim oBook As Excel.Workbook
 
    'For ... Each ... In ... Next - это цикл для просмотра всех одинаковых элементов.
    'В нашем случае одинаковыми элементами будут книги.
    For Each oBook In Workbooks
 
        'Чтобы не заносить данные в личную книгу макросов.
        
        'LCase - используется, чтобы переводить текст в маленькие буквы,
        'чтобы можно было сравнивать два текста. Т.к. по умолчанию
        'учитывается регистр текста.
        
        'С помощью InStr - определяем, есть ли в начале имени файла
        'слово "personal".
        
        If InStr(LCase(oBook.Name), "personal") <> 1 Then
            oBook.Worksheets(2).Range("A5").Value = oBook.Name
        End If
    Next oBook
 
End Sub