Как рассчитать время затраченное на обработку заявки

@IIPAIIOP · Регистрация: 05.02.2013

Author24 — интернет-сервис помощи студентам

Доброго дня.

Подскажите как рассчитать время затраченное на обработку заявки.

Исходные данные выглядят в след. формате

08.12.2013 18:15

09.12.2013 10:44

989

Последнее поле это затраченное время в минутах.

Но оно не логично, потому что раб. день с 9:00 до 18:00.
И эта заявка пришла уже позже.
Как сделать макрос с пост условием чтобы он не считал время с 18:00 до 9:00 след. дня.
А каждый день брал с 9:00

@budulaj-lviv · 17.12.2013, 14:54

ето постав в начале обработки

Visual Basic

1
2
3

Dim StartTime As Date
Dim EndTime As Date
StartTime = Timer

ето в конце

Visual Basic

1
2
3

Dim Ans As Variant
EndTime = Timer
Ans = MsgBox("время исполнения: " & Format(EndTime - StartTime, "0.000") )

@KoGG · 17.12.2013, 15:08

Visual Basic

Sub bb()
    Dim Date1 As Date, Date2 As Date, DateStart  As Date, Minut%
    Date1 = CDate("08.12.2013 18:15")
    Date2 = CDate("09.12.2013 10:44")
    If TimeValue(Date1) > TimeSerial(18, 0, 0) Then
        DateStart = DateValue(Date1) + 1 + TimeSerial(9, 0, 0)
    Else
        DateStart = Date1
    End If
    Minut = DateDiff("n", DateStart, Date2)
    MsgBox Minut
End Sub

@IIPAIIOP · 17.12.2013, 15:09 **[ТС]**

budulaj-lviv, Это понятно... мне не понятен момент с указание не раб часов

@~~Апострофф~~ · 17.12.2013, 15:27

Поправочка-

Visual Basic

    If TimeValue(Date1) > TimeSerial(18, 0, 0) Then
        DateStart = DateValue(Date1) + 1 + TimeSerial(9, 0, 0)
    elseIf TimeValue(Date1) < TimeSerial(9, 0, 0) Then
        DateStart = DateValue(Date1) + TimeSerial(9, 0, 0)
    Else
        DateStart = Date1
    End If

@IIPAIIOP · 17.12.2013, 15:30 **[ТС]**

Сообщение от KoGG

Visual Basic

Sub bb()
    Dim Date1 As Date, Date2 As Date, DateStart  As Date, Minut%
    Date1 = CDate("08.12.2013 18:15")
    Date2 = CDate("09.12.2013 10:44")
    If TimeValue(Date1) > TimeSerial(18, 0, 0) Then
        DateStart = DateValue(Date1) + 1 + TimeSerial(9, 0, 0)
    Else
        DateStart = Date1
    End If
    Minut = DateDiff("n", DateStart, Date2)
    MsgBox Minut
End Sub

А можно чтобы он перебрал данные для Date1 = CDate("B") и Date2 = CDate("С")
озникла ошибка с номером 13, "Type mismatch когда сделал так

Visual Basic

Sub bb()
    Dim Date1 As Date, Date2 As Date, DateStart  As Date, Minut%
    
    For i = 1 To 2
    With ThisWorkbook.Sheets("Лист1")
    Date1 = CDate("B")
    Date2 = CDate("C")
    If TimeValue(Date1) > TimeSerial(18, 0, 0) Then
        DateStart = DateValue(Date1) + 1 + TimeSerial(9, 0, 0)
    Else
        DateStart = Date1
    End If
    Minut = DateDiff("n", DateStart, Date2)
    MsgBox Minut
    
    End With
    Next i
End Sub

@~~Апострофф~~ · 17.12.2013, 15:38

Сообщение от IIPAIIOP

Date1 = CDate("B")

меняйте на

Visual Basic

1	Date1 = CDate(.range("B1"))

ибо CDate не может расшифровать литерал "B"

@KoGG · 17.12.2013, 15:42

Можно, но думаю не нужно, потому что можно вызвать эту функцию с листа.
Более универсальный случай , в том числе с разницей в несколько дней.

Visual Basic

Function RabocheeVremya(Date1, Date2)
    Dim DateStart  As Date, Minut%, Nochi%
    Nochi = DateValue(Date2) - DateValue(Date1)
    If TimeValue(Date1) > TimeSerial(18, 0, 0) Then
        DateStart = DateValue(Date1) + TimeSerial(18, 0, 0)
    ElseIf TimeValue(Date1) < TimeSerial(9, 0, 0) Then
        DateStart = DateValue(Date1) + TimeSerial(9, 0, 0)
    Else
        DateStart = Date1
    End If
    Minut = DateDiff("n", DateStart, Date2) - Nochi * 900  ' 15 часов нераб.
    RabocheeVremya = Minut
