Открыть FolderBrowserDialog на определённом каталоге

FolderBrowserDialog1.SelectedPath = "D:\temp"

 Dim t As New Timer()
 
        AddHandler t.Tick, Sub()
                               SendKeys.Send("{TAB}{TAB}{RIGHT}")
                               t.Stop()
                           End Sub
 
        Dim fbd As New FolderBrowserDialog
        fbd.SelectedPath = "C:\WINDOWS\system32\Microsoft"
        fbd.ShowNewFolderButton = False
        fbd.Description = "Выберите папку, в которой находятся ведомости"
        t.Interval = 10
        t.Start()
        If fbd.ShowDialog = DialogResult.OK Then
 
            path = fbd.SelectedPath
        End If

SendKeys.Send("{TAB}{TAB}{RIGHT}")

SendKeys.Send("{TAB}{TAB}{DOWN}{DOWN}{DOWN}{UP}{UP}{UP}")

SendKeys.Send("{TAB}{TAB}{RIGHT}")

Public Module FolderBrowserLauncher
    ''' <summary>
    ''' Using title text to look for the top level dialog window is fragile.
    ''' In particular, this will fail in non-English applications.
    ''' </summary>
    Private Const _topLevelSearchString As String = "Browse For Folder"
 
    ''' <summary>
    ''' These should be more robust.  We find the correct child controls in the dialog
    ''' by using the GetDlgItem method, rather than the FindWindow(Ex) method,
    ''' because the dialog item IDs should be constant.
    ''' </summary>
    Private Const _dlgItemBrowseControl As Integer = 0
    Private Const _dlgItemTreeView As Integer = 100
 
    <DllImport("user32.dll", SetLastError := True)>
    Function FindWindow(ByVal lpClassName As String, ByVal lpWindowName As String) As IntPtr
    End Function
 
    <DllImport("user32.dll")>
    Function GetDlgItem(ByVal hDlg As IntPtr, ByVal nIDDlgItem As Integer) As IntPtr
    End Function
 
    <DllImport("user32.dll", CharSet := CharSet.Auto)>
    Function SendMessage(ByVal hWnd As IntPtr, ByVal Msg As UInt32, ByVal wParam As IntPtr, ByVal lParam As IntPtr) As IntPtr
    End Function
 
    ''' <summary>
    ''' Some of the messages that the Tree View control will respond to
    ''' </summary>
    Private Const TV_FIRST As Integer = &H1100
    Private Const TVM_SELECTITEM As Integer = (TV_FIRST + 11)
    Private Const TVM_GETNEXTITEM As Integer = (TV_FIRST + 10)
    Private Const TVM_GETITEM As Integer = (TV_FIRST + 12)
    Private Const TVM_ENSUREVISIBLE As Integer = (TV_FIRST + 20)
 
    ''' <summary>
    ''' Constants used to identity specific items in the Tree View control
    ''' </summary>
    Private Const TVGN_ROOT As Integer = &H0
    Private Const TVGN_NEXT As Integer = &H1
    Private Const TVGN_CHILD As Integer = &H4
    Private Const TVGN_FIRSTVISIBLE As Integer = &H5
    Private Const TVGN_NEXTVISIBLE As Integer = &H6
    Private Const TVGN_CARET As Integer = &H9
 
 
    ''' <summary>
    ''' Calling this method is identical to calling the ShowDialog method of the provided
    ''' FolderBrowserDialog, except that an attempt will be made to scroll the Tree View
    ''' to make the currently selected folder visible in the dialog window.
    ''' </summary>
    ''' <param name="dlg"></param>
    ''' <param name="parent"></param>
    ''' <returns></returns>
    Public Function ShowFolderBrowser(ByVal dlg As FolderBrowserDialog, Optional ByVal parent As IWin32Window = Nothing) As DialogResult
        Dim result As DialogResult = DialogResult.Cancel
        Dim retries As Integer = 10
 
        Using t As New Timer()
            AddHandler t.Tick, Sub(s, a)
                If retries > 0 Then
                    retries -= 1
                    Dim hwndDlg As IntPtr = FindWindow(DirectCast(Nothing, String), _topLevelSearchString)
                    If hwndDlg <> IntPtr.Zero Then
                        Dim hwndFolderCtrl As IntPtr = GetDlgItem(hwndDlg, _dlgItemBrowseControl)
                        If hwndFolderCtrl <> IntPtr.Zero Then
                            Dim hwndTV As IntPtr = GetDlgItem(hwndFolderCtrl, _dlgItemTreeView)
 
                            If hwndTV <> IntPtr.Zero Then
                                Dim item As IntPtr = SendMessage(hwndTV, CUInt(TVM_GETNEXTITEM), New IntPtr(TVGN_CARET), IntPtr.Zero)
                                If item <> IntPtr.Zero Then
                                    SendMessage(hwndTV, TVM_ENSUREVISIBLE, IntPtr.Zero, item)
                                    retries = 0
                                    t.Stop()
                                End If
                            End If
                        End If
                    End If
 
                Else
                    '
                    '  We failed to find the Tree View control.
                    '
                    '  As a fall back (and this is an UberUgly hack), we will send
                    '  some fake keystrokes to the application in an attempt to force
                    '  the Tree View to scroll to the selected item.
                    '
                    t.Stop()
                    SendKeys.Send("{TAB}{TAB}{DOWN}{DOWN}{UP}{UP}")
                End If
            End Sub
 
            t.Interval = 10
            t.Start()
 
            result = dlg.ShowDialog(parent)
        End Using
 
        Return result
    End Function
End Module

Private Sub Button2_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button2.Click
        Dim fbd As New FolderBrowserDialog
        fbd.Description = "Выберите папку," & vbLf + "в которой находятся ведомости"
        fbd.SelectedPath = "E:\Jura\VBP\Разное\Editor\Var1.1"
        fbd.ShowNewFolderButton = False
 
        If ShowFolderBrowser(fbd) = DialogResult.OK Then
            sPath = fbd.SelectedPath
            Label1.Text = sPath
        End If
    End Sub