Нарисовать светофор со сменой цветов

Public Class Form1
    Dim Lbl As Label
    Sub Col(ByVal C As Color, ByVal H As Integer)
        Dim BM As New Bitmap(PictureBox2.Width, PictureBox2.Height)
        Dim G As Graphics = Graphics.FromImage(BM)
        G.FillRectangle(New SolidBrush(Color.FromArgb(30, 30, 30)), 100, 40, 100, 300)
        G.FillRectangle(New SolidBrush(C), New Rectangle(100, H, 100, 100))
        PictureBox2.BackgroundImage = BM
    End Sub
 
    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        PictureBox1.Parent = PictureBox2
    End Sub
 
    Private Sub Timer1_Tick(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Timer1.Tick
        Static Mode As Integer = 0
        Static Tick As Integer = 0
        If Mode = 0 Then
            Col(Color.Red, 40)
        End If
        If Mode = 1 Then
            If Tick Mod 2 = 0 Then
                Col(Color.Yellow, 140)
            Else
                Col(Color.Transparent, 140)
            End If
        End If
        If Mode = 2 Then Col(Color.Green, 240)
        If Tick = 0 Then
            If Mode = 0 Then MakeLbl("Red")
            If Mode = 1 Then MakeLbl("Yellow")
            If Mode = 2 Then MakeLbl("Green")
        End If
        Tick += 1
        If Tick > 10 Then Mode += 1 : Tick = 0
        If Mode = 3 Then Mode = 0
    End Sub
 
    Sub MakeLbl(ByVal Txt As String)
        Lbl = New Label With {.Left = Width, .Top = 400, .Text = Txt, .Font = New Font("Verdana", 12, FontStyle.Bold)}
        Controls.Add(Lbl) : Timer2.Start()
    End Sub
 
    Private Sub Timer2_Tick(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Timer2.Tick
        Lbl.Left -= 2
        If Lbl.Left < -Lbl.Width Then
            Controls.Remove(Lbl)
            Timer2.Stop()
        End If
    End Sub
 
    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
        Close()
    End Sub
End Class

Public Class TrafficLights
    Private _state As TrafficLightsEnum
 
    Public Property State() As TrafficLightsEnum
        Get
            Return _state
        End Get
        Set(ByVal value As TrafficLightsEnum)
            _state = value
            RaiseEvent OnStateChanged(value)
        End Set
    End Property
 
    Private Event OnStateChanged(ByVal e As TrafficLightsEnum)
    Public Event StateChanged(ByVal sender As TrafficLights, ByVal e As TrafficLightsEnum)
 
    Sub New()
        Me.State = TrafficLightsEnum.Red
        AddHandler OnStateChanged, AddressOf StateChange
    End Sub
 
    Public Sub New(state As TrafficLightsEnum)
        Me.State = state
        AddHandler OnStateChanged, AddressOf StateChange
    End Sub
 
    Public Overrides Function ToString() As String
        Select Case _state
            Case TrafficLightsEnum.Green
                Return "Зелёный"
            Case TrafficLightsEnum.Red
                Return "Красный"
            Case TrafficLightsEnum.Yellow
                Return "Жёлтый"
            Case TrafficLightsEnum.YellowRed
                Return "Переключение на зелёный"
            Case Else
                Return String.Empty
        End Select
    End Function
 
    Public Enum TrafficLightsEnum
        Red
        Yellow
        Green
        YellowRed
    End Enum
 
    Private Sub StateChange(e As TrafficLightsEnum)
        RaiseEvent StateChanged(Me, e)
    End Sub
 
    Public Sub ChangeState()
        Select Case _state
            Case TrafficLightsEnum.Green
                _state = TrafficLightsEnum.Yellow
            Case TrafficLightsEnum.Yellow
                _state = TrafficLightsEnum.Red
            Case TrafficLightsEnum.Red
                _state = TrafficLightsEnum.YellowRed
            Case TrafficLightsEnum.YellowRed
                _state = TrafficLightsEnum.Green
        End Select
        RaiseEvent OnStateChanged(_state)
    End Sub
End Class

Imports System.Drawing
Imports System.Drawing.Drawing2D
Public Class Form1
    Private WithEvents trl As New TrafficLights()
    Private WithEvents tmr As New Timer() With {.Interval = 1000}
    Private redGP, greenGP, yellowGP As GraphicsPath
 
    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles Me.Load
        AddHandler trl.StateChanged, AddressOf trl_StateChanged
        AddHandler tmr.Tick, AddressOf tmr_Tick
        redGP = New GraphicsPath()
        greenGP = New GraphicsPath()
        yellowGP = New GraphicsPath()
        redGP.AddEllipse(0, 0, Me.ClientSize.Width, Me.ClientSize.Height \ 3)
        yellowGP.AddEllipse(0, Me.ClientSize.Height \ 3, Me.ClientSize.Width, Me.ClientSize.Height \ 3)
        greenGP.AddEllipse(0, 2 * (Me.ClientSize.Height \ 3), Me.ClientSize.Width, Me.ClientSize.Height \ 3)
        tmr.Start()
    End Sub
 
 
    Private Sub trl_StateChanged(sender As TrafficLights, e As TrafficLights.TrafficLightsEnum)
        Me.Refresh()
    End Sub
 
    Private Sub tmr_Tick(sender As Object, e As EventArgs)
        trl.ChangeState()
    End Sub
 
    Private Sub Form1_Paint(sender As Object, e As PaintEventArgs) Handles Me.Paint
        Select Case trl.State
            Case TrafficLights.TrafficLightsEnum.Green
                With e.Graphics
                    .FillPath(Brushes.Green, greenGP)
                    .DrawPath(Pens.Black, redGP)
                    .DrawPath(Pens.Black, yellowGP)
                End With
            Case TrafficLights.TrafficLightsEnum.Red
                With e.Graphics
                    .FillPath(Brushes.Red, redGP)
                    .DrawPath(Pens.Black, greenGP)
                    .DrawPath(Pens.Black, yellowGP)
                End With
            Case TrafficLights.TrafficLightsEnum.Yellow
                With e.Graphics
                    .FillPath(Brushes.Yellow, yellowGP)
                    .DrawPath(Pens.Black, redGP)
                    .DrawPath(Pens.Black, greenGP)
                End With
            Case TrafficLights.TrafficLightsEnum.YellowRed
                With e.Graphics
                    .FillPath(Brushes.Yellow, yellowGP)
                    .FillPath(Brushes.Red, redGP)
                    .DrawPath(Pens.Black, greenGP)
                End With
        End Select
 
    End Sub
 
End Class