Переписать все числа из одного файла в другой файл в порядке возрастания

const f_in = 'input.txt'; //имя входного файла
      f_out = 'output.txt'; //имя выходного файла
var f, g: text; //переменные для входного и выходного файла
    i, c_s, c_n, c_p: longint; //счётчик, счётчик чисел, общее количество чисел, счётчик проходов
    x, s, b: real; //буфер, выбранное число, барьер
begin
  assign(f, f_in); //открываем входной файл
  reset(f); //для чтения, указатель файла в начало файла
  c_n := 0; //количество чисел пока 0
  while not seekeof(f) do //пока не найден конец файла
    begin
      read(f, x); //читаем число
      if (c_n = 0) or (x < s) then s := x; //ищем минимум
      inc(c_n) //число было прочитано, увеличиваем количество чисел
    end;
  if c_n > 0 then //если файл не пустой, то
    begin //выполняем перезапись с сортировкой
      assign(g, f_out); //открываем выходной файл
      rewrite(g); //для записи
      c_p := c_n; //пока количество проходов по файлу равно количеству чисел в файле
      b := s - 1e-10; //назначаем барьер меньше минимума
      repeat //цикл выбора чисел из входного файла и перезаписи их в выходной файл
        reset(f); //указатель файла в начало файла
        c_s := 0; //пока ближайших к барьеру чисел не найдено
        for i := 1 to c_n do //цикл нахождения ближайшего к барьеру числа и подсчёт таких чисел
          begin
            read(f, x); //читаем число
            if (x > b) then //если число больше барьера, то
              begin
                if (c_s = 0) or (x < s) then //если числа не были выбраны, или прочитанное число меньше выбранного, то
                  begin
                    s := x; //выбираем число
                    c_s := 0 //сбрасываем счётчик равных чисел
                  end;
                if x = s then inc(c_s) //если прочитанное число равно выбранному, увеличиваем счётчик
              end
          end;
        for i := 1 to c_s do writeln(g, s); //записываем найденное число в файл столько раз, сколько оно было обнаружено во входном файле
        b := s; //назначаем найденное число в качестве барьера
        c_p := c_p - c_s //уменьшаем количество проходов на количество найденных чисел
      until c_p <= 0; //повторяем, пока не выберем все числа
      close(g) //все числа переписаны, закрываем выходной файл
    end
  else //если файл пустой, то сообщаем об этом
    begin
      write('File is empty. Press <Enter> to exit.'); //выводим сообщение
      readln //ждём реакции пользователя
    end;
  close(f) //закрываем входной файл
end.

b := s - 1e-10;

if abs(s) > 1 then b := s - s / 2 else b := -1;

if abs(s) > 1 then 
  begin
    delta := s / 32768;
    while s <> s - delta do delta := delta / 2;
    b := s - delta * 2
  end
  else b := -1;