Возникла необходимость создать форму не вручную, используя встроенный редактор, а программно, в зависимости от внешних условий. Нашел пример как можно создать форму, поместить на нее заданное количество текстовых полей и кнопку. А также указать обработчики событий для каждого элемента.
Т.е. сначала программно добавляется в проект форма, затем на эту форму добавляются компоненты, далее компоненты связываются с событиями. В проекте создается три модуля: обычный программный модуль и два модуля класса. В одном модуле класса определяются коллекции, в которые добавляются компоненты по мере их добавления на форму. Второй класс будет отвечать за события, происходящие с компонентами.
Программный модуль:
| Visual Basic |
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
| Option Explicit
Dim COF As ControlsOnForm, EOC As EventsOfControls
Sub CreateForm(NumberOfTextBoxes As Integer)
'Добавляем пустую форму и код процедуры, которая выполняется при запуске формы
Dim oNewForm 'Новая форма
Dim sCode 'Переменная для хранения кода формы
' Application.VBE.MainWindow.Visible = False
'Создаем форму
Set oNewForm = ThisDocument.VBProject.VBComponents.Add(3) 'vbext_ct_MSForm
'Добавляем конструкторы классов для событий формы
sCode = ""
'Создаем процедуру инициализации формы
sCode = sCode & "Sub UserForm_Initialize()" & vbCrLf
sCode = sCode & vbTab & "GetControlsForForm Me, " & NumberOfTextBoxes & vbCrLf
' sCode = sCode & vbTab & "UpdateControls" & vbCrLf
sCode = sCode & "End Sub" & vbCrLf
'Вставляем код формы
oNewForm.CodeModule.InsertLines oNewForm.CodeModule.CountOfLines + 1, sCode
'Показываем форму
VBA.UserForms.Add(oNewForm.Name).Show
'Удаляем форму из рабочей книги
ThisDocument.VBProject.VBComponents.Remove oNewForm
End Sub
'Процедура, создающая указанное количество текстовых полей на указанной форме, и кнопку
Sub GetControlsForForm(ByVal oForm As Object, ByVal NumberOfTextBoxes As Integer)
'Переменные для объектов на форме
Dim oBtn As MSForms.CommandButton
Dim oTxt As MSForms.TextBox
'Верхний левый угол компонента
Dim iLeft As Integer, iTop As Integer
'Счетчик
Dim i As Integer
'Максимальный размер формы
Dim iMaxWidth As Integer, iMaxHeight As Integer
'Заполняем форму компонентами
Set COF = New ControlsOnForm
iLeft = 6: iTop = 6 'Верхний левый угол первого текстового поля
For i = 1 To NumberOfTextBoxes
'Создаем кнопку
Set oTxt = oForm.Controls.Add("Forms.TextBox.1", "txtNumber" & i)
With oTxt
.Text = .Name
.Left = iLeft: .Top = iTop
iTop = iTop + .Height
iMaxWidth = iLeft + .Width + 6
iMaxHeight = iTop - .Height + 20
End With
'Связываем текстовое поле с обработчиком событий
Set EOC = New EventsOfControls: Set EOC.TextBoxEv = oTxt
'Добавляем в коллекцию
COF.TextBoxes.Add EOC
Next i
'Теперь добавляем кнопку
Set oBtn = oForm.Controls.Add("Forms.CommandButton.1", "btnTest")
With oBtn
.Caption = "Моя кнопка"
.Left = iLeft
.Top = iTop
iMaxWidth = iLeft + .Width + 6
iMaxHeight = iTop + .Height + 20
End With
'Связываем кнопку с обработчиком событий
Set EOC = New EventsOfControls: Set EOC.ButtonEv = oBtn
'Добавляем в коллекцию
COF.Buttons.Add EOC
'Подгоняем размеры формы
oForm.Height = iMaxHeight: oForm.Width = iMaxWidth
End Sub
'Основная процедура, запускающая весь процесс
Sub СоздатьФорму()
Dim TBCount As Integer
Dim sInput As String
Do
sInput = InputBox("Введите число нужных текстовых полей", "Динамическое создание формы", 5)
If Len(sInput) = 0 Then Exit Sub 'Если ничего не ввели, или нажали отмену
'Если ввели не число, предлагаем ввод еще раз
If IsNumeric(sInput) Then TBCount = CInt(sInput) Else sInput = ""
Loop Until Len(sInput) > 0
CreateForm (TBCount)
End Sub |
|
Модуль класса 1:
| Visual Basic |
1
2
3
4
| Option Explicit
'Класс, для хранения в коллекциях элементов формы
Public Buttons As New Collection
Public TextBoxes As New Collection |
|
Модуль класса 2:
| Visual Basic |
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
| Option Explicit
'Этот класс содержит в себе обработчики событий для различных элементов формы
'Элемент, ответсвтвенный за обработку событий в текстовом поле
Public WithEvents TextBoxEv As MSForms.TextBox
'Обработчик событий кнопки
Public WithEvents ButtonEv As MSForms.CommandButton
Private Sub ButtonEv_Click()
Dim oForm As Object
Set oForm = Me.ButtonEv.Parent
MsgBox "Вы кликнули на кнопке " & Me.ButtonEv.Name & vbCr & _
"На форме расположено " & Me.ButtonEv.Parent.Controls.Count - 1 & " текстовых полей", vbInformation, _
"Динамическое создание формы"
End Sub
'Обработчик двойного нажатия в текстовом поле
Private Sub TextBoxEv_DblClick(ByVal Cancel As MSForms.ReturnBoolean)
MsgBox "Вы дважды кликнули мышкой в текстовом поле " & Me.TextBoxEv.Name & "!", vbInformation, _
"Динамическое создание формы"
End Sub |
|
При запуске ругается на отсутствие объявления пользовательских типов ControlsOnForm, EventsOfControls.
Пожалуйста, помогите довести скрипт до работоспособного состояния.
(
