Сцепить группы строк

@MarkedOne · Регистрация: 03.04.2013

Author24 — интернет-сервис помощи студентам

Здравствуйте

Прошу помощи в следующей задаче.

Есть файл, где в одном столбце есть группы строк (изменяющееся количество), разделенных пустой строкой. Примерно так:

Кликните здесь для просмотра всего текста

заголовок 1
ааа
ббб
ссс

заголовок 2
ввв
гг

Заголовок 3
фф
ввв
ккк
ййй

И так далее 1000 раз.

Цель - получить 1000 строк, в которых группы строк будут объединены в одну ячейку.
Для объединения диапазона я нашел готовую пользовательскую функцию (сцепить много), она работает на отлично.
А вот написать цикл, который будет подавать этой функции на вход диапазоны, мне не удалось.
Помогите, пожалуйста, укажите на ошибки и как их исправить. Спасибо!

Visual Basic

Sub Макрос()
 
For i = 1 To i = 3
 
addr = 2
'
    Cells.Find(What:="XXX_", After:=ActiveCell, LookIn:=xlFormulas, LookAt _
        :=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, MatchCase:= _
        False, SearchFormat:=False).Activate
 
    Range(Selection, Selection.End(xlDown)).Select
    xxx = Selection.Address
    
Range("C" & addr).FormulaR1C1 = "=PERSONAL.XLSB!СцепитьМного(" & xxx & ",CHAR(10))"
addr = addr + 1
i = i + 1
Next i
 
End Sub

@pashulka · 18.10.2016, 15:20

Альтернативный вариант, без использования пользовательской функции

Visual Basic

Private Sub Test()
    Application.ScreenUpdating = False
    Dim iSource As Range
    For Each iSource In [A:A].SpecialCells(xlConstants).Areas
        iSource(1, 2) = Join(Application.Transpose(iSource), vbLf)
    Next
    Application.ScreenUpdating = True
End Sub

@MarkedOne · 18.10.2016, 16:58 **[ТС]**

pashulka, ого! ОГО. Идеально, делает именно то, что нужно. Спасибо огромное!

А вы не могли бы пояснить, как это работает?
Я вижу, что тут цикл, который работает с каждой Area в столбце А. А вот что в пятой строке происходит, не могли бы пояснить?

@pashulka · 18.10.2016, 17:48

Происходит транспонирование (с помощью одноимённой стандартной функции рабочего листа), а затем VB(A) функция Join возвращает строку, содержащую все элементы одномерного массива, об'единённые вместе.

P.S. Ещё один вариант решения поставленной задачи.

Visual Basic

Private Sub Test2()
    Application.ScreenUpdating = False
    Dim iSource As Range, iClipboard As New MSForms.DataObject
    'Tools - References - Microsoft Forms 2.0 ... (FM20.dll)
    For Each iSource In [A:A].SpecialCells(xlConstants).Areas
        iSource.Copy: iClipboard.GetFromClipboard
        iSource(1, 2) = Replace(iClipboard.GetText, vbCrLf, vbLf)
    Next
    Application.CutCopyMode = False
    Application.ScreenUpdating = True
End Sub

@MarkedOne 0 / 0 / 0 Регистрация: 03.04.2013 Сообщений: 7
	18.10.2016, 16:58 [ТС]	3
	pashulka, ого! ОГО. Идеально, делает именно то, что нужно. Спасибо огромное! А вы не могли бы пояснить, как это работает? Я вижу, что тут цикл, который работает с каждой Area в столбце А. А вот что в пятой строке происходит, не могли бы пояснить? 0

	18.10.2016, 17:48