Написать рекурсивную процедуру для однонаправленного списка: сколько раз входит данный элемент в однонаправленных список

uses
  crt;
type
  TData  = real;
  TPNode = ^TNode;
  TNode  = record
  Data : TData;
  Next : TPNode;
  end;
  TList = record
  First, Last : TPNode;
  end;
//  добавляет элемент в конец списка
procedure AddList(var aList : TList; n : TData);
var aL : TList;
begin
  If aList.Last = nil then begin
    New(aList.Last);
    aList.Last^.Data := n;
    aList.First := aList.Last;
  end else begin
    aL.First := nil;
    aL.Last := nil;
    AddList(aL,n);
    aList.Last^.Next := aL.First;
    aList.Last := aL.Last;
  end;
  aList.Last^.Next := nil;
end;
//  выводит список
procedure Print(aList : Tlist);
begin
  if aList.First = nil then writeln('.')
  else begin 
    write(aList.First^.Data:7:2);
    aList.First := aList.First^.Next;  
    Print(aList);
  end;
end; 
procedure NumbElem(aList : TList; aPElem : TData; var aNumb : word);
var PTmp : TPNode;
begin
  if aList.First = nil then aNumb := 0
  else begin
    PTmp := aList.First;
    aList.First := aList.First^.Next;
    NumbElem(aList,aPElem,aNumb);
    if aPElem = PTmp^.Data then inc(aNumb);
  end;
end; 
//освобождает память
procedure FreeMemor(var aList : Tlist);
var PElem : TPNode;
begin
  if aList.First = nil then aList.Last := nil
  else begin
    PElem := aList.First;
    aList.First := aList.First^.Next;
    Dispose(PElem);
    FreeMemor(aList);
  end;
end;
var
  L   : TList;
  i, n : word;
  a    : TData;
begin
  clrscr;
  write('List size : '); readln(n); 
  L.First := nil;
  L.Last  := nil;
  for i := 1 to n do begin
    write(i,'-oe number : '); readln(a);
    AddList(L,a);
  end; 
  writeln(#10,#13,'List L :');
  Print(L); 
  write('Enter element : '); readln(a);
  NumbElem(L,a,i);
  writeln('Number of elements ',a:0:2,' in the List L : ',i);
  FreeMemor(L);
  readln;
end.