Связать memo с текстом между тегами(html)

procedure TForm1.Button2Click(Sender: TObject);
begin
opendialog1.execute;
Memo1.lines.loadfromfile(opendialog1.FileName);
end;
 
end.

uses
  MSHTML;

Acid_Burn, это надо получить доступ к объектной модели HTML документа (DOM)

uses
  MSHTML, ActiveX;
 
procedure TForm1.Button1Click(Sender: TObject);
const
  Fn = 'file.html';
var
  F : File;
  FileName : String;
  S : String;
  VS : Variant;
  i, Len : Integer;
  IDoc : DispHTMLDocument;
  IDoc2 : IHTMLDocument2;
  Elems : IHTMLElementCollection;
  Elem : IHTMLElement;
begin
  FileName := ExtractFilePath( ParamStr(0) ) + Fn;
  if not FileExists(FileName) then begin
    MessageDlg(
      'Заданный файл не найден. Действие отменено.'
      , mtWarning, [mbOk], 0
    );
    Exit;
  end;
 
  //Загружаем данные из файла в строку.
  AssignFile(F, FileName);
  Reset(F, 1);
  Len := FileSize(F);
  SetLength(S, Len);
  BlockRead(F, Pointer(S)^, Len);
  CloseFile(F);
 
  //Получаем доступ к OLE объекту, представляющему HTML DOM,
  //через интерфейс DispHTMLDocument.
  IDoc := CoHTMLDocument.Create;
 
  //Чтобы загрузить текстовые данные в объект документа, требуется
  //представить их в виде вариантного массива. Т. е., надо создать
  //вариантный массив из одного элемента и в качестве данных
  //элемента массива прикрепить строку.
  VS := VarArrayCreate([0, 0], varVariant);
  VS[0] := S;
  //Подключаемся к OLE объекту через интерфейс IHTMLDocument2.
  IDoc2 := IDoc as IHTMLDocument2;
  //Создаём содержимое документа на основе данных строки.
  IDoc2.write(PSafeArray(TVarData(VS).VArray));
 
  //Получаем содержимое элемента body.
  Memo1.Text := IDoc2.body.innerHTML;
  //Также можно установить новое содержимое для этого элемента.
  //IDoc.body.innerHTML := Memo1.Text;
 
  //Теперь, прочитаем сведения о всех элементах с тегом <A>: <a href="">...</a>.
 
  //Коллекция всех элементов с тегом <A>, имеющихся в документе.
  Elems := IDoc.getElementsByTagName('A');
  Memo2.Lines.Add('--------------------------------------------------');
  Memo2.Lines.Add('Перечень всех элементов с тегом <A> в документе:');
  for i := 0 to Elems.length - 1 do begin
    Elem := Elems.item(i, 0) as IHTMLElement;
    Memo2.Lines.Add(IntToStr(i) + ':');
    Memo2.Lines.Add(Elem.outerHTML);
    Memo2.Lines.Add('-----');
  end;
end;

uses
  MSHTML, ActiveX;
 
//Построение модели HTML DOM по HTML коду из потока.
function GetDomFromStream(aStream : TStream) : DispHTMLDocument;
var
  S : String; //AnsiString
  VS : Variant;
  Len : Integer;
  IDoc2 : IHTMLDocument2;
begin
  //Загружаем данные из потока в строку.
  Len := aStream.Size;
  SetLength(S, Len);
  aStream.Read(Pointer(S)^, Len);
 
  //Получаем доступ к OLE объекту, представляющему HTML DOM,
  //через интерфейс DispHTMLDocument.
  Result := CoHTMLDocument.Create;
 
  //Чтобы загрузить текстовые данные в объект документа, требуется
  //представить их в виде вариантного массива. Т. е., надо создать
  //вариантный массив из одного элемента и в качестве данных
  //элемента массива прикрепить строку.
  VS := VarArrayCreate([0, 0], varVariant);
  VS[0] := S;
  //Подключаемся к OLE объекту через интерфейс IHTMLDocument2.
  IDoc2 := Result as IHTMLDocument2;
  //Создаём содержимое документа на основе данных строки.
  IDoc2.write(PSafeArray(TVarData(VS).VArray));
end;
 
//Построение модели HTML DOM по HTML коду из файла.
function GetDomFromFile(const aFileName : String) : DispHTMLDocument;
var
  Fs : TFileStream;
begin
  Fs := TFileStream.Create(aFileName, fmOpenRead, fmShareDenyNone);
  Result := GetDomFromStream(Fs);
  FreeAndNil(Fs);
end;
 
procedure TForm1.Button1Click(Sender: TObject);
const
  Fn = 'file.html';
var
  FileName : String;
  IDoc : DispHTMLDocument;
  Elems : IHTMLElementCollection;
  Elem : IHTMLElement;
  i : Integer;
begin
  FileName := ExtractFilePath( ParamStr(0) ) + Fn;
  if not FileExists(FileName) then begin
    MessageDlg(
      'Заданный файл не найден. Действие отменено.'
      , mtWarning, [mbOk], 0
    );
    Exit;
  end;
 
  //Подключаемся к HTML DOM.
  IDoc := GetDomFromFile(FileName);
 
  //Читаем сведения о первом элементе с тегом <BODY>.
 
  //Коллекция всех элементов с тегом <BODY>, имеющихся в документе.
  Elems := IDoc.getElementsByTagName('BODY');
  Memo1.Lines.Add('--------------------------------------------------');
  Memo1.Lines.Add('Содержимое "главного" элемента BODY в документе:');
  if Elems.length > 0 then begin
    Elem := Elems.item(0, 0) as IHTMLElement;
    Memo1.Lines.Add(Elem.outerHTML);
  end;
 
  //Читаем сведения о всех элементах с тегом <A>: <a href="">...</a>.
 
  //Коллекция всех элементов с тегом <A>, имеющихся в документе.
  Elems := IDoc.getElementsByTagName('A');
  Memo1.Lines.Add('--------------------------------------------------');
  Memo1.Lines.Add('Перечень всех элементов с тегом <A> в документе:');
  for i := 0 to Elems.length - 1 do begin
    Elem := Elems.item(i, 0) as IHTMLElement;
    Memo1.Lines.Add(IntToStr(i) + ':');
    Memo1.Lines.Add(Elem.outerHTML);
    Memo1.Lines.Add('-----');
  end;
end;