Импорт данных из разных файлов эксель

Public Function LinkExcelList(sExcelFilePath As String, sListName As String, sLocTableName As String) As Long
' Подлинковка листа книги Excel в режиме: READONLY - редакция данных не доступна
' Внимание!!! - Первая строка листа должна содержать имена столбцов!
' Возвращает код ошибки или 0
'-------------------------------------------------------------------------
'Аргументы:
'   sExcelFilePath = Полный путь к файлу
'   sListName      = Название листа
'   sLocTableName  = Название таблицы листа в текущей базе
'-------------------------------------------------------------------------
Dim strLink As String
Dim tdf As TableDef
On Error GoTo LinkExcelListErr
'Создание строки подключения:
    strLink = "Excel 12.0;DATABASE=" & sExcelFilePath
    Set tdf = CurrentDb.CreateTableDef(sLocTableName)
    tdf.Connect = strLink
    tdf.SourceTableName = sListName & "$" 'Название листа
'Удаление старой таблицы (если есть):
    If DCount("*", "MSysObjects", "[Name]='" & sLocTableName & "' AND Type=6") > 0 Then
        CurrentDb.TableDefs.Delete sLocTableName
    End If
    CurrentDb.TableDefs.Append tdf 'Создание подлинкованной таблицы
    Application.RefreshDatabaseWindow 'Обновление Области Навигации (Navigation Pane)
 
LinkExcelListEnd:
    Set tdf = Nothing
    Exit Function
 
LinkExcelListErr:
    LinkExcelList = Err.Number
    MsgBox "Функция [LinkExcelList] привела к ошибке:" & vbCrLf & _
    Err.Description & vbCrLf & " Err#" & Err.Number, vbCritical
    Resume LinkExcelListEnd
End Function