For Each в таблице Ворда

@Ципихович Эндрю · Регистрация: 10.04.2009

Author24 — интернет-сервис помощи студентам

я думал, что эти строки

Visual Basic

For w = 1 To ActiveDocument.Tables.Count
Set oTbl = ActiveDocument.Tables(w)
Set oCell = oTbl.Range.Cells(1)
For Each oCell In ActiveDocument.Tables(w).Range.Cells
oCell.Range.Text = Trim(Left(oCell.Range.Text, Len(oCell.Range.Text) - 2))
Next
Next w

проходят по всем ячейкам таблицы, увы заглядывают только в 1 ячейку, как подправить???
Не люблю эти For Each

@~~Busine2009~~ · 28.06.2011, 17:14

Код:

Visual Basic

Sub P1()
Dim oTbl As Word.Table, oCell As Word.Cell
For Each oTbl In ActiveDocument.Tables
    For Each oCell In oTbl.Range.Cells
        oCell.Range.Text = Trim(Left(oCell.Range.Text, Len(oCell.Range.Text) - 2))
    Next oCell 
Next oTbl
End Sub

@Ципихович Эндрю · 28.06.2011, 20:01 **[ТС]**

одним словом с моего кода строку № 3 долой и всё ОК

Добавлено через 28 минут
голова к вечеру не варит, теперь не могу сообладать с все таблицы Word, только 1е ячейки таблиц
Busine2009, посмотрите пжл, подправьте

Visual Basic

'1
'все таблицы Word, только 1е ячейки таблиц
For y = 1 To ActiveDocument.Tables.Count
Set oTbl_Cell1 = ActiveDocument.Tables(y)
'эта строка указывает, что только 1 ячейка таблиц
Set oCell_Cell1 = oTbl_Cell1.Range.Cells(1)
For Each oCell_Cell1 In ActiveDocument.Tables(y).Range.Cells
oCell_Cell1.Range.Text = Trim(Left(oCell_Cell1.Range.Text, Len(oCell_Cell1.Range.Text) - 2))
Next
Next y
 
'2
'все таблицы Word, все ячейки таблиц
Dim oTblWord As Word.Table
Dim oCellWord As Word.Cell
 
For Each oTblWord In ActiveDocument.Tables
    For Each oCellWord In oTblWord.Range.Cells
        oCellWord.Range.Text = Trim(Left(oCellWord.Range.Text, Len(oCellWord.Range.Text) - 2))
    Next oCellWord
Next oTblWord
 
'3
'все ячейки таблицы ... Word
Dim oTbl As Word.Table
Dim oCell As Word.Cell
 
Set oTbl = ActiveDocument.Tables(1)
    For Each oCell In oTbl.Range.Cells
        oCell.Range.Text = Trim(Left(oCell.Range.Text, Len(oCell.Range.Text) - 2))
    Next oCell

@~~Busine2009~~ · 28.06.2011, 20:20

Все таблицы Word, только первые ячейки таблиц:

Visual Basic

Sub P1()
'Все таблицы Word, только первые ячейки таблиц.
Dim i As Integer
Dim oTbl As Word.Table
For Each oTbl In ActiveDocument.Tables
    'эта строка указывает, что только 1 ячейка таблиц
    With oTbl.Range.Cells(1).Range
        .Text = Trim(Left(.Text, Len(.Text) - 2))
    End With
Next oTbl
End Sub

Все таблицы Word, все ячейки таблиц:

Visual Basic

Sub P2()
'Все таблицы Word, все ячейки таблиц.
Dim oTblWord As Word.Table
Dim oCellWord As Word.Cell
For Each oTblWord In ActiveDocument.Tables
    For Each oCellWord In oTblWord.Range.Cells
        oCellWord.Range.Text = Trim(Left(oCellWord.Range.Text, Len(oCellWord.Range.Text) - 2))
    Next oCellWord
Next oTblWord
End Sub

Одна таблица Word, все ячейки:

Visual Basic

Sub P3()
'Все ячейки для одной таблицы.
Dim oTbl As Word.Table
Dim oCell As Word.Cell
Set oTbl = ActiveDocument.Tables(1)
For Each oCell In oTbl.Range.Cells
    oCell.Range.Text = Trim(Left(oCell.Range.Text, Len(oCell.Range.Text) - 2))
Next oCell
End Sub

@Ципихович Эндрю · 28.06.2011, 20:25 **[ТС]**

и чтобы счасть было полным как будет таблица 1, только ячейки 1 строки??
Спасибо

@~~Busine2009~~ · 28.06.2011, 20:52

Первая таблица в активном документе, первая строка:

Visual Basic

Sub P3()
'Первая таблица в активном документе, первая строка.
'Будет ошибка, если ячейки будут объединены.
Dim oRow As Word.Row
Dim oCell As Word.Cell
Set oRow = ActiveDocument.Tables(1).Rows(1)
For Each oCell In oRow.Cells
    oCell.Range.Text = Trim(Left(oCell.Range.Text, Len(oCell.Range.Text) - 2))
Next oCell
End Sub

В этом случае сложней ориентироваться, т.к. ошибка возникнет, если ячейки объединены. Надо конкретную ситуация рассматривать.

@Ципихович Эндрю 1592 / 559 / 74 Регистрация: 10.04.2009 Сообщений: 9,106
	28.06.2011, 20:25 [ТС]	5
	и чтобы счасть было полным как будет таблица 1, только ячейки 1 строки?? Спасибо 0

	28.06.2011, 20:52