Перемножение двух чисел, количество цифр в каждом из которых может достигать 100

type
  TBigNum = String;
 
procedure SetLength(var s: String; n: Byte);
begin
  s[0]:=Chr(n);
end;
 
function bnAdd(const a, b: TBigNum): TBigNum;
var
  s: TBigNum;
  i, j, k, c: Integer;
begin
  i:=Length(a); j:=Length(b);
  if j<i then k:=i else k:=j;
  SetLength(s,k); c:=0;
  while (i>0) and (j>0) do begin
    c:=c+Ord(a[i])+Ord(b[j])-2*Ord('0');
    s[k]:=Chr(c mod 10+Ord('0')); c:=c div 10;
    Dec(i); Dec(j); Dec(k);
  end;
  while i>0 do begin
    c:=c+Ord(a[i])-Ord('0');
    s[k]:=Chr(c mod 10+Ord('0')); c:=c div 10;
    Dec(i); Dec(k);
  end;
  while j>0 do begin
    c:=c+Ord(b[j])-Ord('0');
    s[k]:=Chr(c mod 10+Ord('0')); c:=c div 10;
    Dec(j); Dec(k);
  end;
  if c>0 then s:=Chr(c mod 10+Ord('0'))+s;
  if s='' then bnAdd:='0' else bnAdd:=s;
end;
 
function bnMul(const a, b: TBigNum): TBigNum;
var
  pa, pb: ^TBigNum;
  p, s, o: TBigNum;
  i, j, c, d: Integer;
begin
  if Length(a)<Length(b)
  then begin pa:=@b; pb:=@a; end
  else begin pa:=@a; pb:=@b; end;
  p:=''; o:=''; c:=0;
  for j:=Length(pb^) downto 1 do begin
    if pb^[j]>'0' then begin
      SetLength(s,Length(pa^)); d:=Ord(pb^[j])-Ord('0');
      for i:=Length(pa^) downto 1 do begin
        c:=c+d*(Ord(pa^[i])-Ord('0'));
        s[i]:=Chr(c mod 10+Ord('0')); c:=c div 10;
      end;
      while c>0 do begin
        s:=Chr(c mod 10+Ord('0'))+s; c:=c div 10;
      end;
      p:=bnAdd(p,s+o);
    end;
    o:=o+'0';
  end;
  if p='' then bnMul:='0' else bnMul:=p;
end;
 
var
  a, b: TBigNum;
begin
  Write(  '  a='); ReadLn(a);
  Write(  '  b='); ReadLn(b);
  WriteLn('a*b=',bnMul(a,b));
end.