Рекурсия: вывести значение логического выражения, заданного в виде строки

@dsl · Регистрация: 10.06.2009

Author24 — интернет-сервис помощи студентам

Доброе время суток всем вошедшим)) Вот проблема такая замысловатая, решить программу рекурсия((
Буду весь благодарен откликнувшимся

Вывести значение логического выражения, заданного в виде строки S. Выражение определяется следующим образом («T» — True, «F» — False):
<выражение> := T | F | And(<параметры>) | Or(<параметры>)
<параметры> := <выражение> | <выражение> , <параметры>

например S= Or(And(Or(F,T,T),F,F),T,T)
ответ True

@yanyk1n · 23.11.2009, 21:34

Насколько я понял, у функций три параметра?

@dsl · 23.11.2009, 22:08 **[ТС]**

Сообщение от k1ry4

Насколько я понял, у функций три параметра?

так точно там 3 параметра(

@dsl · 24.11.2009, 01:06 **[ТС]**

Кто нибудь знает как это хоть сделать?

это последняя прога по паскалю

@new_in_net · 24.11.2009, 01:50

Сообщение от dsl

Доброе время суток всем вошедшим)) Вот проблема такая замысловатая, решить программу рекурсия((
Буду весь благодарен откликнувшимся

Вывести значение логического выражения, заданного в виде строки S. Выражение определяется следующим образом («T» — True, «F» — False):
<выражение> := T | F | And(<параметры>) | Or(<параметры>)
<параметры> := <выражение> | <выражение> , <параметры>

например S= Or(And(Or(F,T,T),F,F),T,T)
ответ True

Вот написал на Дельфи но думаю и на Паскале сработает, так как не использовал ничего сугубо Дельфийного:

Delphi

function CalcResult(S: string): boolean;
  function ParseParams(S: string): array [1..3] of string;
  var
    I, Pos, Skobki, Start, ParamLen: integer;
  begin
    Pos := 1;
    Skobki := 0;
    Start := 2;
    ParamLen := 0;
    for I:=2 to Length(S)-1 do begin // krajnie skobki
      if (S[I] = ',') and (Skobki = 0) then begin
        Result[Pos] := Copy(S, Start, ParamLen);
        Start := I+1;
        ParamLen := 0;
        Inc(Pos);
      end
      else begin
        if S[I] = '(' then
          Inc(Skobki)
        else if S[I] = ')' then
          Dec(Skobki);
        Inc(ParamLen);
      end;
    end;
    // zapishem poslednij parametr
    Result[Pos] := Copy(S, Start, ParamLen);
  end;
var
  Params: array [1..3] of string;
begin
  if S = 'T' then
    Result := True
  else if S = 'F' then
    Result := False
  else if S[1] = 'O' then begin // or
    Params := ParseParams(Copy(S, 3, Length(S)-2));
    Result := CalcResult(Params[1]) or CalcResult(Params[2]) or CalcResult(Params[3]);
  end
  else if S[1] = 'A' then begin // and
    Params := ParseParams(Copy(S, 4, Length(S)-3));
    Result := CalcResult(Params[1]) and CalcResult(Params[2]) and CalcResult(Params[3]);
  end else
    Result := False;
end;

Проверил. На строке: 'Or(And(Or(F,T,T),F,F),T,T)' выдает ответ True

@dsl · 24.11.2009, 10:56 **[ТС]**

Спасибо

что то не хочет работать на паскале, ругается

@Puporev · 24.11.2009, 11:28

dsl, Перепиши на Паскале, что тебе мешает? Только переменную result объяви в разделе переменных.

@dsl · 26.11.2009, 15:44 **[ТС]**

Pascal

1	function ParseParams(S: string): array [1..3] of string;

строка вызывает ошибку

а Result как лучше задать не пойму((

@Puporev · 26.11.2009, 15:47

Объяви сначала тип

Pascal

1	type mas=array [1..3] of string;

потом в функции это не пойдет, нужно процедурой

Pascal

1	procedure ParseParams(S: string; var a:mas);

@dsl · 26.11.2009, 16:16 **[ТС]**

Pascal

1	Result:string

по любому вроде так после procedure ParseParams

Pascal

1	Result[Pos] := Copy(S, Start, ParamLen);

но выходит ошибка 26 Type mismatch (Несоответствие типов).

как понимаю тут либо Char либо String и при чем одновременно

@Puporev · 26.11.2009, 16:30

Вот переписал Вам программу, с приведенным примером работает, а так я это честно не понимаю.

Pascal

uses crt;
function CalcResult(S: string): boolean;
type mas=array [1..3] of string;
  procedure ParseParams(S:string;var a:mas);
  var
    I, Pos, Skobki, Start, ParamLen: integer;
  begin
    Pos := 1;
    Skobki := 0;
    Start := 2;
    ParamLen := 0;
    for I:=2 to Length(S)-1 do begin {// krajnie skobki}
      if (S[I] = ',') and (Skobki = 0) then
       begin
        a[Pos] := Copy(S, Start, ParamLen);
        Start := I+1;
        ParamLen := 0;
        Inc(Pos);
      end
      else begin
        if S[I] = '(' then
          Inc(Skobki)
        else if S[I] = ')' then
          Dec(Skobki);
        Inc(ParamLen);
      end;
    end;
    {// zapishem poslednij parametr}
    a[Pos] := Copy(S, Start, ParamLen);
  end;
var
  Params:mas;
begin
  if S = 'T' then
    CalcResult := True
  else if S = 'F' then
    CalcResult := False
  else if S[1] = 'O' then begin {// or}
    ParseParams(copy(S, 3, Length(S)-2),params);
    {Params := ParseParams(Copy(S, 3, Length(S)-2));}
    CalcResult := CalcResult(Params[1]) or CalcResult(Params[2]) or CalcResult(Params[3]);
  end
  else if S[1] = 'A' then begin {// and}
    ParseParams(Copy(S, 4, Length(S)-3),params);
    CalcResult := CalcResult(Params[1]) and CalcResult(Params[2]) and CalcResult(Params[3]);
  end else
    CalcResult := False;
end;
var st:string;
begin
clrscr;
st:='Or(And(Or(F,T,T),F,F,),T,T)';
write(CalcResult(st));
readln
end.

@new_in_net · 26.11.2009, 17:21

Сообщение от Puporev

Вот переписал Вам программу, с приведенным примером работает, а так я это честно не понимаю.

Может мне надо было пояснить...
Начало думаю ясно - если строка T, то true, Если F, то false
Дальше, если не T или F, то должно быть AND(параметр1,параметр2,параметр3) или OR(параметр1,параметр2,параметр3)
S[1] - первая буква проверяется на 'A' или 'O' и далее отделяется та часть которая '(параметр1,параметр2,параметр3)' и передается на вход функции ParseParams

ParseParams возвращает 3 элемента, параметра. Внутри учитывается, что если параметр не простой, а составной, то у него есть открывающая и закрывающая скобки.
Каждый возвращенный параметр опять же является строкой начальной структуры, но меньшей длины, которую опять передаем на вход главной функции и разчитываем AND или OR значений этих параметров.

Все.

@dsl · 26.11.2009, 17:29 **[ТС]**

Вас понял))

@new_in_net 283 / 262 / 32 Регистрация: 11.11.2009 Сообщений: 605
	26.11.2009, 17:21	12
	Сообщение от Puporev Вот переписал Вам программу, с приведенным примером работает, а так я это честно не понимаю. Может мне надо было пояснить... Начало думаю ясно - если строка T, то true, Если F, то false Дальше, если не T или F, то должно быть AND(параметр1,параметр2,параметр3) или OR(параметр1,параметр2,параметр3) S[1] - первая буква проверяется на 'A' или 'O' и далее отделяется та часть которая '(параметр1,параметр2,параметр3)' и передается на вход функции ParseParams ParseParams возвращает 3 элемента, параметра. Внутри учитывается, что если параметр не простой, а составной, то у него есть открывающая и закрывающая скобки. Каждый возвращенный параметр опять же является строкой начальной структуры, но меньшей длины, которую опять передаем на вход главной функции и разчитываем AND или OR значений этих параметров. Все. 1

@dsl 0 / 0 / 0 Регистрация: 10.06.2009 Сообщений: 27
	26.11.2009, 17:29 [ТС]	13
	Вас понял)) 0

@yanyk1n 4342 / 1474 / 680 Регистрация: 12.03.2009 Сообщений: 5,310
	23.11.2009, 21:34	2
	Насколько я понял, у функций три параметра? 0

@dsl 0 / 0 / 0 Регистрация: 10.06.2009 Сообщений: 27
	23.11.2009, 22:08 [ТС]	3
	Сообщение от k1ry4 Насколько я понял, у функций три параметра? так точно там 3 параметра( 0

@dsl 0 / 0 / 0 Регистрация: 10.06.2009 Сообщений: 27
	24.11.2009, 01:06 [ТС]	4
	Кто нибудь знает как это хоть сделать? это последняя прога по паскалю 0

@dsl 0 / 0 / 0 Регистрация: 10.06.2009 Сообщений: 27
	24.11.2009, 10:56 [ТС]	6
	Спасибо что то не хочет работать на паскале, ругается 0

@Puporev Почетный модератор 64303 / 47600 / 32742 Регистрация: 18.05.2008 Сообщений: 115,181
	24.11.2009, 11:28	7
	dsl, Перепиши на Паскале, что тебе мешает? Только переменную result объяви в разделе переменных. 0