Быстрая сортировка: отсортировать по возрастанию отдельно элементы первой и второй половин массива - Pascal - Ответ 12343530

program sorting_array_by_halves;
{задача https://www.cyberforum.ru/pascal/thread2235948.html
по условию:
Массив содержит четное количество элементов. Напишите программу,
которая сортирует по возрастанию отдельно элементы первой и второй
половин массива. Каждый элемент должен остаться в «своей» половине.
Используйте алгоритм быстрой сортировки}
 
{$mode objfpc}{$H+}
 
uses
  {$IFDEF UNIX}{$IFDEF UseCThreads}
  cthreads,
  {$ENDIF}{$ENDIF}
  Classes, sysutils, math;
{quick sort from wikipedia }   {по возрастанию}
 
procedure qsort(var A: array of Integer);
 
    procedure sort(l, r: integer);
    var
      i, j, x, y: integer;
    begin
      i := l;
      j := r;
      x := A[(l + r) div 2];
      repeat
        while A[i] < x do
          Inc(i);
        while x < A[j] do
          Dec(j);
        if not (i > j) then
        begin
          y := A[i];
          A[i] := A[j];
          A[j] := y;
          Inc(i);
          Dec(j);
        end;
      until i > j;
      if l < j then
        sort(l, j);
      if i < r then
        sort(i, r);
    end;
 
begin
    sort(0, High(A));
end;
 
 
var
  arr: array of integer;
  n: integer; //size of array
  value, i: integer;
begin
  {подбираем и заполняем масивв случайными числами}
  Randomize;
  n:= RandomRange(11, 20); // размер случаен от 11 до 20
  if odd(n) then dec(n);   //если вдруг n не четное то уменьшем его на 1
  SetLength(arr, n);       //создаем массив
  //заполняем массив
  for i:=0 to pred(n) do
      arr[i]:= RandomRange(-10, 10);
  //выводим массив
  Write('Arr:        ');
  for value in arr do
      write(value:4);
  WriteLn();
 
   //сортируем по половинам:
   qsort(arr[0..pred(Length(arr) div 2)]);
   qsort(arr[Length(arr) div 2..pred(Length(arr))]);
 
 
  //выводим массив после сортировки
  Write('Sorted arr: ');
  for value in arr do
      write(value:4);
  WriteLn();
  ReadLn;
end.