Как создать макросом UserForm, создать на ней кнопку и привязать к ней макрос?

Load MyBar1
Set B = New MyBar1
Set o = B.Controls.Add("Forms.CommandButton.1", "", True)
o.OnAction "Макрос1"

Option Explicit
 
Dim WithEvents c As MSForms.CommandButton 'Объявляем кнопку с её событиями
 
Private Sub c_Click()
    '
    'Событие нажатия на неё
    '
    'Варианты вызова макроса
    Application.Run "Макрос1" ', Аргумент1, Аргумент2, Аргумент3, и_т_д
    'Или
    Макрос1 ', Аргумент1, Аргумент2,... '---Прямой вызов макроса
End Sub
 
Private Sub UserForm_Initialize()
    Set c = Controls.Add("Forms.CommandButton.1", "c", 1)
    With c
        .Move 10, 10, 100, 20 '-------- Скрытый метод размерности Move Left, Top, Width, Height
        .Caption = "Нажми сюда"
    End With
End Sub

Private Sub Добавление_Формы_К_Проекту()
    Dim UserFormNew As Object
    With ThisWorkbook.VBProject.VBComponents
        Set UserFormNew = .Add(3) '3 это форма // 2 - класс // 1 - модуль
        With UserFormNew
            .Name = "UserFormNew"
        End With
    End With
End Sub

If ActiveWorkbook.VBProject.Protection = 1 Then 
   MsgBox "VBProject защищён"
Else
   MsgBox "VBProject не защищён"
End If

Option Explicit
Dim WithEvents c As MSForms.CommandButton 'Объявляем кнопку с её событиями
 
Private Sub c_Click()
    Dim v
    With ThisWorkbook.VBProject.VBComponents.Add(3)
         .Properties("Width") = 200
         .Properties("Height") = 100
         With .Designer.Controls.Add("Forms.CommandButton.1")
            .Caption = "Нажми сюда"
            .Move 60, 30
         End With
         With .CodeModule
            For Each v In Array( _
                "", _
                "Private Sub CommandButton1_Click()", _
                "    MsgBox ""Нажата CommandButton1""", _
                "End Sub")
                .InsertLines .CountOfLines, v
            Next
         End With
         VBA.UserForms.Add(.Name).Show
    End With
End Sub
 
Private Sub UserForm_Initialize()
    Set c = Controls.Add("Forms.CommandButton.1", "c", 1)
    With c
        .Move 10, 10, 100, 20 '-------- Скрытый метод размерности Move Left, Top, Width, Height
        .Caption = "Нажми сюда"
    End With
End Sub