Сформировать одномерный массив, каждый элемент которого равен латинской букве

@ктм · Регистрация: 09.01.2016

Author24 — интернет-сервис помощи студентам

Дана неквадратная матрица строк. Сформировать одномерный массив, каждый элемент которого равен латинской букве, которая наиболее часто используется при записи элементов соответствующей строки. (помогите написать прогу, где описывается последнее условие)

@bormant · 09.01.2016, 02:27

Pascal

const m=3; n=2;
var
  a: array [1..m,1..n] of String[31];
  b: array [1..m] of Char;
  c: array ['A'..'Z'] of Integer;
  i, j, k: Integer;
  d, mx: Char;
begin
  for i:=1 to m do begin
    FillChar(c,SizeOf(c),#0);
    for j:=1 to n do begin
      Write('a[',i,',',j,']: '); ReadLn(a[i,j]);
      for k:=1 to Length(a[i,j]) do
        if a[i,j][k] in ['A'..'Z','a'..'z'] then
          Inc(c[UpCase(a[i,j][k])]);
    end;
    mx:='A'; for d:='B' to 'Z' do if c[mx]<c[d] then mx:=d;
    b[i]:=mx; WriteLn('Строка ',i,': ',b[i]);
  end;
end.

Добавлено через 4 минуты
При такой постановке можно было и вовсе без массивов обойтись:

Pascal

const m=3; n=2;
var
  a: String[31];
  c: array ['A'..'Z'] of Integer;
  i, j, k: Integer;
  d, mx: Char;
begin
  for i:=1 to m do begin
    FillChar(c,SizeOf(c),#0);
    for j:=1 to n do begin
      Write('a[',i,',',j,']: '); ReadLn(a);
      for k:=1 to Length(a) do
        if a[k] in ['A'..'Z','a'..'z'] then
          Inc(c[UpCase(a[k])]);
    end;
    mx:='A'; for d:='B' to 'Z' do if c[mx]<c[d] then mx:=d;
    WriteLn('Строка ',i:2,': ',mx);
  end;
end.

Добавлено через 3 минуты
И даже вывести несколько букв при равенстве количества вхождений:

Pascal

const m=3; n=2;
var
  a: String[31];
  c: array ['A'..'Z'] of Integer;
  i, j, k: Integer;
  d, mx: Char;
begin
  for i:=1 to m do begin
    FillChar(c,SizeOf(c),#0);
    for j:=1 to n do begin
      Write('a[',i,',',j,']: '); ReadLn(a);
      for k:=1 to Length(a) do
        if a[k] in ['A'..'Z','a'..'z'] then
          Inc(c[UpCase(a[k])]);
    end;
    mx:='A'; for d:='B' to 'Z' do if c[mx]<c[d] then mx:=d;
    Write('Строка ',i:2,':');
    for d:=mx to 'Z' do if c[d]=c[mx] then Write(' ',d); WriteLn;
  end;
end.

@ктм · 09.01.2016, 11:09 **[ТС]**

спасибо, но если не сложно могли бы в прокомментировать все с 11 строчки.

@bormant · 09.01.2016, 11:24

Для каждой строки массива
.обнуляем счетчик вхождения латиницы (массив c)

..Для каждого строкового элемента строки массива
...выдаем подсказку, вводим элемент
...считаем количество латиницы в нем побуквенно

.В c ищем максимум, его индекс -- искомый частый символ
.Присваиваем найденное I-му элементу формируемого массива, выводим.

Добавлено через 6 минут
Проверку на латиницу можно переписать так:

Pascal

14
15

        if UpCase(a[i,j][k]) in ['A'..'Z'] then
          Inc(c[UpCase(a[i,j][k])]);

@ктм · 09.01.2016, 22:20 **[ТС]**

ааааа, понял! спасибо

Добавлено через 7 часов 36 минут
если я так напишу, то ничего же не изменится?

Pascal

const m=3; n=2;
var a:array[1..m,1..n] of string;
    b:array['a'..'z'] of integer;
    c:array[1..m]of char;
    l,bmax:char;
    i,j,t,max:integer;
 
BEGIN
max:=0;
writeln('a[',i,',',j,']: ');
for i:=1 to m do
  begin
  for j:=1 to n do
    begin
    readln(a[i,j]);
    for t:=1 to length(a[i,j]) do
      if a[i,j][t] in ['a'..'z'] then b[a[i,j][t]]:=b[a[i,j][t]]+1;
    end;
  for l:='a' to 'z' do
    begin
    if b[l]> max then begin max:=b[l]; bmax:=l; end;
    b[l]:=0;
    end;
  c[i]:=bmax;
  max:=0;
  end;
writeln;
for i:=1 to m do write(c[i],' ');
END.

@bormant · 09.01.2016, 23:39

ктм,
пользуйтесь тегом PASCAL, невозможно же читать...

Зачем выводить "a[0,0]: " перед вводом в цикле?
Max достаточно обнулять во внешнем цикле по строке перед использованием.

@ктм · 09.01.2016, 23:44 **[ТС]**

хорошо, я вас понял. Еще раз спасибо

@ктм 1 / 1 / 2 Регистрация: 09.01.2016 Сообщений: 44
		1
	Сформировать одномерный массив, каждый элемент которого равен латинской букве 09.01.2016, 00:52. Показов 1077. Ответов 6 Метки нет (Все метки) Дана неквадратная матрица строк. Сформировать одномерный массив, каждый элемент которого равен латинской букве, которая наиболее часто используется при записи элементов соответствующей строки. (помогите написать прогу, где описывается последнее условие) 0

@ктм 1 / 1 / 2 Регистрация: 09.01.2016 Сообщений: 44
	09.01.2016, 11:09 [ТС]	3
	спасибо, но если не сложно могли бы в прокомментировать все с 11 строчки. 0

@bormant Модератор 7794 / 4617 / 2830 Регистрация: 22.11.2013 Сообщений: 13,112 Записей в блоге: 1
	09.01.2016, 23:39	6
	ктм, пользуйтесь тегом PASCAL, невозможно же читать... Зачем выводить "a[0,0]: " перед вводом в цикле? Max достаточно обнулять во внешнем цикле по строке перед использованием. 0

@ктм 1 / 1 / 2 Регистрация: 09.01.2016 Сообщений: 44
	09.01.2016, 23:44 [ТС]	7
	хорошо, я вас понял. Еще раз спасибо 0

Сформировать одномерный массив, каждый элемент которого равен латинской букве

Решение