Неправильно работает ..класс.... - Delphi - Ответ 319834

@Mawrat · 25.10.2009, 02:40

Готово. Сделал на основе динамического массива. Добавил методы загрузки/выгрузки библиотеки из/в файл(а).

В приложенный архив я ещё файл ярлыка положил - если через этот файл программу запустить, то работать будет удобнее - там увеличено число строк и столбцов для консольного окна.

Delphi

program HomeLibrary;
 
{$APPTYPE CONSOLE}
 
uses
  SysUtils,
  uTHomeLib in 'uTHomeLib.pas';
 
var
  HomeLib : THomeLib;
begin
  HomeLib := THomeLib.Create;
  HomeLib.ConsoleMain;
  HomeLib.Destroy;
end.

Delphi

unit uTHomeLib;
 
interface
 
type
 
  //Книга.
  TBook = record
    //Название книги.
    Name            : String;
    //Автор.
    Author          : String;
    //Год издания.
    Year            : Integer;
 
    //Индекс в массиве.
    Index           : Integer;
  end;
 
  //Тип, задающий динамический массив для хранения книг.
  TArrBook          = array of TBook;
 
  //Книга пригодная для записи в типизированный файл.
  TBookPack = record
    //Название книги.
    Name            : String[50];
    //Автор.
    Author          : String[50];
    //Год издания.
    Year            : Integer;
 
    //Индекс в массиве.
    Index           : Integer;
  end;
 
  THomeLib = class (TObject)
  private
    //Массив для хранения сведений о книгах библиотеки. Вид массива - динамический.
    FArrBook        : TArrBook;
    //Количество книг в библиотеке. Это количество значимых элементов (книг) в массиве FArrBook.
    FCountBook      : Integer;
    //Этот параметр задаёт шаг увеличения длины массива FArrBook.
    //Т. е. когда нам нужно увеличить длину массива FArrBook, тогда мы будем увеличивать
    //её (длину массива) на величину FCapacity.
    FCapacity       : Integer;
  protected
    //Метод для сравнения двух книг. Этот метод применяется в процедурах сортировки.
    //True, если: aBook1 > aBook2
    //False, если: aBook1 <= aBook2
    function CompareBook(aBook1, aBook2 : TBook) : Boolean;
  public
    //Конструктор класса.
    constructor Create;
    //Деструктор класса.
    destructor Destroy; override;
 
    //Показывает количество книг в библиотеке.
    function GetCountBook() : Integer;
    //Добавляет новую книгу в конец списка.
    procedure AddBook(aBook : TBook);
    //Возвращает книгу по её индексу.
    function GetBook(aIndex : Integer) : TBook;
    //Удаление книги из библиотеки.
    procedure DeleteBook(aIndex : Integer);
    //Удаление всех книг из массива (из библиотеки).
    procedure Clear();
    //Сортировка книг библиотеки по автору / имени / году издания.
    procedure Sort();
 
    //--------------------------------------------------------------------------
    //Методы, которые не обращаются напрямую к private полям.
    //--------------------------------------------------------------------------
 
    //Поиск книг по названию и автору.
    function FindBook(var aArrBook : TArrBook; aName : String; aAuthor : String = '') : Boolean;
 
    //Процедура записи библиотеки в файл.
    function SaveToFile(aFileName : String) : Boolean;
    //Процедура загрузки библиотеки из файла.
    function LoadFromFile(aFileName : String) : Boolean;
 
    //Методы для взаимодействия с пользователем через консоль.
 
    procedure ConsoleAddBook();
    procedure ConsoleDeleteBook();
    procedure ConsoleFindBook();
    procedure ConsoleSort();
    procedure ConsoleShowAllBook();
    procedure ConsoleClear();
    procedure ConsoleLoadFromFile();
    procedure ConsoleSaveToFile();
    procedure ConsoleMain();
  end;
 
implementation
 
uses
  SysUtils, Windows;
 
