Сортировка строк матрицы по убыванию

@snob · Регистрация: 22.10.2012

Author24 — интернет-сервис помощи студентам

Сортировка строк матрицы по убыванию

Задание было такое, отсортировать по убыванию каждую строку матриц 3x4 и 2x5, с использованием нетипизированного параметра.

В общем у меня получилось такая вот штука:

Pascal

program matrica;
type matrix=array[1..100,1..100] of byte;
var i,j,n,buf,a,b:byte;
mat:matrix;
 
procedure gen(var m; a,b:byte);
begin
 randomize;
 for i:=1 to a do
 for j:=1 to b do
 matrix(m)[i,j]:=random(99);
end;
 
procedure obr(var m; a,b:byte);
begin
 for i:=1 to n do
  for j:=1 to n-i do
   if matrix(m)[i,j]>matrix(m)[i,j+1] then
   begin
    buf:=matrix(m)[i,j];
    matrix(m)[i,j]:=matrix(m)[i,j+1];
    matrix(m)[i,j+1]:=buf;
   end;
end;
 
procedure vyvod(var m; a,b:byte);
begin
 for i:=1 to a do begin
  for j:=1 to b do
  write(matrix(m)[i,j]:4);
  writeln;
  end;
 end;
 
 begin
 write('Vvedite razmer matrici: ');
 readln(a,b);
 writeln;
 gen(mat,a,b);
 writeln('polychivshaysya matrica: ');
 vyvod(mat,a,b);
 writeln;
 obr(mat,a,b);
 writeln('s perepisanumi strokami: ');
 vyvod(mat,a,b);
 readln;
 end.

но у меня что то с сортировкой не выходит, не пойму что не так. Всё вроде по примеру сортировки стандартным обменом делал...

Добавлено через 30 минут
извините за созданную тему, сам разобрался, можете удалить тему админы или модераторы не знаю как правильно

Добавлено через 17 минут
сам разобрался вот результат

Pascal

program matrica;
type matrix=array[1..100,1..100] of byte;
var i,j,n,buf,a,b:byte;
mat:matrix;
f:boolean;
 
procedure gen(var m; a,b:byte);
begin
 randomize;
 for i:=1 to a do
 for j:=1 to b do
 matrix(m)[i,j]:=random(99);
end;
 
procedure obr(var m; a,b:byte);
begin
 for i:=1 to a do
 repeat
  f:=true;
  for j:=1 to b-1 do
   if matrix(m)[i,j+1]>matrix(m)[i,j] then
   begin
    buf:=matrix(m)[i,j];
    matrix(m)[i,j]:=matrix(m)[i,j+1];
    matrix(m)[i,j+1]:=buf;
    f:=false;
   end;
  until f; 
end;
 
procedure vyvod(var m; a,b:byte);
begin
 for i:=1 to a do begin
  for j:=1 to b do
  write(matrix(m)[i,j]:4);
  writeln;
  end;
 end;
 
 begin
 write('Vvedite razmer matrici: ');
 readln(a,b);
 writeln;
 gen(mat,a,b);
 writeln('polychivshaysya matrica: ');
 vyvod(mat,a,b);
 writeln;
 obr(mat,a,b);
 writeln('s perepisanumi strokami: ');
 vyvod(mat,a,b);
 readln;
 end.

Исправлено с 15 по 30 строчку

@bormant · 03.04.2014, 00:25

Если пройдет проверку, хорошо. Но, скорее всего, будет завернуто, в таком решении смысла в нетипизированном параметре нет, он не добавляет гибкости. Скорее всего имелось в виду что-то вроде:

Pascal

const
  LIM=100; W=3;
procedure SortInt(var Integers; Size: integer);
var
  m: array [0..65535 div 2 - 1] of integer absolute Integers;
  i, t: integer;
  done: boolean;
begin
  dec(Size);
  repeat
    done:=true;
    for i:=1 to Size do
      if m[i-1]<m[i] then begin
        t:=m[i-1]; m[i-1]:=m[i]; m[i]:=t; done:=false;
      end;
  until done;
end;
var
  a: array [1..3,1..4] of integer;
  b: array [1..2,1..5] of integer;
  i, j: integer;
begin
  Randomize;
  WriteLn('A=');
  for i:=1 to 3 do begin
    for j:=1 to 4 do begin
      a[i,j]:=Random(100); Write(a[i,j]:W);
    end; WriteLn;
    SortInt(a[i],4);
  end;
  WriteLn('B=');
  for i:=1 to 2 do begin
    for j:=1 to 5 do begin
      b[i,j]:=Random(100); Write(b[i,j]:W);
    end; WriteLn;
    SortInt(b[i],5);
  end;
  WriteLn('После сортировки');
  WriteLn('A=');
  for i:=1 to 3 do begin
    for j:=1 to 4 do Write(a[i,j]:W); WriteLn;
  end;
  WriteLn('B=');
  for i:=1 to 2 do begin
    for j:=1 to 5 do Write(b[i,j]:W); WriteLn;
  end;
end.

Обратите внимание, нетипизированный параметр позволил передавать на сортировку разнотипные массивы, процедура сортирует первые Size элементов переданного массива, большего от нее не требуется.

	03.04.2014, 00:25