Задать тип массива через переменную - PascalABC.NET - Ответ 13947978

uses System;
 
type
  MemoryBlock = sealed class
    private const data_size = 4096; // Сколько байт в 1 выделяемом блоке памяти
    private data: IntPtr; // указатель на сам блок памяти
    private l_bl, r_bl: MemoryBlock; // точки связи для связного списка из блоков
    private unit_size: integer; // кол-во байт в 1 единице памяти. То есть 1, 2, 4 или 8
    private pos: integer; // позиция (в байтах) указателя в этом блоке (если указатель в другом блоке - значение тут по сути мусор)
    
    static procedure RtlZeroMemory(ptr: IntPtr; length: integer);
    external 'kernel32.dll';
    
    public constructor(unit_size: integer; l_bl, r_bl: MemoryBlock);
    begin
      self.unit_size := unit_size;
      self.l_bl := l_bl; if l_bl<>nil then l_bl.r_bl := self;
      self.r_bl := r_bl; if r_bl<>nil then r_bl.l_bl := self;
      self.data := System.Runtime.InteropServices.Marshal.AllocHGlobal(data_size);
      RtlZeroMemory(data, data_size); // обнуляем все байты
    end;
    
    protected procedure Finalize; override :=
    System.Runtime.InteropServices.Marshal.FreeHGlobal(data); // неуправляемые данные всегда надо освобождать при удалении объекта MemoryBlock, а то будет утечка памяти
    
    // возвращаемое значение будет не текущим блоком если точка памяти вышла за текущий блок
    // использование подразумевается как "текущий_блок := текущий_блок.MoveLeft"
    public function MoveLeft: MemoryBlock;
    begin
      pos -= unit_size;
      // если память закончилась - выделяем новый блок и скрепляем в связный список с текущим блоком
      if pos<0 then
      begin
        // если левый блок уже есть - надо только переключиться на него. Иначе создаём новый
        Result := self.l_bl=nil ? new MemoryBlock(unit_size, nil, self) : self.l_bl;
        Result.pos := data_size-unit_size; // позиция считаеться с 0, поэтому надо отойти на 1 юнит от конца, чтоб не читать/записывать мимо памяти
      end else
        Result := self;
    end;
    
    public procedure SetVal(v: uint64);
    begin
      var ptr := pointer(data + pos);
      case unit_size of
        1: PByte(ptr)^     := v; // лишние биты v обрежет автоматически из за присвоения другому типу, на данной строчке запишет только 8 младших бит
        2: PWord(ptr)^     := v;
        4: PLongint(ptr)^  := v;
        8: PUInt64(ptr)^   := v;
      end;
    end;
    
  end;
  
begin end.