Изменить программу интегрирования методом второго порядка - Pascal ABC - Ответ 7309980

program RungeKutta4;
 
  function f(t, y: real): real;
  begin
    f := exp(-t) * (exp(-t) - 1);
  end;
 
  procedure RungeKutta4Step(var t, y: real; h: real);
  var
    k1, k2, k3, k4: real;
  begin
    k1 := f(t, y);
    k2 := f(t + (h / 2), y + k1 * (h / 2));
    k3 := f(t + (h / 2), y + k2 * (h / 2));
    k4 := f(t + h, y + k3 * h);
    y  := y + (k1 + 2 * k2 + 2 * k3 + k4) * h / 6;
    t  := t + h;
  end;
 
  procedure RungeKutta4(t0, tfin, h, y0: real; var yfin: real; Show: boolean);
  var
    t: real;
    y: real;
  begin
    t := t0;
    y := y0;
    if Show then
      writeln('y(', t: 12: 5, ')=', y: 12: 5);
    while t <= tfin do
    begin
      RungeKutta4Step(t, y, h);
      if Show then
        writeln('y(', t: 12: 5, ')=', y: 12: 5);
    end;
    yfin := y;
  end;
 
  procedure Differ(t0, tfin, y0: real; eps: real);
  var
    h: real;
    y1, y2: real;
  begin
    h := (tfin - t0) / 1;
    RungeKutta4(t0, tfin, h, y0, y2, False);
    repeat
      y1 := y2;
      h  := h / 2;
      RungeKutta4(t0, tfin, h, y0, y2, False);
    until abs(y2 - y1) < eps;
    RungeKutta4(t0, tfin, h, y0, y2, True);
  end;
 
begin
  Differ(0, 35, -0.5, 0.001);
end.