End Function

@~~Апострофф~~ · 17.12.2013, 15:45

Не по теме:

А ещё бы выходные исключить:scratch:

@IIPAIIOP · 17.12.2013, 15:49 **[ТС]**

Сообщение от KoGG

Можно, но думаю не нужно, потому что можно вызвать эту функцию с листа.
Более универсальный случай , в том числе с разницей в несколько дней.

Visual Basic

Function RabocheeVremya(Date1, Date2)
    Dim DateStart  As Date, Minut%, Nochi%
    Nochi = DateValue(Date2) - DateValue(Date1)
    If TimeValue(Date1) > TimeSerial(18, 0, 0) Then
        DateStart = DateValue(Date1) + TimeSerial(18, 0, 0)
    ElseIf TimeValue(Date1) < TimeSerial(9, 0, 0) Then
        DateStart = DateValue(Date1) + TimeSerial(9, 0, 0)
    Else
        DateStart = Date1
    End If
    Minut = DateDiff("n", DateStart, Date2) - Nochi * 900  ' 15 часов нераб.
    RabocheeVremya = Minut
End Function

Функция класс!!!!!!!!!)))
вот что заметил

10.12.2013 23:09

11.12.2013 8:14

-46

@KoGG · 17.12.2013, 15:59

Разумеется. Нет дополнительной защиты от дурака.
Не рассчитано, что заявка закрывается в нерабочее время.

Добавлено через 7 минут
На случай последнего примера времени:

Visual Basic

Function RabocheeVremya(Date1, ByVal Date2)
    Dim DateStart  As Date,  Nochi%
    Nochi = DateValue(Date2) - DateValue(Date1)
    If TimeValue(Date1) > TimeSerial(18, 0, 0) Then
        DateStart = DateValue(Date1) + TimeSerial(18, 0, 0)
    ElseIf TimeValue(Date1) < TimeSerial(9, 0, 0) Then
        DateStart = DateValue(Date1) + TimeSerial(9, 0, 0)
    Else
        DateStart = Date1
    End If
    If TimeValue(Date2) > TimeSerial(18, 0, 0) Then
        Date2 = DateValue(Date2) + TimeSerial(18, 0, 0)
    ElseIf TimeValue(Date2) < TimeSerial(9, 0, 0) Then
        Date2 = DateValue(Date2) + TimeSerial(9, 0, 0)
    End If
    RabocheeVremya = DateDiff("n", DateStart, Date2) - Nochi * 900  ' 15 часов нераб.
End Function

@IIPAIIOP · 24.12.2013, 13:31 **[ТС]**

KoGG, Еще один вопрос столкнулся с таким казусом, как выходные дни : Суббота, воскресенье.

Как их вычитать из текущей формулы ?

@~~Апострофф~~ · 24.12.2013, 13:52

Не по теме:

KoGG, и праздники (желательно с учётом переносов правительственными постановлениями дней отдыха):)

@IIPAIIOP · 24.12.2013, 14:02 **[ТС]**

Ну зачем праздники...

Visual Basic

Function RabocheeVremya(Date1, ByVal Date2)
    Dim DateStart  As Date, Nochi%
   ' Dim IntKolDney$
'IntKolDney(1, 1) = Application.WorksheetFunction.NetworkDays(DtmDataDol, DtmDataVozvr)
    Nochi = DateValue(Date2) - DateValue(Date1)
    If TimeValue(Date1) > TimeSerial(18, 0, 0) Then
        DateStart = DateValue(Date1) + TimeSerial(18, 0, 0)
    ElseIf TimeValue(Date1) < TimeSerial(8, 0, 0) Then
        DateStart = DateValue(Date1) + TimeSerial(8, 0, 0)
    Else
        DateStart = Date1
    End If
    If TimeValue(Date2) > TimeSerial(18, 0, 0) Then
        Date2 = DateValue(Date2) + TimeSerial(18, 0, 0)
    ElseIf TimeValue(Date2) < TimeSerial(8, 0, 0) Then
        Date2 = DateValue(Date2) + TimeSerial(8, 0, 0)
    End If
    RabocheeVremya = DateDiff("n", DateStart, Date2) - Nochi * 840 - Application.WorksheetFunction.NetworkDays(Date1, Date2) ' 14 часов нераб.
End Function

Сделал так... Но... не считается...

@KoGG · 25.12.2013, 09:51

