Ограничение на ввод из другой таблицы - MS Access - Ответ 4414473

Option Explicit
 
Dim IdOld, NumOld, IdNew, NumNew
 
Private Sub Form_AfterDelConfirm(Status As Integer)
  If Status = acDeleteOK Then
    CurrentDb.Execute "UPDATE Продукция SET [Наличие на складе]= [Наличие на складе]+" & _
              NumNew & " WHERE Код_продук=" & IdNew
  End If
End Sub
 
Private Sub Form_AfterUpdate()
  If Not (IdOld = IdNew And NumOld = NumNew) Then
    CurrentDb.Execute "UPDATE Продукция SET [Наличие на складе]= [Наличие на складе]+" & _
              IIf(IdOld = IdNew, NumOld, 0) - NumNew & " WHERE Код_продук=" & IdNew
    If (Not (IdOld = IdNew)) And Len(IdOld & "") > 0 Then
      CurrentDb.Execute "UPDATE Продукция SET [Наличие на складе]= [Наличие на складе]+" & _
                         NumOld & " WHERE Код_продук=" & IdOld
    End If
  End If
End Sub
 
Private Sub Form_BeforeUpdate(Cancel As Integer)
Dim NumWarehouse&
  If IsNull(Me!Код_заказа) Or IsNull(Me!id_продукции) Then
    MsgBox "Заполните поле id_продукции"
    Cancel = True
  ElseIf Nz(Me![Кол-во прод], 0) <= 0 Then
    MsgBox "Заполните поле Кол-во прод"
    Cancel = True
  Else
    IdOld = Me!id_продукции.OldValue
    NumOld = Nz(Me![Кол-во прод].OldValue, 0)
    IdNew = Me!id_продукции.Value
    NumNew = Me![Кол-во прод].Value
    NumWarehouse = DLookup("[Наличие на складе]", "Продукция", "Код_продук=" & IdNew)
    If NumWarehouse - NumNew + IIf(IdOld = IdNew, NumOld, 0) < 0 Then
      MsgBox "Затребованное количество продукции превышает наличие на складе"
      Cancel = True
    End If
  End If
  If Not Cancel Then Me![Итоговая цена] = Me![Итог цена]
End Sub
 
Private Sub Form_Delete(Cancel As Integer)
  IdNew = Me!id_продукции.Value
  NumNew = Me![Кол-во прод].Value
End Sub