В поле Фамилия Имя Отчество вывести Фамилия И.О

Private Sub test()
Dim str As String
Dim v As Variant
    
    str = "Сидоров Петр Иванович"
    v = "Пример работы функции cutStr():"
    v = v & vbCrLf & String(30, "-")
    v = v & vbCrLf & "Часть 2 = " & cutStr(str, 2)
    v = v & vbCrLf & "Часть 3 = " & cutStr(str, 3)
    v = v & vbCrLf & "Часть 8 = "
    If IsNull(cutStr(str, 8)) Then v = v & "Null" Else v = v & " ...  "
    Debug.Print v
 
End Sub

Пример работы функции cutStr():
------------------------------
Часть 2 = Петр
Часть 3 = Иванович
Часть 8 = Null

Public Function cutStr(val As Variant, intPosition As Integer, _
            Optional strSeparator As String = " ") As Variant
Dim v As Integer
Dim i As Integer, x As Integer
'es 29.01.04
'Рубит строку переданную в аргументе: val на отдельные слова
'   и возвращает слово стоящее в позиции указанной в intPosition
'   ... или Null если в заданной позиции слова нет
'Аргумент: strSeparator = разделитель слов (по умолчанию=пробел " ")
'----------------------------------------------------------------
On Error GoTo cutStrErr
    val = val & strSeparator
    x = 1
    For i = 1 To intPosition
        v = InStr(x, val, strSeparator)
        If v = 0 Then cutStr = Null: Exit For
        If i = intPosition Then
            cutStr = Mid(val, x, v - x)
            Exit For
        Else
            x = CInt(v + 1)
        End If
    Next i
'На случай лишних пробелов
    cutStr = Trim(cutStr)
    If cutStr = "" Then cutStr = Null
    Exit Function
cutStrErr:
    cutStr = "#Error!#"
    Err.clear
End Function

Public Function cutStrSplit(val As Variant, intPosition As Integer, _
            Optional strSeparator As String = " ") As Variant
Dim v() As String
'----------------------------------------------------------------
On Error GoTo cutStrSplitErr
    If IsNull(val) Then cutStrSplit = Null: Exit Function
    v = Split(val, strSeparator, intPosition)
    cutStrSplit = v(intPosition - 1)
'На случай лишних пробелов
    cutStrSplit = Trim(cutStrSplit)
    If cutStrSplit = "" Then cutStrSplit = Null
    Exit Function
cutStrSplitErr:
    cutStrSplit = "#Error!#"
    Err.clear
End Function

Public Function CutString(sString$, iPartNo As Integer) As Variant
'es - 23.06.2019
'----------------------------------------------------------------
'Разделение строки
'Например: Петрова Ирина Ваильевна на ФИО раздельно
'----------------------------------------------------------------
Dim s$, i%, iDateStart%
Dim vArr As Variant
On Error GoTo CutString_Error
    
  
    s = sString
    vArr = Split(s, " ") 'Разделитель
    CutString = vArr(iPartNo - 1)
 
CutString_End:
    On Error GoTo 0
    Exit Function
 
CutString_Error:
    MsgBox "Error " & Err.Number & " (" & Err.Description & ") in procedure CutString, line " & Erl & "."
    Err.Clear
    Resume CutString_End
End Function

Public Function GetFIO(vFamilia As Variant, vImja As Variant, vOtchestvo As Variant, _
    Optional bInLongFormat As Boolean) As Variant
'es 19.04.2018 - LE 10.10.2019
'Возвращает ФИО (Или ничего) по аргументам:
'   vFamilia      = Фамилия
'   vImja         = Имя
'   vOtchestvo    = Отчество
'   bInLongFormat = Краткий или длинный формат = По умолчанию краткий
'       Краткий формат = Пушкин А.С.
'       Длинный формат = Пушкин Александр Сергеевич
'--------------------------------------------------------------------------
Dim iLen%
On Error GoTo GetFIO_Err
 
'Фамилия
    iLen = Len(vFamilia & "")
    If iLen > 0 Then 'Фамилия указана
        'Простое составление с нормализацией строки
        GetFIO = UCase(Mid(vFamilia, 1, 1)) & LCase(Mid(vFamilia, 2))
    Else 'Фамилии нет и формат краткий- на выход!
        If bInLongFormat = False Then
            GetFIO = vImja & " " & vOtchestvo
            Exit Function
        End If
    End If
 
'Имя
    iLen = Len(vImja & "")
    If iLen > 0 Then 'Имя указано
        If bInLongFormat = False Then
            GetFIO = GetFIO & " " & UCase(Mid(vImja, 1, 1)) & "."
        Else 'Полностью с нормализацией строки
            GetFIO = GetFIO & " " & UCase(Mid(vImja, 1, 1)) & LCase(Mid(vImja, 2))
            'If iLen > 1 Then GetFIO = GetFIO
        End If
    Else
        If bInLongFormat = False Then Exit Function
    End If
 
'Отчество
    iLen = Len(vOtchestvo & "")
    If iLen > 0 Then 'Отчество указано
        If bInLongFormat = False Then
            GetFIO = GetFIO & UCase(Mid(vOtchestvo, 1, 1)) & "."
        Else 'Полностью с нормализацией строки
            GetFIO = GetFIO & " " & UCase(Mid(vOtchestvo, 1, 1)) & LCase(Mid(vOtchestvo, 2))
        End If
    End If
 
GetFIO_Bye:
    Exit Function
 
GetFIO_Err:
    Err.Clear
    Resume GetFIO_Bye
End Function

Public Function FIOShort(vFIO As Variant) As Variant
'es 03.06.2019
'Преобразование длинного ФИО в краткий формат ("Пушкин А.С.")
'--------------------------------------------------------------------------
'?FIOShort("Пушкин Александр Сергеевич")
'--------------------------------------------------------------------------
Dim s As String
Dim sFam$, sImia$, sOth$
Dim i%, x%
On Error GoTo FIOShort_Err
    s = CStr(vFIO)
    s = Trim(Replace(s, "  ", " "))
    x = Len(s)
    i = InStr(1, s, " ")
    
    If i > 1 Then
        FIOShort = Mid(s, 1, i - 1)
    Else
        FIOShort = s
        Exit Function
    End If
   
    sImia = UCase(Mid(s, i + 1, 1)) & "."
    FIOShort = FIOShort & " " & sImia
    
    i = InStr(i + 2, s, " ")
    If i > 0 Then
        sOth = UCase(Mid(s, i + 1, 1)) & "."
        FIOShort = FIOShort & sOth
    End If
 
 
FIOShort_End:
    On Error Resume Next
    Err.Clear
    Exit Function
 
FIOShort_Err:
    'MsgBox "Error: " & Err.Number & vbCrLf & Err.Description & vbCrLf & _
    "in Function: FIOShort in module: modTools", vbCritical, "Error in Application"
    Err.Clear
    Resume FIOShort_End
End Function

=IIf(InStr(InStr([ФИО];" ")+1;[ФИО];" ")>0;Mid([ФИО];1;InStr([ФИО];" ")-1) & (" "+Mid([ФИО];InStr([ФИО];" ")+1;1)+".") & (" "+Mid([ФИО];InStrRev([ФИО];" ")+1;1)+".");Mid([ФИО];1;InStr([ФИО];" ")-1) & (" "+Mid([ФИО];InStr([ФИО];" ")+1;1)+"."))