Макрос. Выбрать отмеченные позиции и перенести на другой лист - VBA - Ответ 10588187

'при активации листа
Private Sub Worksheet_Activate()
    Dim i&, ii&, x&, a
 
    'берём в массив дааные листа ниже шапки
    With Sheets("Oбщий").[b2].CurrentRegion
        a = .Offset(1).Value
        'если вообще есть метки (смотрим адрес первого столбца)
        If .Cells(1).Address(0, 0) Like "A#" Then
            'цикл по массиву
            For i = 1 To UBound(a)
                'если есть метка
                If Len(Trim(a(i, 1))) Then
                    'увеличиваем индекс
                    ii = ii + 1
                    'циклом по строке копируем данные текущей строки в строку с номером ii
                    'и стираем возможную метку
                    For x = 2 To UBound(a, 2): a(ii, x) = a(i, x): Next: a(ii, 1) = Empty
                End If
            Next
            'работа с диапазоном выгрузки
            With [a5].Resize(ii, UBound(a, 2))
                'ставим правильный формат столбцу с датами
                .Columns(5).NumberFormat = "m/d/yyyy"
                'выгружаем заполненную верхушку массива
                .Value = a
            End With
        End If
    End With
End Sub
 
'при деактивации листа
Private Sub Worksheet_Deactivate()
'очистка всего ниже шапки
    [b4].CurrentRegion.Offset(1).Clear
End Sub