Для каждой строки текстового файла распечатать слово наибольшей длины, если их несколько, то распечатать все

program Project1;
 
const
  //Множество разделителей.
  D = ['.', ',', ':', ';', '!', '?', '-', ' ', #9, #10, #13];
  //Короткое имя файла.
  Fn = 'file.txt';
 
var
  F: TextFile;
  S, SRes, FileName: String;
  i, Len, LenW, LenMax: Integer;
 
begin
  //Переключение окна консоли на кодовую страницу CP1251 (Win-1251).
  //Если после переключения русские буквы показываются неверно,
  //следует открыть системное меню консольного окна - щелчком мыши в левом
  //верхнем углу окна консоли и выбрать:
  //Свойства - закладка "Шрифт" - выбрать шрифт: "Lucida Console".
  
  FileName := ExtractFilePath(ParamStr(0)) + Fn;
  AssignFile(F, FileName);
  repeat
    Writeln('--------------------------------------------------');
    Writeln('Файл: ' + FileName);
    Reset(F);
    while not Eof(F) do 
    begin
      Readln(F, S);
      Len := Length(S);
      LenW := 0; //Длина текущего слова.
      LenMax := 0; //Текущая наибольшая длина слова.
      SRes := ''; //Строка результата.
      for i := 1 to Len do 
      begin
        if S[i] in D then Continue; //Пропуск разделителей.
        Inc(LenW); //Уточнение длины очередного слова.
        if (i = Len) or (S[i + 1] in D) then begin//Если найден конец слова.
          //Если длина текущего слова больше текущей наибольшей, то начинаем составлять строку результата заново.
          if LenW > LenMax then begin
            LenMax := LenW;
            SRes := Copy(S, i - LenW + 1, LenW);
            //Если длина текущего слова равна наибольшей, то добавляем слово в строку результата.
          end else if LenW = LenMax then
            SRes := SRes + ', ' + Copy(S, i - LenW + 1, LenW);
          LenW := 0;
        end;
      end;
      //Распечатка результатов по очередной строке.
      Writeln('Строка: ' + S);
      Writeln('Перечень слов с наибольшей длиной: ' + SRes);
    end;
    CloseFile(F);
    
    Writeln('Повторить - Enter. Выход - любой символ + Enter.');
    Readln(S);
  until S <> '';
end.