Новая функция исключает выходные и праздники.
Нерабочие считаются аналогично функции листа ЧИСТРАБДНИ.
Дополнительные праздники, неизвестные системе, должны вводиться в виде ссылки на диапазон с датами, либо в виде массива переменных типа дата.

Visual Basic

Function RabocheeVremya(ByVal StartDate, ByVal EndDate, ParamArray Holidays())
    Dim Minut&, Nochi&, NeRabochie&, Rabochie&
    Dim StartDateIsNerab As Boolean, EndDateIsNerab As Boolean
    If UBound(Holidays, 1) >= LBound(Holidays, 1) Then
        Rabochie = Application.WorksheetFunction.NetworkDays(StartDate, EndDate, Holidays())
        StartDateIsNerab = (Application.WorksheetFunction.NetworkDays(StartDate, StartDate, Holidays()) = 0)
        EndDateIsNerab = (Application.WorksheetFunction.NetworkDays(EndDate, EndDate, Holidays()) = 0)
    Else
        Rabochie = Application.WorksheetFunction.NetworkDays(StartDate, EndDate)
        StartDateIsNerab = (Application.WorksheetFunction.NetworkDays(StartDate, StartDate) = 0)
        EndDateIsNerab = (Application.WorksheetFunction.NetworkDays(EndDate, EndDate) = 0)
    End If
    If Rabochie = 0 Then
        RabocheeVremya = 0
        Exit Function
    End If
    Nochi = DateValue(EndDate) - DateValue(StartDate)
    NeRabochie = Nochi + 1 - Rabochie
    If StartDateIsNerab Then
        StartDate = DateValue(StartDate) + TimeSerial(18, 0, 0)
        NeRabochie = NeRabochie - 1
    Else
        If TimeValue(StartDate) > TimeSerial(18, 0, 0) Then
            StartDate = DateValue(StartDate) + TimeSerial(18, 0, 0)
        ElseIf TimeValue(StartDate) < TimeSerial(9, 0, 0) Then
            StartDate = DateValue(StartDate) + TimeSerial(9, 0, 0)
        End If
    End If
    If EndDateIsNerab Then
        If DateValue(EndDate) > DateValue(StartDate) Then
            EndDate = DateValue(EndDate) + TimeSerial(9, 0, 0)
        Else
            EndDate = DateValue(StartDate) + TimeSerial(18, 0, 0)
        End If
        NeRabochie = NeRabochie - 1
    Else
        If TimeValue(EndDate) > TimeSerial(18, 0, 0) Then
            EndDate = DateValue(EndDate) + TimeSerial(18, 0, 0)
        ElseIf TimeValue(EndDate) < TimeSerial(9, 0, 0) Then
            EndDate = DateValue(EndDate) + TimeSerial(9, 0, 0)
        End If
    End If
    RabocheeVremya = RabocheeVremya - NeRabochie * 9 - Nochi * 15 '9 час. в нерабочие дни, 15 часов раб. ночей в любые дни
    ' Либо в часах:
    'RabocheeVremya = RabocheeVremya + DateDiff("h", StartDate, EndDate) ' в часах
    ' Либо в минутах
    RabocheeVremya = RabocheeVremya * 60 + DateDiff("n", StartDate, EndDate) ' в минутах
End Function

Надеюсь, что не возникнет необходимость вычитать время обеда по скользящему графику.

@IIPAIIOP · 25.12.2013, 11:06 **[ТС]**

KoGG, ЭТО ГРАНДИОЗНО!!! БЛАГОДАРЮ!!!

@IIPAIIOP 0 / 0 / 1 Регистрация: 05.02.2013 Сообщений: 150
	25.12.2013, 11:06 [ТС]	16
	KoGG, ЭТО ГРАНДИОЗНО!!! БЛАГОДАРЮ!!! 0

@IIPAIIOP 0 / 0 / 1 Регистрация: 05.02.2013 Сообщений: 150
	17.12.2013, 15:09 [ТС]	4
	budulaj-lviv, Это понятно... мне не понятен момент с указание не раб часов 0

@~~Апострофф~~
	17.12.2013, 15:45 #9
	Не по теме: А ещё бы выходные исключить:scratch: 0

@IIPAIIOP 0 / 0 / 1 Регистрация: 05.02.2013 Сообщений: 150
	24.12.2013, 13:31 [ТС]	12
	KoGG, Еще один вопрос столкнулся с таким казусом, как выходные дни : Суббота, воскресенье. Как их вычитать из текущей формулы ? 0

@~~Апострофф~~
	24.12.2013, 13:52 #13
	Не по теме: KoGG, и праздники (желательно с учётом переносов правительственными постановлениями дней отдыха):) 0

Как рассчитать время затраченное на обработку заявки

Решение