Как переместить скриншот в папку? - Delphi - Ответ 14193043

Procedure TForm1.Button1Click(Sender: TObject);
Const
  CAPTUREBLT = $40000000;
Var
  StrDate: String;
  DC: HDC;
  jpg: TJPEGImage;
  bmp: TBitmap;
Begin
StrDate := IncludeTrailingPathDelimiter(IncludeTrailingPathDelimiter(GetCurrentDir()) + DateToStr(Date));
If ForceDirectories(StrDate) Then
  Begin
  DC := GetDC(0);
  If (DC <> 0) Then
    Try
      bmp := TBitmap.Create();
      Try
        bmp.PixelFormat := pf24bit;
        bmp.Width := Screen.Width;
        bmp.Height := Screen.Height;
        BitBlt(bmp.Canvas.Handle, 0, 0, Screen.Width, Screen.Height, DC, 0, 0, SRCCOPY Or CAPTUREBLT);
        jpg := TJPEGImage.Create();
        Try
          jpg.Assign(bmp);
          jpg.CompressionQuality := 100; // 100 = best quality, 25 = pretty awful
          jpg.Compress();
          jpg.SaveToFile(StrDate + FormatDateTime('dd.mm.yyyy -,- hh.mm.ss.ms', Now()) + '.jpg');
        Finally
          FreeAndNil(jpg);
        End;
      Finally
        FreeAndNil(bmp);
      End;
    Finally
      ReleaseDC(0, DC);
    End
  Else
    Raise Exception.Create('GetDC() failed!');
  End
Else
  Raise Exception.Create('ForceDirectories() failed!'#13#10#13#10'"' + StrDate + '"');
End;