Копирование строки из одной книги в другую

@nt_dmn · Регистрация: 28.04.2011

Author24 — интернет-сервис помощи студентам

Необходимо скопировать строку под номером 10 с активного листа активной книги, открыть книгу например С:\test.xls (с одним листом) и вставить скопированные данные в 5 строку.
Помогите пожалуйста. Темы о копировании строк на форуме нашел, но не разобрался что к чему.
Заранее благодарен.

Памирыч · 05.10.2011, 18:38

Visual Basic

Dim I As Integer
For I = 1 To 20
Cells(5, I).Value = Cells(10, I).Value
Next I

Но это уже совсем по-самодельному

Хотя мне это нравится больше, чем

Visual Basic

Rows("10:10").Copy
Rows("5:5").Select
    ActiveSheet.Paste
Application.CutCopyMode = False

@nt_dmn · 05.10.2011, 18:43 **[ТС]**

я делал очень похоже, но на строку

Visual Basic

1	ActiveSheet.Paste

ругается, в чем причина не пойму...

Памирыч · 05.10.2011, 18:45

Visual Basic

1	Rows("5:5").Select

Это присутствует?

@nt_dmn · 05.10.2011, 18:48 **[ТС]**

Присутствует, а ругается потому что нечего вставлять, значит не копирует оператор

Visual Basic

1	Rows("10:10").Copy

, может перед ним тоже поставить

Visual Basic

1	Rows("10:10").Select

Добавлено через 1 минуту
Выделило, но опять ничего не скопировало, буфер пустой

Памирыч · 05.10.2011, 18:51

Прикрепил книгу

@nt_dmn · 06.10.2011, 10:23 **[ТС]**

В книге вижу что работает, а у меня почему то нет, ладно... утро вечера мудренее

Спасибо за посильную помощь, завтра далее ковырять буду

Добавлено через 15 часов 18 минут
Вот собственно кусок кода:

Visual Basic

'открываем книгу
Workbooks.Open(incoming)
'копируем строку
        Rows("10:10").Select
        Rows("10:10").Copy
        'открываем сводный отчет
        Workbooks.Open (report)
        'выбираем номер начальной строки для поиска последней записи
        nss = 2
        'ищем последнюю запись
        Do While nss <> "1"
            If Range("B" & nss).Value <> "" Then
                'увеличиваем номер строки на 1
                nss = nss + 1
            Else
                'вставляем строку из буфера
                Rows("5:5").Select
                ActiveSheet.Paste
                'присваиваем переменной номера строки значение конца цикла
                nss = 1
            End If
        Loop

Для этого поста я присвоил статичную величину при вставке (5 строка), а вообще надо вставлять в строку nss.
В чем моя ошибка может быть?

@~~Busine2009~~ · 06.10.2011, 15:43

Visual Basic

Sub Процедура1()
'Обращаться с книгами будем через переменные
'(кода меньше писать и не промахнёшься мимо нужной книги)
Dim Исходная As Excel.Workbook, Конечная As Excel.Workbook
Dim nss As Long
Set Исходная = ActiveWorkbook
'открываем книгу
Set Конечная = Workbooks.Open("C:\Documents and Settings\Пользователь\Рабочий стол\Книга2.xlsx")
'копируем строку
        Исходная.Worksheets(1).Rows("10:10").Copy
        'выбираем номер начальной строки для поиска последней записи
        nss = 2
        'ищем последнюю запись
        Do While Конечная.Worksheets(1).Range("B" & nss).Value <> ""
            'увеличиваем номер строки на 1
            nss = nss + 1
        Loop
        'вставляем строку из буфера
        Конечная.Worksheets(1).Rows(nss).PasteSpecial
        Конечная.Close SaveChanges:=True
End Sub

@nt_dmn · 06.10.2011, 16:11 **[ТС]**

Так работает, спасибо!

Добавлено через 24 минуты
А ещё нюансик один остался... как добиться что бы происходило копирование только значений, а формулы не копировались в новый документ?

@~~Busine2009~~ · 06.10.2011, 16:17

Visual Basic

1	Конечная.Worksheets(1).Rows(nss).PasteSpecial Paste:=xlPasteValuesAndNumberFormats

С помощью макрорекордера можно узнавать синтаксис VBA.

@nt_dmn · 06.10.2011, 16:48 **[ТС]**

Спасибо огромное, я просто не спец, сижу разбираюсь, второй день как с vba связался

Добавлено через 23 минуты

Сообщение от Busine2009

С помощью макрорекордера можно узнавать синтаксис VBA.

...а что такое макрорекодер?

@~~Busine2009~~ · 06.10.2011, 17:01

nt_dmn,
Excel какого года у вас?

@nt_dmn · 06.10.2011, 17:04 **[ТС]**

Сейчас в 2007 сижу...
А не подскажете ещё где мне отключить оповещение при закрытии файлов "в буфере обмена осталось.. бла бла бла" Чет все настройки перерыл, нету...

@~~Busine2009~~ · 06.10.2011, 17:16

Сообщение от nt_dmn

...а что такое макрорекодер?

Круглая кнопка - Параметры Excel - Основные - Показывать вкладку "Разработчик на ленте" - OK;
вкладка Разработчик - группа Код - Запись макроса;
проделайте какие-нибудь действия (например, введите букву А и нажмите клавишу Enter);
группа Код - Остановить запись;
в VBA будет код, который надо подкорректировать.

Сообщение от nt_dmn

А не подскажете ещё где мне отключить оповещение при закрытии файлов "в буфере обмена осталось.. бла бла бла" Чет все настройки перерыл, нету...

не знаю, можно это сделать с помощью интерфейса программы Excel, а программно вот так делается:
эту строку поместите перед закрытием книги:

Visual Basic

