Запустить внешнее приложение, передать ему параметры и получить результат

@Andrew Puchinin · Регистрация: 25.04.2016

Author24 — интернет-сервис помощи студентам

Здравствуйте.
Проблема такая:

Delphi

1	RunCommand(exe_name,[exe_param],output);

Думаю, что такое exe_name и exe_param, пояснять не надо)
Дебаг показал, что на этой строчке программа стопорится и дальше не идет. Сколько бы энтеров я ни нажал в своей консольке.
В чем может быть проблема? Перепробовал кучу вариантов... если что: задача запустить стороннюю программу, ввести в неё свои параметры и получить вывод. Если кто подкинет других вариантов, тоже буду благодарен =)

Добавлено через 10 часов 39 минут
Пробовал такой вариант

Delphi

Process:=TProcess.Create(nil);
    Process.Executable := exe_name+'.exe';
    Process.Parameters.Add(exe_param);
    Process.Options := Process.Options + [poUsePipes];
    Process.Execute;
    output:=Process.Output.ToString;
    Process.Free;

Но Process.Output.ToString сказал мне 'TInputPipeStream'... Вывода программы я так и не увидел.

@volvo · 03.02.2017, 14:45

Сообщение от Andrew Puchinin

Но Process.Output.ToString сказал мне 'TInputPipeStream'

Правильно сказал. Нужно брать вот так:

Pascal

var SL : TStringList;
// ...
  SL := TStringList.Create;
  SL.LoadFromStream(Process.Output);
  output := SL.Text;

@Andrew Puchinin · 03.02.2017, 15:06 **[ТС]**

Тоже уже пробовал, теперь стопорится на SL.LoadFromStream(Process.Output)...

Добавлено через 5 минут
Уже залез внутрь LoadFromStream():

Delphi

Procedure TStrings.LoadFromStream(Stream: TStream);    
Const
  BufSize = 1024;
  MaxGrow = 1 shl 29;
 
Var
  Buffer     : AnsiString;
  BytesRead,
  BufLen,
  I,BufDelta     : Longint;
begin
  // reread into a buffer
  try
    beginupdate;
    Buffer:='';
    BufLen:=0;
    I:=1;
    Repeat
      BufDelta:=BufSize*I;
      SetLength(Buffer,BufLen+BufDelta);
      BytesRead:=Stream.Read(Buffer[BufLen+1],BufDelta);
      inc(BufLen,BufDelta);
      If I<MaxGrow then
        I:=I shl 1;
    Until BytesRead<>BufDelta;
    SetLength(Buffer, BufLen-BufDelta+BytesRead);
    SetTextStr(Buffer);
    SetLength(Buffer,0);
  finally
    EndUpdate;
  end;
end;

Как я понял, проблема в цикле - он не завершается. Почему, сказать не могу.

Добавлено через 3 минуты
Отдебажить функцию почему-то не дает

@volvo · 03.02.2017, 16:29

poWaitOnExit в опции процесса добавь, чтобы он завершился к тому моменту, как будет производиться чтение результатов его выполнения.

@Andrew Puchinin · 03.02.2017, 17:00 **[ТС]**

Добавлял) Тогда тормозит на Process.Execute

Добавлено через 3 минуты
Давайте уточню: если моя сторонняя программа

Delphi

program project1;
 
var
  a,b: string;
 
begin
  read(a);
  read(b);
  writeln('!',a,',',b,'!');
end.

то Process.Parameters.Add('1 2') передаст нужные аргументы в стороннюю программу?..

@volvo · 03.02.2017, 17:10

Нет. Parameters - это параметры командной строки, которые читаются через ParamStr(...). А то, что ты хочешь прочесть через Read/ReadLn - это нужно писать в Process.Input (который как раз и присоединен к стандартному потоку ввода процесса)...

@Andrew Puchinin · 03.02.2017, 17:36 **[ТС]**

О, класс, спасибо! А как его использовать, напишите, пожалуйста. Пробую два варианта:

Pascal

1	Process.Input:=exe_param;

и

Pascal

1	Process.Input(exe_param)

На второе говорит

Error: Illegal expression

на первое

Error: No member is provided to access property

Добавлено через 15 минут
Нашел:

Pascal

1	Process.Input.Write(exe_param,length(exe_param));

Только ран-тайм вылетает... SIGSEGV

@volvo · 03.02.2017, 19:10

Не знаю, что у тебя там вылетает, написал тестовую программу:

Pascal

var
  a, b : integer;
begin
  read(a);
  read(b);
  writeln('result = ', a + b);
end.

, и вот такой код:

Pascal

procedure TForm1.Button4Click(Sender: TObject);
var
  P : TProcess;
  s : string;
  L : TStringList;
begin
  P := TProcess.Create(nil);
  P.Executable := 'F:\_Volvo\Programs\lazarus\lcl_04\040.exe';
  P.Options := [poUsePipes, poNoConsole];
  P.Execute;
  s := '2 5';
  P.Input.Write(s[1], Length(s));
  P.CloseInput;
 
  L := TStringList.Create;
  L.LoadFromStream(P.Output);
  Memo2.Lines.Add(L.Text);
  L.Free;
 
  P.Free;
end;

Нормально все выполняется, и результат заносится в Memo:

@Andrew Puchinin · 03.02.2017, 19:40 **[ТС]**

Да, спасибо, заработало. Надо было в опциях поставить poNoConsole и убрать poWaitOnExit.

@volvo Супер-модератор 32955 / 21273 / 8168 Регистрация: 22.10.2011 Сообщений: 36,542 Записей в блоге: 8
	03.02.2017, 16:29	4
	poWaitOnExit в опции процесса добавь, чтобы он завершился к тому моменту, как будет производиться чтение результатов его выполнения. 0

@volvo Супер-модератор 32955 / 21273 / 8168 Регистрация: 22.10.2011 Сообщений: 36,542 Записей в блоге: 8
	03.02.2017, 17:10	6
	Нет. Parameters - это параметры командной строки, которые читаются через ParamStr(...). А то, что ты хочешь прочесть через Read/ReadLn - это нужно писать в Process.Input (который как раз и присоединен к стандартному потоку ввода процесса)... 2

@Andrew Puchinin 2 / 5 / 1 Регистрация: 25.04.2016 Сообщений: 125
	03.02.2017, 19:40 [ТС]	9
	Да, спасибо, заработало. Надо было в опциях поставить poNoConsole и убрать poWaitOnExit. 0

Запустить внешнее приложение, передать ему параметры и получить результат

Решение