Макрос копирования одного диапазона с каждого листа книги в другой файл

Sub Перенос_В2В3В4()
   'В активную книгу постранично копирует ячейки на одноименных листах с транспонированием из другой открытой книги
   '[B2]=[B2]:[C2]=[B3]:[D2]=[B4]
    Dim k&, Tablica$
    Dim wb_Ishodn As Workbook, wb_Cel As Workbook, wb_Tek As Workbook
    Dim UslovieKnigi As Integer
    Set wb_Cel = ActiveWorkbook
    UslovieKnigi = 1
    For Each wb_Tek In Workbooks
        If Not wb_Tek Is wb_Cel Then
            If Left$(LCase(wb_Tek.Name), 11) <> "personal.xl" Then
                Set wb_Ishodn = wb_Tek
                UslovieKnigi = UslovieKnigi + 1
            End If
        End If
    Next
    If UslovieKnigi <> 2 Then
          MsgBox "Выполнение макроса прервано. Нет открытых 2-х книг."
          Exit Sub
    End If
    With Application
        .Calculation = xlCalculationManual
        .ScreenUpdating = False
    End With
    On Error GoTo Err1
    For k = 1 To wb_Cel.Worksheets.Count
       With wb_Cel.Worksheets(k)
            Tablica = .Name
            .[B2] = wb_Ishodn.Sheets(Tablica).[B2]
            .[C2] = wb_Ishodn.Sheets(Tablica).[B3]
            .[D2] = wb_Ishodn.Sheets(Tablica).[B4]
       End With
    Next k
    With Application
        .Calculation = xlCalculationAutomatic
        .ScreenUpdating = True
    End With
    Set wb_Cel = Nothing
    Set wb_Ishodn = Nothing
    Exit Sub
Err1:
    Debug.Print "Ошибка при копировании на лист " & Tablica
    Err.Clear
    Resume Next
End Sub