1	Application.DisplayAlerts = False

а эту после закрытия книги:

Visual Basic

1	Application.DisplayAlerts = True

@nt_dmn · 06.10.2011, 17:32 **[ТС]**

Спасибо, со всем разобрался

позавчера из познаний у меня был только бэйсик ук нц со школьной программы, за 2 дня уже в vba начал вникать

@gera_vip · 13.06.2014, 15:35

Форумчане, подскажите, пожалуйста, как в 12 строчке кода, вместо Rows("10:10") указать копировать заполненный диапазон, начиная от второй строчки и до конца, где есть записи.
И есть ли возможность, этот макрос привязать к какой-то новой кнопке на ленте? А то с этим еще не разбирался.
Заранее спасибо!

Visual Basic

Sub Процедура1()
'Обращаться с книгами будем через переменные
'(кода меньше писать и не промахнёшься мимо нужной книги)
Dim Исходная As Excel.Workbook, Конечная As Excel.Workbook
Dim nss As Long
Set Исходная = ActiveWorkbook
'открываем книгу
Set Конечная = Workbooks.Open("C:\Documents and Settings\Пользователь\Рабочий стол\Книга2.xlsx")
'копируем строку 
'Вот тут :)
Исходная.Worksheets(1).Rows("10:10").Copy
        'выбираем номер начальной строки для поиска последней записи
        nss = 2
        'ищем последнюю запись
        Do While Конечная.Worksheets(1).Range("B" & nss).Value <> ""
            'увеличиваем номер строки на 1
            nss = nss + 1
        Loop
        'вставляем строку из буфера
        Конечная.Worksheets(1).Rows(nss).PasteSpecial
        Конечная.Close SaveChanges:=True
End Sub

@Hugo121 · 13.06.2014, 16:09

Попробуйте так (не проверял):

Visual Basic

Sub Процедура1()
'Обращаться с книгами будем через переменные
'(кода меньше писать и не промахнёшься мимо нужной книги)
    Dim Исходная As Excel.Workbook, Конечная As Excel.Workbook
    Set Исходная = ActiveWorkbook
    'открываем книгу
    Set Конечная = Workbooks.Open("C:\Documents and Settings\Пользователь\Рабочий стол\Книга2.xlsx")
    'копируем строку
    'Вот тут :)
    Исходная.Worksheets(1).Range("B2").CurrentRegion.Copy Конечная.Worksheets(1).Cells(Rows.Count, "B").End(xlUp)(2, 0)
    Конечная.Close SaveChanges:=True
End Sub

@gera_vip · 13.06.2014, 16:19

Hugo, а что поменять, чтобы копировались не все данные, а начиная со второй строки и до конца, т.к. в первой строке идут названия столбцов?

@Hugo121 · 13.06.2014, 16:50

Visual Basic

1	Исходная.Worksheets(1).Range("B2").CurrentRegion.Offset(1).Copy Конечная.Worksheets(1).Cells(Rows.Count, "B").End(xlUp)(2, 0)

Будет правда ещё снизу одну пустую строку прихватывать - но это ведь ерунда. Можно убрать ресайсом, но лень.

@gera_vip · 13.06.2014, 18:16

Hugo, огромнейшая благодарность!!! Работает!

@nt_dmn 0 / 0 / 0 Регистрация: 28.04.2011 Сообщений: 60
		1
	Копирование строки из одной книги в другую 05.10.2011, 17:50. Показов 62790. Ответов 19 Метки нет (Все метки) Необходимо скопировать строку под номером 10 с активного листа активной книги, открыть книгу например С:\test.xls (с одним листом) и вставить скопированные данные в 5 строку. Помогите пожалуйста. Темы о копировании строк на форуме нашел, но не разобрался что к чему. Заранее благодарен. 0

@nt_dmn 0 / 0 / 0 Регистрация: 28.04.2011 Сообщений: 60
	06.10.2011, 16:11 [ТС]	9
	Так работает, спасибо! Добавлено через 24 минуты А ещё нюансик один остался... как добиться что бы происходило копирование только значений, а формулы не копировались в новый документ? 0

@nt_dmn 0 / 0 / 0 Регистрация: 28.04.2011 Сообщений: 60
	06.10.2011, 16:48 [ТС]	11
	Спасибо огромное, я просто не спец, сижу разбираюсь, второй день как с vba связался Добавлено через 23 минуты Сообщение от Busine2009 С помощью макрорекордера можно узнавать синтаксис VBA. ...а что такое макрорекодер? 0

@~~Busine2009~~ Заблокирован
	06.10.2011, 17:01	12
	nt_dmn, Excel какого года у вас? 0

@nt_dmn 0 / 0 / 0 Регистрация: 28.04.2011 Сообщений: 60
	06.10.2011, 17:04 [ТС]	13
	Сейчас в 2007 сижу... А не подскажете ещё где мне отключить оповещение при закрытии файлов "в буфере обмена осталось.. бла бла бла" Чет все настройки перерыл, нету... 0

@nt_dmn 0 / 0 / 0 Регистрация: 28.04.2011 Сообщений: 60
	06.10.2011, 17:32 [ТС]	15
	Спасибо, со всем разобрался позавчера из познаний у меня был только бэйсик ук нц со школьной программы, за 2 дня уже в vba начал вникать 0

@gera_vip 0 / 0 / 0 Регистрация: 13.06.2014 Сообщений: 5
	13.06.2014, 16:19	18
	Hugo, а что поменять, чтобы копировались не все данные, а начиная со второй строки и до конца, т.к. в первой строке идут названия столбцов? 0

@gera_vip 0 / 0 / 0 Регистрация: 13.06.2014 Сообщений: 5
	13.06.2014, 18:16	20
	Hugo, огромнейшая благодарность!!! Работает! 0