//Функция берёт строку в ANSI кодировке (Windows)
//и возвращает её перевод в OEM кодировку (DOS) в виде отдельной строки.
function AnsiToOem(aStr : String) : String;
begin
  Result := '';
  if Length(aStr) > 0 then begin
    SetLength(Result, Length(aStr));
    CharToOem(PChar(aStr), PChar(Result));
  end;
end;
 
{ THomeLib }
 
constructor THomeLib.Create;
begin
  inherited Create;
  FCapacity := 10;
  FCountBook := 0;
end;
 
destructor THomeLib.Destroy;
begin
  //Освобождаем память, выделенную для массива FArrBook;
  Finalize(FArrBook);
  inherited Destroy;
end;
 
function THomeLib.GetCountBook: Integer;
begin
  Result := FCountBook;
end;
 
procedure THomeLib.AddBook(aBook: TBook);
begin
  //Подсчитываем общее количество книг в массиве.
  Inc(FCountBook);
  //Если требуется, увеличиваем длину массива FArrBook.
  if FCountBook > Length(FArrBook) then begin
    //Длину массива FArrBook увеличиваем на величину FCapacity элементов.
    SetLength(FArrBook, Length(FArrBook) + FCapacity);
  end;
  //Добавляем в массив новую книгу.
  FArrBook[FCountBook - 1] := aBook;
end;
 
function THomeLib.GetBook(aIndex: Integer): TBook;
begin
  Result := FArrBook[aIndex];
  Result.Index := aIndex;
end;
 
procedure THomeLib.DeleteBook(aIndex: Integer);
var
  i : Integer;
begin
  //Удаляем книгу с индексом aIndex.
  //Удаление заключается в сдвиге всех книг, расположенных правее этого индекса
  //на одну позицию влево.
  for i := aIndex to FCountBook - 1 do begin
    FArrBook[i] := FArrBook[i + 1];
  end;
  //Подсчитываем общее количество книг в массиве.
  Dec(FCountBook);
  //Если требуется, уменьшаем длину массива FArrBook.
  if FCountBook + 2 * FCapacity < Length(FArrBook) then begin
    SetLength(FArrBook, FCountBook + FCapacity);
  end;
end;
 
procedure THomeLib.Clear;
begin
  //Освобождаем память, выделенную ранее для массива FArrBook.
  Finalize(FArrBook);
  //Количество книг теперь равно нулю.
  FCountBook := 0;
end;
 
function THomeLib.CompareBook(aBook1, aBook2: TBook): Boolean;
const
  //Массив весовых коэффициентов.
  ArrWeight : array[1..3] of Integer = (2, 4, 8);
var
  //Баланс веса при сравнении двух книг.
  Weight : Integer;
begin
  Weight := 0;
 
  if aBook1.Author > aBook2.Author then begin
    Weight := Weight + ArrWeight[3];
  end else begin
    Weight := Weight - ArrWeight[3];
  end;
 
  if aBook1.Name > aBook2.Name then begin
    Weight := Weight + ArrWeight[2];
  end else begin
    Weight := Weight - ArrWeight[2];
  end;
 
  if aBook1.Name > aBook2.Name then begin
    Weight := Weight + ArrWeight[1];
  end else begin
    Weight := Weight - ArrWeight[1];
  end;
 
  if Weight > 0 then begin
    //aBook1 > aBook2.
    Result := True;
  end else begin
    //aBook1 <= aBook2.
    Result := False;
  end;
 
end;
 
//Сортировка книг по возрастанию.
//Применён метод перестановок "наименьших".
procedure THomeLib.Sort;
var
  i, j, jMin  : Integer;
  Book       : TBook;
begin
  for i := 0 to FCountBook - 1 - 1 do begin
    jMin := i;
    for j := i + 1 to FCountBook - 1 do begin
      if CompareBook(FArrBook[jMin], FArrBook[j]) then begin
        jMin := j;
      end;
    end;
    if i < jMin then begin
      Book := FArrBook[i];
      FArrBook[i] := FArrBook[jMin];
      FArrBook[jMin] := Book;
    end;
  end;
