Карта парковки

unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, Grids, StdCtrls;
 
type
  TForm1 = class(TForm)
    btnBusy: TButton;
    btnFree: TButton;
    StringGrid1: TStringGrid;
    procedure FormCreate(Sender: TObject);
    procedure StringGrid1DrawCell(Sender: TObject; ACol, ARow: Integer;
      Rect: TRect; State: TGridDrawState);
    procedure btnBusyClick(Sender: TObject);
    procedure btnFreeClick(Sender: TObject);
    procedure StringGrid1DblClick(Sender: TObject);
  private
    { Private declarations }
    p: array[0..6, 0..19] of byte;
  public
    { Public declarations }
  end;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.dfm}
 
procedure TForm1.FormCreate(Sender: TObject);
var
  x, y: integer;
begin
  with StringGrid1 do
  begin
    FixedCols := 0;
    FixedRows := 0;
    DefaultColWidth := 45;
    ColCount := 20;
    RowCount := 7;
    for y := 0 to RowCount-1 do
      for x := 0 to ColCount-1 do
        Cells[x, y] := Format('р%d, м%d', [y, x]);
  end;
end;
 
procedure TForm1.StringGrid1DrawCell(Sender: TObject; ACol, ARow: Integer;
  Rect: TRect; State: TGridDrawState);
const CellCol: array[0..1] of TColor = (clLime, clYellow);
var dx, dy: integer;
begin
  with (Sender as TStringGrid) do
  begin
    Canvas.Brush.Color := CellCol[p[ARow, ACol]];
    Canvas.FillRect(Rect);
    if gdSelected in State then begin
      Canvas.Pen.Color := clFuchsia;
      Canvas.Pen.Width := 2;
      Canvas.Rectangle(Rect.Left+1, Rect.Top+1, Rect.Right, Rect.Bottom);
//      Canvas.RoundRect(Rect.Left+1, Rect.Top+1, Rect.Right, Rect.Bottom, 10, 10);
    end;
    Canvas.Font.Color := clBlack;
    dx := (Rect.Right - Rect.Left - Canvas.TextWidth(Cells[ACol, ARow])) div 2;
    dy := (Rect.Bottom - Rect.Top - Canvas.TextHeight(Cells[ACol, ARow])) div 2;
    Canvas.TextOut(Rect.Left+dx, Rect.Top+dy, Cells[ACol, ARow]);
  end;
end;
 
procedure TForm1.btnBusyClick(Sender: TObject);
var
  x, y: integer;
begin
  with StringGrid1.Selection do
    for y := Top to Bottom do
      for x := Left to Right do
        p[y, x] := 1;
  StringGrid1.Invalidate;
end;
 
procedure TForm1.btnFreeClick(Sender: TObject);
var
  x, y: integer;
begin
  with StringGrid1.Selection do
    for y := Top to Bottom do
      for x := Left to Right do
        p[y, x] := 0;
  StringGrid1.Invalidate;
end;
 
procedure TForm1.StringGrid1DblClick(Sender: TObject);
var
  r: TRect;
begin
  with StringGrid1.Selection do begin
    p[Top, Left] := 1 - p[Top, Left];
    r := StringGrid1.CellRect(Left, Top);
  end;
  InvalidateRect(StringGrid1.Handle, @r, false);
//  StringGrid1.Invalidate;
end;
 
end.