Определить поля шахматной доски, которые бьёт ферзь

@JACKFAF · Регистрация: 19.12.2022

Author24 — интернет-сервис помощи студентам

Реализовать программу, решающую следующую задачу:

Даны два символа - латинская буква от «а» до «h» и цифра от 1 до 8 (например: а5 или g2). Рассматривая их как координаты поля шахматной доски, на котором находится ферзь, схематически нарисовать шахматную доску, пометив крестиками все поля, которые «бьет» ферзь, и ноликами все остальные поля.

* Замечание:
Положение шахматной фигуры задается пользователем с клавиатуры. Целесообразно выдавать пользователю на экран «координатную сетку» шахматного поля для помощи в выборе координаты.

@Cyborg Drone · 20.03.2023, 22:31

JACKFAF, я же Вас просил: соблюдайте правила форума. Темы называйте осмысленно: название темы должно кратко отражать суть вопроса темы.

Pascal

var
  x, y, xf, yf: integer;
  f: array[1..8, 1..8] of char;
  c: string;
  i: char;
begin
  writeln('Координатная сетка шахматного поля:');
  for y := 8 downto 1 do
    begin
      write(y:2);
      for x := 1 to 8 do
        begin
          f[y,x] := '0';
          write(f[y,x]:2)
        end;
      writeln
    end;
  write('':2);
  for i := 'a' to 'h' do write(i:2);
  writeln;
  write('Введите координаты ферзя, например, g2: ');
  readln(c);
  xf := ord(c[1]) - ord('a') + 1;
  yf := ord(c[2]) - ord('0');
  for y := 1 to 8 do
    for x := 1 to 8 do
      if (x = xf) or (y = yf) or (abs(x - xf) = abs(y - yf)) then f[y,x] := 'X';
  writeln('Поля, которые бьёт ферзь:');
  for y := 8 downto 1 do
    begin
      write(y:2);
      for x := 1 to 8 do write(f[y,x]:2);
      writeln
    end;
  write('':2);
  for i := 'a' to 'h' do write(i:2);
  readln
end.

На всякий случай, с подпрограммой для печати поля:

Pascal

type
  p = array[1..8, 1..8] of char;
 
procedure prn(m: string; var ff: p);
var
  x, y: integer;
  i: char;
begin
  writeln(m);
  for y := 8 downto 1 do
    begin
      write(y:2);
      for x := 1 to 8 do write(ff[y,x]:2);
      writeln
    end;
  write('':2);
  for i := 'a' to 'h' do write(i:2);
  writeln
end;
 
var
  x, y, xf, yf: integer;
  f: array[1..8, 1..8] of char;
  c: string;
begin
  for y := 1 to 8 do
    for x := 1 to 8 do
      f[y,x] := '0';
  prn('Координатная сетка шахматного поля:', f);
  write('Введите координаты ферзя, например, g2: ');
  readln(c);
  xf := ord(c[1]) - ord('a') + 1;
  yf := ord(c[2]) - ord('0');
  for y := 1 to 8 do
    for x := 1 to 8 do
      if (x = xf) or (y = yf) or (abs(x - xf) = abs(y - yf)) then f[y,x] := 'X';
  prn('Поля, которые бьёт ферзь:', f);
  readln
end.

@JACKFAF 0 / 0 / 0 Регистрация: 19.12.2022 Сообщений: 12
		1
	Определить поля шахматной доски, которые бьёт ферзь 20.03.2023, 17:09. Показов 411. Ответов 1 Метки pascal abc (Все метки) Реализовать программу, решающую следующую задачу: Даны два символа - латинская буква от «а» до «h» и цифра от 1 до 8 (например: а5 или g2). Рассматривая их как координаты поля шахматной доски, на котором находится ферзь, схематически нарисовать шахматную доску, пометив крестиками все поля, которые «бьет» ферзь, и ноликами все остальные поля. * Замечание: Положение шахматной фигуры задается пользователем с клавиатуры. Целесообразно выдавать пользователю на экран «координатную сетку» шахматного поля для помощи в выборе координаты. 0

	20.03.2023, 22:31