Дан неупорядоченный линейный односвязный список и массив, содержащий номера соответствующих элементов в упорядоченном списке. Перестроить данный списо

program Project1;
 
type
  //Тип основных данных.
  TData = Integer;
  //Указатель на элемент списка.
  TPElem = ^TElem;
  //Элемент списка.
  TElem = record
    Data : TData; //Основные данные.
    PNext : TPElem; //Указатель на следующий элемент.
  end;
  //Список.
  TDList = record
    PFirst, PLast : TPElem; //Указатели на первый и на последний элементы списка.
  end;
 
//Процедура инициализации списка. Внимание! Эту процедуру можно выполнять
//только в отношении пустого списка. Иначе, произойдёт утечка памяти.
procedure Init(var aList : TDList);
begin
  aList.PFirst := nil;
  aList.PLast := nil;
end;
 
//Добавление элемента в конец списка.
procedure Add(var aList : TDList; const aData : TData);
var
  PElem : TPElem;
begin
  New(PElem);
  PElem^.Data := aData;
  PElem^.PNext := nil;
  if aList.PFirst = nil then
    aList.PFirst := PElem
  else
    aList.PLast^.PNext := PElem;
  aList.PLast := PElem;
end;
 
//Освобождение памяти, занятой под список.
procedure Free(var aList : TDList);
var
  PElem, PDel : TPElem;
begin
  PElem := aList.PFirst;
  while PElem <> nil do begin
    PDel := PElem;
    PElem := PElem^.PNext;
    Dispose(PDel);
  end;
  Init(aList);
end;
 
//Распечатка всего списка.
procedure Print(var aList : TDList);
var
  PElem : TPElem;
  i : Integer;
begin
  PElem := aList.PFirst;
  i := 0;
  while PElem <> nil do begin
    Inc(i);
    if i > 1 then Write(', ');
    Write(PElem^.Data);
    PElem := PElem^.PNext;
  end;
  Writeln;
end;
 
const
  M = 8; //Количество элементов в списке.
var
  L : TDList;
  PElem : TPElem;
  Arr : array[1..M] of Integer; //Массив номеров элементов.
  ArrP : array[1..M] of TPElem; //Массив указателей на элементы.
  i, j, Num : Integer;
  S : String;
begin
  //Переключение окна консоли на кодовую страницу CP1251 (Win-1251).
  //Если после переключения русские буквы показываются неверно,
  //следует открыть системное меню консольного окна - щелчком мыши в левом
  //верхнем углу окна консоли и выбрать:
  //Свойства - закладка "Шрифт" - выбрать шрифт: "Lucida Console".
  SetConsoleCP(1251);
  SetConsoleOutputCP(1251);
 
  //Начальная инициализация списка.
  Init(L);
 
  repeat
    //Составляем список и записываем номера элементов в массив.
    for i := 1 to M do begin
      Add(L, i);
      Arr[i] := i;
    end;
    Writeln('Составлен список:');
    Print(L);
 
    //Случайным образом перемешиваем номера элементов в массиве.
    Randomize;
    for i := 1 to M do begin
      j := 2 + Random(M - 1);
      Num := Arr[1];
      Arr[1] := Arr[j];
      Arr[j] := Num;
    end;
    Writeln('Составлен массив:');
    for i := 1 to M do begin
      if i > 1 then Write(', ');
      Write(Arr[i]);
    end;
    Writeln;
 
    //Для каждого элемента списка по его порядковому номеру находим индекс
    //соответствующего элемента в массиве Arr. И по этому индексу записываем
    //указатель на элемент списка в массив ArrP.
    PElem := L.PFirst;
    i := 0;
    while PElem <> nil do begin
      Inc(i);
      j := 1;
      while (j <= M) and (Arr[j] <> i) do Inc(j);
      ArrP[j] := PElem;
      PElem := PElem^.PNext;
    end;
 
    //Теперь перестраиваем список по данным массива указателей ArrP.
    L.PFirst := ArrP[1];
    L.PLast := ArrP[M];
    L.PLast^.PNext := nil;
    for i := 1 to M - 1 do ArrP[i]^.PNext := ArrP[i + 1];
 
    //Ответ.
    Writeln('Перестроенный список:');
    Print(L);
 
    Free(L);
    Writeln('Память, выделенная для списка, освобождена.');
 
    Writeln('Повторить - Enter, выход - любой символ + Enter.');
    Readln(S);
  until S <> '';
end.