Excel VBA: Копирование листа из другой книги

@marty0701 · Регистрация: 20.04.2009

Author24 — интернет-сервис помощи студентам

Снова здравствуйте!
Пытаюсь скопировать лист из одной книги в другую

Visual Basic

Private Sub Load_Click()
    shName As Variant
    
    On Error Resume Next
    
    ZDBFileName = Workbooks("1.xls").Path & "\2.xls"
    shName = Workbooks("1.xls").Worksheets("Z").ZName.Text
    
    Workbooks.Open ZDBFileName
    Workbooks("2.xls").Worksheets(shName).Activate
    Workbooks("2.xls").Worksheets(shName).Copy Before:=Workbooks("1.xls").Worksheets("Z")
End Sub

Копировать то копирует, проблема в том, что необходимо заменить содержимое листа Z из 1.xls, содержимым листа из 2.xls по сути, в данном случае просто создается новый лист с именем shName.
Спасибо за ответы!

Ой мать... Не заметил раздел VBA 2 раза, простите, перенесите тему.

@~~Busine2009~~ · 18.08.2011, 08:43

Код:

Visual Basic

Sub Процедура1()
    Dim ZDBFileName As String
    Dim Лист1 As Excel.Worksheet
    Dim Книга2 As Excel.Workbook
    Dim НомерЛиста As Long
    
    ZDBFileName = Workbooks("1.xls").Path & "\2.xls"
    'Обращаться к листу Z книги 1.xls будем через переменную Лист1
    '(так удобнее и кода меньше писать).
    Set Лист1 = Workbooks("1.xls").Worksheets("Z")
    'Определение порядкового номера листа Z в книге 1.xls.
    НомерЛиста = Лист1.Index
    'Обращаться к книге 2.xls будем через переменную Книга2.
    Set Книга2 = Workbooks.Open(Filename:=ZDBFileName)
    'Копирование листа Z из книги 2.xls в книгу 1.xls
    Книга2.Worksheets(Лист1.Name).Copy Before:=Лист1
    'Чтобы не появлялись предупреждающие сообщения об удалении листа.
    Application.DisplayAlerts = False
    'Удаление старого листа Z из книги 1.xls
    Лист1.Delete
    'Чтобы появлялись предупреждающие сообщения тогда,
    'когда они должны появляться.
    Application.DisplayAlerts = True
    'Переименовываем вставленный лист.
    Workbooks("1.xls").Worksheets(НомерЛиста).Name = "Z"
End Sub

@marty0701 · 18.08.2011, 12:50 **[ТС]**

Спасибо, надеялся есть путь проще, но и такой вариант подойдет.

@marty0701 43 / 10 / 1 Регистрация: 20.04.2009 Сообщений: 32
	18.08.2011, 12:50 [ТС]	3
	Спасибо, надеялся есть путь проще, но и такой вариант подойдет. 0