Макрос отправки письма Outlook через Excel с автоприкреплением файла

Option Explicit
 
Sub Send_Mail()
    Dim objOutlookApp As Object, objMail As Object
    Dim sTo As String, sSubject As String, sBody As String, sAttachment As String
 
    Application.ScreenUpdating = False
    On Error Resume Next
    Set objOutlookApp = CreateObject("Outlook.Application")
    objOutlookApp.Session.Logon
    Set objMail = objOutlookApp.CreateItem(0)   'создаем новое сообщение
    'если не получилось создать приложение или экземпляр сообщения - выходим
    If Err.Number <> 0 Then Set objOutlookApp = Nothing: Set objMail = Nothing: Exit Sub
    
    sTo = "AddressTo@mail.ru"    'Кому(можно заменить значением из ячейки - sTo = Range("A1").Value)
    sSubject = "Автоотправка"    'Тема письма(можно заменить значением из ячейки - sSubject = Range("A2").Value)
    sBody = "Привет от Excel-VBA"    'Текст письма(можно заменить значением из ячейки - sBody = Range("A3").Value)
    sAttachment = "C:/Temp/Книга1.xls"    'Вложение(полный путь к файлу. Можно заменить значением из ячейки - sAttachment = Range("A4").Value)
    
    'создаем сообщение
    With objMail
        .To = sTo 'адрес получателя
        .Subject = sSubject 'тема сообщения
        .Body = sBody 'текст сообщения
        .Attachments.Add sAttachment
        .Send 'Display, если необходимо просмотреть сообщение, а не отправлять без просмотра
    End With
exit_:
    Set objOutlookApp = Nothing: Set objMail = Nothing
    Application.ScreenUpdating = True
End Sub

Option Explicit
 
Private Sub TEST()
    Dim txt$
    SaveAccountData
    txt = "Это письмо сформировано макросом" & vbNewLine & "без использования внешних программ и подключения дополнительных библиотек"
    If Send_Mail("FelixMacintosh@yandex.ru", "FelixMacintosh@yandex.ru", "проверка отправки почты_2", _
    txt) Then
        MsgBox "Письмо успешно отправлено", vbInformation
    Else
        MsgBox "Не удалось отправить письмо", vbExclamation
    End If
End Sub
 
 
Sub SaveAccountData() 'запускать один раз - для записи в реестр Windows параметров почтового аккаунта
    SaveSetting App.EXEName, "mail", "smtpserver", "smtp.yandex.ru" 'Ваш SMTPServer
    SaveSetting App.EXEName, "mail", "sendusername", "FelixMacintosh@yandex.ru" 'Ваша учетная запись
    SaveSetting App.EXEName, "mail", "sendpassword", "XXXXXXX" 'Ваш пароль
End Sub
 
Function Send_Mail(ByVal MailTo As String, ByVal MailFrom As String, ByVal MailSubject As String, _
ByVal MailText As String, Optional ByVal MailAttachment As String = "") As Boolean
    'функция для отправки почты без использования внешних почтовых программ
    '----------------------------------------------------------------------
    'в качестве параметров получает:
    'MailTo - адрес получателя письма
    'MailFrom - адрес отправителя письма
    'MailSubject - тема письма
    'MailText - текст письма
    'MailAttachment - полный путь к файлу вложения (необязательный параметр)
    '----------------------------------------------------------------------
    'возвращает TRUE, если отправка почты произошла успешно, и FALSE в обратном случае
    Const cdoConfigURL = "http://schemas.microsoft.com/cdo/configuration/"
    Dim smtpserver$, sendusername$, sendpassword$
    Dim cdoConfig As Object, cdoMessage As Object
    On Error Resume Next: Err.Clear
    smtpserver = GetSetting(App.EXEName, "mail", "smtpserver", "")
    sendusername = GetSetting(App.EXEName, "mail", "sendusername", "")
    sendpassword = GetSetting(App.EXEName, "mail", "sendpassword", "")
    If Len(smtpserver) = 0 Or Len(sendusername) = 0 Or Len(sendpassword) = 0 Then Exit Function
    Set cdoConfig = CreateObject("CDO.Configuration")
    With cdoConfig.Fields
        .Item(cdoConfigURL & "sendusing") = 2
        .Item(cdoConfigURL & "smtpauthenticate") = 1
        .Item(cdoConfigURL & "smtpserver") = smtpserver
        .Item(cdoConfigURL & "sendusername") = sendusername
        .Item(cdoConfigURL & "sendpassword") = sendpassword
        'для отправки почты с аккаунта @gmail.com
        .Item(cdoConfigURL & "smtpserverport") = 465 'порт для SSL: 465
        .Item(cdoConfigURL & "smtpusessl") = 1 'использовать аутентификацию: да
        .Update
    End With
    Set cdoMessage = CreateObject("CDO.Message")
    With cdoMessage
        Set .Configuration = cdoConfig
        .BodyPart.Charset = "koi8-r"
        .From = MailFrom:
        .To = MailTo
        .Subject = MailSubject
        .TextBody = MailText
        If Len(MailAttachment) > 0 Then .AddAttachment MailAttachment 'Вложение !
        .Send
    End With
    Set cdoMessage = Nothing: Set cdoConfig = Nothing
    'If Err.Number = -2147220973 Then MsgBox ("Отсутствует связь с интернетом")
    'If Err.Number = -2147220975 Then MsgBox ("SMTP сервер ответил отказом")
    'If Err.Number = 0 Then MsgBox ("Письмо отправлено")
    Send_Mail = Err = 0
End Function