end;
 
//------------------------------------------------------------------------------
//Методы, которые не обращаются напрямую к private переменным.
//------------------------------------------------------------------------------
 
function THomeLib.FindBook(var aArrBook: TArrBook; aName,
  aAuthor : String) : Boolean;
const
  Capacity    : Integer = 10;
var
  i            : Integer;
  Compare      : Boolean;
  Count        : Integer;
begin
  Result := False;
  SetLength(aArrBook, 0);
 
  //Ищем книги, которые подходят по названию и автору.
  Count := 0;
  for i := 0 to Pred(GetCountBook) do begin
 
    //Определяем: подходит ли текущая книга под заданный шаблон.
    Compare :=
      ( aName = Copy( GetBook(i).Name, 1, Length(aName) ) )
      and ( aAuthor = Copy( GetBook(i).Author, 1, Length(aAuthor) ) )
    ;
 
    //Если текущая книга соответствует заданному шаблону,
    //то добавляем её в результирующий массив.
    if Compare then begin
      Inc(Count);
      //Увеличиваем длину результирующего массива, если требуется.
      if Length(aArrBook) < Count then begin
        SetLength(aArrBook, Length(aArrBook) + Capacity);
      end;
      //Добавляем книгу в результирующий массив.
      aArrBook[Count - 1] := GetBook(i);
    end;
 
  end;
 
  //Корректируем длину результирующего массива в соответствии с количеством
  //добавленных в него книг.
  SetLength(aArrBook, Count);
  Result := True;
end;
 
//Загрузка книг из файла.
function THomeLib.LoadFromFile(aFileName : String) : Boolean;
var
  //Файловая переменная.
  f           : file of TBookPack;
  //Книга пригодная для записи в типизированный файл.
  BookPack    : TBookPack;
  //Книга библиотеки.
  Book        : TBook;
begin
  //Связываем файловую переменную с именем файла.
  AssignFile(f, aFileName);
  try
    //Открываем файл в режиме "только чтение".
    Reset(f);
    //Очищаем библиотеку.
    Clear;
    //Последовательно читаем из файла книги и помещаем их в библиотеку.
    while not Eof(f) do begin
      //Чтение очредной книги.
      Read(f, BookPack);
      //Преобразование книги.
      Book.Name := BookPack.Name;
      Book.Author := BookPack.Author;
      Book.Year := BookPack.Year;
      Book.Index := BookPack.Index;
      //Запись книги в библиотеку.
      AddBook(Book);
    end;
    //Закрываем файл
    CloseFile(f);
    //Успешное завершение операции.
    Result := True;
  except
    //При выполнении возникли ошибки.
    Result := False;
  end;
end;
 
//Запись книг библиотеки в файл.
function THomeLib.SaveToFile(aFileName : String) : Boolean;
var
  //Файловая переменная.
  f           : file of TBookPack;
  //Книга пригодная для записи в типизированный файл.
  BookPack    : TBookPack;
  //Счётчик.
  i           : Integer;
begin
  //Связыаем файловую переменную с именем файла.
  AssignFile(f, aFileName);
  try
    //Перезаписываем файл (создаём файл). И открываем его в режиме "только запись".
    Rewrite(f);
    //Записываем в файл последовательно все книги библиотеки.
    for i := 0 to GetCountBook - 1 do begin
      //Преобразовываем книгу.
      BookPack.Name := GetBook(i).Name;
      BookPack.Author := GetBook(i).Author;
      BookPack.Year := GetBook(i).Year;
      BookPack.Index := GetBook(i).Index;
      //Записываем книгу в файл.
      Write(f, BookPack);
    end;
    //Закрываем файл.
    CloseFile(f);
    //Успешное завершение операции.
    Result := True;
  except
    //При выполнении возникли ошибки.
    Result := False;
  end;
end;
 
//Консольный диалог добавления книги.
procedure THomeLib.ConsoleAddBook;
var
  StrTmp : String;
  Book   : TBook;
