Сохранение листа в отдельную книгу. Как добиться удаления макроса и кнопки его запуска на копии?

Sub SaveActiveSheetWithValuesAndFormats()
' Сохранить лист в отдельную книгу, сохранить только значения и оформление
    Dim sh As Worksheet, wbNew As Workbook, cFileName
    Set sh = ActiveSheet
    cFileName = Application.GetSaveAsFilename(sh.Name, "Книга Microsoft Office Excel (*.xls), *.xls")
    If cFileName = False Then Exit Sub
    Application.ScreenUpdating = False
    ' Копируем лист (при этом создается новый файл с этим листом)
    sh.Copy
    Set wbNew = ActiveWorkbook
    ' Заменяем формулы значениями
    With wbNew.Sheets(1).UsedRange.Cells
        .Value = .Value
    End With
    ' Сохраняем файл
    Application.DisplayAlerts = False
    wbNew.SaveAs Filename:=(cFileName), FileFormat:=xlNormal
    ' Закрываем файл и возвращаемся в начало
    wbNew.Close
    Application.DisplayAlerts = True
    Application.ScreenUpdating = True
    sh.Activate
End Sub

Sub SaveActiveSheetWithValuesAndFormats()
' Сохранить лист в отдельную книгу, сохранить только значения и оформление
    Dim sh As Worksheet, wbNew As Workbook, cFileName, LastRow&, LastCol&
    Set sh = ActiveSheet
    cFileName = Application.GetSaveAsFilename(sh.Name)
    If cFileName = False Then Exit Sub
    Application.ScreenUpdating = False
    Workbooks.Add xlWBATWorksheet
    Set wbNew = ActiveWorkbook
    With wbNew
        With .Sheets(1)
            .Name = sh.Name
            With sh
                LastRow = .UsedRange.Rows.Count + .UsedRange.Row - 1
                LastCol = .UsedRange.Columns.Count + .UsedRange.Column - 1
                .Range(.Cells(1, 1), .Cells(LastRow, LastCol)).Copy
            End With
            .Cells(1, 1).PasteSpecial Paste:=xlPasteColumnWidths, Operation:=xlNone, _
            SkipBlanks:=False, Transpose:=False
            .Cells(1, 1).PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
                :=False, Transpose:=False
            .Cells(1, 1).PasteSpecial Paste:=xlPasteFormats, Operation:=xlNone, _
                SkipBlanks:=False, Transpose:=False
        End With
    End With
    ' Сохраняем файл
    Application.DisplayAlerts = False
    ' В зависимости от указанного расширения
    If InStr(1, cFileName, ".xlsx") > 0 Then
        wbNew.SaveAs FileName:=(cFileName), FileFormat:=xlOpenXMLWorkbook
    ElseIf InStr(1, cFileName, ".xlsm") > 0 Then
        wbNew.SaveAs FileName:=(cFileName), FileFormat:=xlOpenXMLWorkbookMacroEnabled
    ElseIf InStr(1, cFileName, ".xls") > 0 Then
        wbNew.SaveAs FileName:=(cFileName), FileFormat:=xlExcel8
    ElseIf InStr(1, cFileName, ".csv") > 0 Then
        wbNew.SaveAs FileName:=(cFileName), FileFormat:=xlCSV
    ElseIf InStr(1, cFileName, ".pdf") > 0 Then
        ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, FileName:= _
        (cFileName), Quality:=xlQualityStandard, _
        IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=False
    End If
    Application.DisplayAlerts = True
    wbNew.Close 0
    Application.ScreenUpdating = True
    sh.Activate
End Sub

    With Application.FileDialog(msoFileDialogSaveAs)
       .InitialFileName = sh.Name
       If .Show = 0 Then Exit Sub
       cFileName = .SelectedItems(1)
    End With