Существует ли WinAPI для подготовки строки PATH к использованию в wsprintf - удвоить в строке одиночные '\'

include '%fasm%/win64w.inc' ;; 'win64w.fincg'
format PE64 CONSOLE ;; 6.2 at 0x1_0000
section '.flat' code readable executable writeable


multi_concatenation:
        pop rdx
        xchg rax,rsi
.strcpy:
        pop rsi
.copy:  movsb
        cmp byte [rsi],0
        jnz .copy
        cmp qword [rsp],0
        jnz .strcpy
        xchg rax,rsi
        pop rax
        jmp rdx


Example:
virtual at RBP - .FRAME
                        dq ?,?,?,?
        .P5             dq ?,?

        .FRAME := $ - $$
assert .FRAME and 15 = 0
end virtual
        entry $
        enter .FRAME,0

; GetCurrentDirectory
; SHGetFolderPath
        mov ecx,sizeof input_buffer
        lea rdx,[input_buffer]
        call [GetCurrentDirectoryA]
        test eax,eax
        jz .fail

; pretend we don't know where the path came from, scan string to find end
        push rdi
        lea rdi,[input_buffer]
        mov ecx,-1
        xor eax,eax
        repnz scasb
        ; RDI points to byte after zero byte!
        not ecx ; string bytes
        sub ecx,1
        jz .fail ; zero length path

        std ; move backward from end of string
        scasb ; backup to zero byte
        mov al,'\'
        push 0 ; terminator for multi_concatenation
; gather non-slash fragments
.more:
        mov byte [rdi+1],0 ; null terminate this fragment
        repnz scasb
        lea rdx,[rdi+2] ; our string fragment ; RDI is byte before slash
        push rdx
        lea rdx,[slashslash]
        push rdx
        jz .more
        pop rdx
        pop rdx
        push rdi ; last fragment is always string start

        cld ; back to default direction
        lea rdi,[output_buffer]
        call multi_concatenation
        xchg eax,edi
        lea rdi,[output_buffer]
        sub eax,edi ; byte in output buffer
        pop rdi
        mov dword [.P5],eax

        push STD_OUTPUT_HANDLE
        pop rcx
        call [GetStdHandle]
        xchg rcx,rax
        xor r9,r9
        mov r8d,dword [.P5]
        lea rdx,[output_buffer]
        mov [.P5],r9
        call [WriteConsoleA]
.fail:
        leave
        retn

slashslash db '\\',0

libraries 'kernel32' ; import section


label input_buffer:4096
rb sizeof input_buffer

label output_buffer:4096
rb sizeof output_buffer