begin
  repeat
    Writeln('------------------------------');
    Writeln(AnsiToOem( 'Добавление книги в библиотеку.' ));
    Write(AnsiToOem( 'Введите автора:' ));
    Readln(Book.Author);
    Write(AnsiToOem( 'Введите название книги:' ));
    Readln(Book.Name);
    Write(AnsiToOem( 'Введите год издания:' ));
    Readln(Book.Year);
    AddBook(Book);
    Write(AnsiToOem( 'Продолжить добавление книг: пробел + ENTER. Выход - только ENTER.:' ));
    Readln(StrTmp);
  until StrTmp = '';
end;
 
//Консольный диалог удаления книги.
procedure THomeLib.ConsoleDeleteBook;
var
  StrTmp : String;
begin
  repeat
    Writeln('------------------------------');
    Write(AnsiToOem( 'Удаление книги: индекс удаляемой книги + ENTER. Выход - только ENTER.:' ));
    Readln(StrTmp);
    if StrTmp <> '' then begin
      DeleteBook(StrToInt(StrTmp));
      Writeln(AnsiToOem( 'Книга удалена.' ));
    end;
  until StrTmp = '';
end;
 
//Консольный диалог поиска книг.
procedure THomeLib.ConsoleFindBook;
var
  StrTmp    : String;
  Book      : TBook;
  ArrBook   : TArrBook;
  i          : Integer;
begin
  repeat
    Writeln('------------------------------');
    Writeln(AnsiToOem( 'Поиск книг в библиотеке.' ));
    Write(AnsiToOem( 'Первые буквы в строке автора:' ));
    Readln(Book.Author);
    Write(AnsiToOem( 'Первые буквы названия книги:' ));
    Readln(Book.Name);
    if FindBook(ArrBook, Book.Name, Book.Author) then begin
      Writeln(AnsiToOem( 'Найдено книг: ' + IntToStr(Length(ArrBook)) ));
      //Показываем найденные книги по одной.
      for i := Low(ArrBook) to High(ArrBook) do begin
        Writeln('------------------------------');
        Write(AnsiToOem( 'Автор:' ));
        Writeln(ArrBook[i].Author);
        Write(AnsiToOem( 'Название книги:' ));
        Writeln(ArrBook[i].Name);
        Write(AnsiToOem( 'Год издания:' ));
        Writeln( IntToStr(ArrBook[i].Year) );
        Write(AnsiToOem( 'Индекс в библиотеке:' ));
        Writeln( IntToStr(ArrBook[i].Index) );
        if i < High(ArrBook) then begin
          Write(AnsiToOem( 'Следующая книга: пробел + ENTER. Выход - только ENTER.:' ));
          Readln(StrTmp);
          if StrTmp = '' then begin
            Break;
          end;
        end;
      end;
      Finalize(ArrBook);
    end else begin
      Writeln(AnsiToOem( 'По вашему запросу не найдено ни одной книги.' ));
    end;
    Writeln('------------------------------');
    Write(AnsiToOem( 'Повторить поиск: пробел + ENTER. Выход - только ENTER.:' ));
    Readln(StrTmp);
  until StrTmp = '';
end;
 
//Консольный диалог сортировки книг в библиотеке.
procedure THomeLib.ConsoleSort;
begin
  Sort;
  Writeln('------------------------------');
  Writeln(AnsiToOem( 'Сортировка произведена.' ));
end;
 
//Консольный диалог показа всех книг библиотеки.
procedure THomeLib.ConsoleShowAllBook;
var
  i        : Integer;
  StrTmp   : String;
begin
  if GetCountBook = 0 then begin
    Writeln('------------------------------');
    Writeln(AnsiToOem( 'В библиотеке нет ни одной книги.' ));
    Exit;
  end;
  //Показываем книги последовательно, по одной.
  for i := 0 to GetCountBook - 1 do begin
    Writeln('------------------------------');
    Write(AnsiToOem( 'Автор:' ));
    Writeln(GetBook(i).Author);
    Write(AnsiToOem( 'Название книги:' ));
    Writeln(GetBook(i).Name);
    Write(AnsiToOem( 'Год издания:' ));
    Writeln( IntToStr(GetBook(i).Year) );
    Write(AnsiToOem( 'Индекс в библиотеке:' ));
    Writeln( IntToStr(GetBook(i).Index) );
    if i < GetCountBook - 1 then begin
      Write(AnsiToOem( 'Следующая книга: пробел + ENTER. Выход - только ENTER.:' ));
      Readln(StrTmp);
      if StrTmp = '' then begin
        Break;
      end;
    end;
  end;
end;
 
//Консольный диалог удаления всех книг из библиотеки.
procedure THomeLib.ConsoleClear;
begin
  Clear;
  Writeln('------------------------------');
  Writeln(AnsiToOem( 'Из библиотеки удалены все книги.' ));
end;
 
//Консольный диалог загрузки библиотеки из файла.
procedure THomeLib.ConsoleLoadFromFile;
var
  //Имя файла.
  FileName : String;
begin
  Writeln('------------------------------');
  Writeln(AnsiToOem( 'Загрузка библиотеки из файла: имя файла + ENTER. Выход - только ENTER.:' ));
  Readln(FileName);
  if not FileExists(FileName) then begin
    Writeln(AnsiToOem( 'Ошибка. Файла с таким именем не существует. Загрузка отменена.' ));
  end else begin
    if LoadFromFile(FileName) then begin
      Writeln(AnsiToOem( 'Загрузка произведена. Загружено книг: ' + IntToStr(GetCountBook) ));
    end else begin
      Writeln(AnsiToOem( 'Ошибка. Не удалось выполнить загрузку.' ));
    end;
  end;
end;
 
//Консольный диалог записи библиотеки в файл.
procedure THomeLib.ConsoleSaveToFile;
var
  //Имя файла.
  FileName : String;
begin
  Writeln('------------------------------');
  Writeln(AnsiToOem( 'Запись библиотеки в файл: имя файла + ENTER. Выход - только ENTER.:' ));
  Readln(FileName);
  if SaveToFile(FileName) then begin
    Writeln(AnsiToOem( 'Запись произведена. Записано книг: ' + IntToStr(GetCountBook) ));
  end else begin
    Writeln(AnsiToOem( 'Ошибка. Не удалось выполнить запись в файл.' ));
  end;
end;
 
//Главный консольный диалог. Управляет работой с библиотекой.
procedure THomeLib.ConsoleMain;
var
  Num : Integer;
begin
  repeat
    Writeln('------------------------------');
    Write(AnsiToOem( 'Всего книг в библиотеке: ' ));
    Writeln(IntToStr(GetCountBook));
    Writeln(AnsiToOem( 'Главное меню. Введите номер действия и нажмите ENTER:' ));
    Writeln(AnsiToOem( '1. Добавить книгу.' ));
    Writeln(AnsiToOem( '2. Удалить книгу.' ));
    Writeln(AnsiToOem( '3. Поиск книг.' ));
    Writeln(AnsiToOem( '4. Сортировка.' ));
    Writeln(AnsiToOem( '5. Показать все книги.' ));
    Writeln(AnsiToOem( '6. Удалить все книги.' ));
    Writeln(AnsiToOem( '7. Загрузить библиотеку из файла.' ));
    Writeln(AnsiToOem( '8. Записать библиотеку в файл.' ));
    Writeln(AnsiToOem( '9. Выход.' ));
    Readln(Num);
    case Num of
      1 : ConsoleAddBook;
      2 : ConsoleDeleteBook;
      3 : ConsoleFindBook;
      4 : ConsoleSort;
      5 : ConsoleShowAllBook;
      6 : ConsoleClear;
      7 : ConsoleLoadFromFile;
      8 : ConsoleSaveToFile;
    end;
  until Num = 9;
end;
 
end.

По ходу изучения кода, задавай вопросы - отвечу.

Вернуться к обсуждению:
Неправильно работает ..класс.... Delphi

Следующий ответ

Другие темы раздела
Delphi целочисельная матрица https://www.cyberforum.ru/ delphi-beginners/ thread57941.html Задана целочисельная матрица A(n,n), n=<20 . Разработать программу, которая исчет и печатает номера тех рядков, елементы которых создают симетрические последовательности 1, 2, 3, 3, 2, 1 или 1, 2, 3, 5,3, 2, 1. Просьба реализировать программку через параметр Delphi7 - "StrinGrid". Помогите плизз	Delphi Вывод из файла. Суть такая, я ввожу в Edit слово, нажимаю на Button, оно выводится в Label, и сразу же после этого слова, в тот же Label, выводится любое слово из файла, файл - текстовый. В файле, каждая строка - новое слово. Помогите это осуществить. Заранее спасибо.
Delphi как вывести количество чисел Даны два целых числа А и В (А<В). Вывести в порядке возрастания все целые числа, расположенные между А и В (включая сами числа А и В), а также количество N этих чисел. procedure TForm1.Button1Click(Sender: TObject); var a,b,x,i:integer; begin a:=strtoint(Edit1.text); b:=strtoint(Edit2.text); for i:=a to b do begin x:=x+1* ; memo1.Lines.Add(inttostr(i)); https://www.cyberforum.ru/ delphi-beginners/ thread57908.html	Delphi Закрыть приложение Есть прога написанная на Delphi суть вопрса: есть процедура FormCreate(Sender: TObject) на форме для отображение ничего нет, тоесть она мне не нужна. При ее создании работает прога, а как следствие по завершению появляется пустая форма и каждый раз мне нужно ее закрывать! Помогите плз... по идеи мне и создовать-то ее не нужно, но вот как это реализовать чтоб прога работала я не знаю... https://www.cyberforum.ru/ delphi-beginners/ thread57904.html
Delphi Операции с натуральными числами в 16-ричной системе счисления Реализовать в виде модуля набор подпрограмм для выполнения следующих операции над натуральными числами в шестнадцатиричной системе счисления: 1)сложениее; 2)вычитание; 3)умножение; 4)деление; 5)перевод из двоичной системы счисления в шестнадцатеричную; 6)перевод из шестнадцеричной системы счисления в десятичную; 7)функция проверки правильности записи числа в шестнадцатеричную систему...	Delphi имитация мышки? https://www.cyberforum.ru/ delphi-beginners/ thread57855.html ктото может знает как сделать так чтобы мышшь сама выполняла действия при этом курсор мышки не двигался или был свободным... мне надо чтобы в браузере нажимались опр кнопки и программа выполнялась... при этом чтобы мышка была свободная... Добавлено через 58 секунд функция mouse_event тут совсем некатит так как она требует мышку
Delphi ДИПЛОМ!!! https://www.cyberforum.ru/ delphi-beginners/ thread57851.html скиньте пожжжалуйста любой диплом на дельфи!!! А я тоже вам что нить закину...	Движение полукруга Delphi Надо чтобы полукруг двигался по полукругу. или скажите хоть примерно че делать
Delphi Пожалуйста помогите,нарисовать линию а данные брать из текстового фаила. https://www.cyberforum.ru/ delphi-beginners/ thread57805.html я сделал запись данных в файл и чтение их,остался график... unit Unit1; interface uses Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms, Dialogs, StdCtrls; type	Delphi Анализ текстовых даных в Delphi Добый день, уважаемые учасники форума! У меня такой вопрос: есть текст такого типа: <s>ключевое слово1:</s> данные1 <s>ключевое слово2:</s> данные2 Подскажите, пожалуйста, текст программы, который анализирует текст, ищет в нем выражения <s>ключевое слово1:</s> и <s>ключевое слово2:</s>, и присваивает переменной a1 значение 'данные1' , а переменной a2 значение 'данные2'. Возможно ли это... https://www.cyberforum.ru/ delphi-beginners/ thread57788.html
Строки, сумма ряда Delphi Народ помогите пожалуйста я вообще не могу разобраться что и как :( первая: Даны две строки. Пусть n1 – число слов в первой строке, а n2 – во второй (n1< n2). Добавить в конец первой строки, последние n2-n1 слов второй строки. вторая : Используя представление е^х=1+х/1+х^2/2!+x^3/3!+... вычислить значение e^x для указанного значения x(0) с точностью =0,001.	Delphi таблица умножения https://www.cyberforum.ru/ delphi-beginners/ thread57737.html Помогите разработать программу для проверки знания таблицы умножения число * число Результат ОК

Новые блоги и статьи
Как проводить научные вычисления на Python InfoMaster 15.01.2025 Python стал одним из наиболее востребованных языков программирования в области научных вычислений благодаря своей простоте, гибкости и обширной экосистеме специализированных библиотек. Научные. . .	Создание игры типа Minecraft на PyGame/Python: пошаговое руководство InfoMaster 15.01.2025 В данном руководстве мы рассмотрим процесс создания игры в стиле Minecraft с использованием библиотеки PyGame на языке программирования Python. Этот проект идеально подходит как для начинающих. . .	Как создать свою первую игру в стиле Doom на Unreal Engine InfoMaster 15.01.2025 Разработка шутера от первого лица в стиле классического Doom представляет собой увлекательное путешествие в мир игрового программирования, где сочетаются творческий подход и технические навыки. . . .	Параллельное программирование: основные технологии и принципы InfoMaster 15.01.2025 Введение в параллельное программирование Параллельное программирование представляет собой фундаментальный подход к разработке программного обеспечения, который позволяет одновременно выполнять. . .	Как написать микросервис на C# с Kafka, MediatR, Redis и GitLab CI/CD InfoMaster 15.01.2025 В современной разработке программного обеспечения микросервисная архитектура стала стандартом де-факто для создания масштабируемых и гибких приложений. Этот подход позволяет разделить сложную систему. . .	Что такое CQRS и как это реализовать на C# с MediatR InfoMaster 15.01.2025 Концепция CQRS и её роль в современной разработке В современном мире разработки программного обеспечения архитектурные паттерны играют ключевую роль в создании масштабируемых и поддерживаемых. . .
Как настроить CI/CD с Azure DevOps InfoMaster 15.01.2025 CI/ CD, или непрерывная интеграция и непрерывное развертывание, представляет собой современный подход к разработке программного обеспечения, который позволяет автоматизировать и оптимизировать процесс. . .	Как настроить CI/CD с помощью Jenkins InfoMaster 15.01.2025 Введение в CI/ CD и Jenkins В современной разработке программного обеспечения непрерывная интеграция (CI) и непрерывная доставка (CD) стали неотъемлемыми элементами процесса создания качественных. . .	Как написать микросервис на Go/Golang с Kafka, REST и GitHub CI/CD InfoMaster 14.01.2025 Определение микросервиса, преимущества использования Go/ Golang Микросервис – это архитектурный подход к разработке программного обеспечения, при котором приложение состоит из небольших, независимо. . .	Как написать микросервис с нуля на C# с RabbitMQ, CQRS, Swagger и CI/CD InfoMaster 14.01.2025 В современном мире разработки программного обеспечения микросервисная архитектура стала стандартом де-факто для создания масштабируемых и гибких приложений. Этот архитектурный подход предполагает. . .	Как создать интернет-магазин на PHP и JavaScript InfoMaster 14.01.2025 В современном мире электронная коммерция стала неотъемлемой частью бизнеса. Создание собственного интернет-магазина открывает широкие возможности для предпринимателей, позволяя достичь большей. . .	Как написать Тетрис на Ассемблере InfoMaster 14.01.2025 Тетрис – одна из самых узнаваемых и популярных компьютерных игр, созданная в 1984 году советским программистом Алексеем Пажитновым. За прошедшие десятилетия она завоевала симпатии миллионы людей по. . .

	25.10.2009, 02:40