Линия со стрелкой (ООП)

@Kirchberg · Регистрация: 23.12.2018

Author24 — интернет-сервис помощи студентам

Здравствуйте, мне нужно сделать класс, позволяющий рисовать линию некоторого размера и заданного направления из точки, определенной нажатием левой клавиши мыши. Класс, позволяющий рисовать такую же линию, но со стрелкой.

В моем тексте программы я никак не могу понять как сделать у конца линии нормальную стрелку, может кто поможет?

Добавлено через 44 секунды

Delphi

unit Line;
 
interface
 
uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls, Vcl.ExtCtrls;
 
type
  TForm1 = class(TForm)
    ExitButton: TButton;
    Image: TImage;
    RadioGroup1: TRadioGroup;
    procedure ExitButtonClick(Sender: TObject);
    procedure FormActivate(Sender: TObject);
    procedure ImageMouseDown(Sender: TObject; Button: TMouseButton;
      Shift: TShiftState; X, Y: Integer);
  private
    { Private declarations }
  public
    { Public declarations }
  end;
 
var
  Form1: TForm1;
 
implementation
{$R *.dfm}
 
procedure TForm1.ExitButtonClick(Sender: TObject); // Кнопка выхода
begin
  close;
end;
 
//Линия
 
procedure TForm1.FormActivate(Sender: TObject); // Фон изображения
begin
  Image.Canvas.Brush.Color:= clWhite;  //При активации программы становится белым фон
end;
 
procedure TForm1.ImageMouseDown(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);   //Нажатие левой и правой кнопки мыши
var P1,P2:TPoint; Angle:real; P3,P4:TPoint;
begin
  Image.Canvas.Pen.Color:= clBlack;
  Image.Canvas.Pen.Width:= 4;
 
 
  if button = mbLeft then
    begin
      Image.Canvas.MoveTo(x,y);
      Image.Canvas.Pen.color:=clBlack;
      Image.Canvas.Brush.color:=clBlack;
      Image.Canvas.Ellipse(x,y,x+2,y+2); //Создаю точку при нажатии на фон (Начало координат линии)
    end;
 
   case RadioGroup1.ItemIndex of
 
        0: begin
            if button = mbRight then
              Image.Canvas.LineTo(x,y); //Стандартная линия
        end;
 
        1: begin
           if button = mbRight then
            Image.Canvas.LineTo(x,y);   //Стандартная линия со стрелкой на конце
            //Вот здесь нужно нарисовать у конца линии стрелку
   end;
 
end;
 
 
end.

@Puporev · 03.02.2019, 18:06

Стрелку нарисовать можно так.

Delphi

var
  Form1: TForm1;
  x1,y1,x2,y2:integer; //координаты 1 и 2 точек
implementation
 
{$R *.dfm}
uses Math;
//функция определения угла
function ugol(x1,y1,x2,y2:integer):double;
var r,c:real;
begin
r:=sqrt(sqr(x2-x1)+sqr(y2-y1));//расстояние от центра до вершины
c:=(x2-x1)/r; //косинус угла
if y2<y1 then ugol:=arccos(c)//вершина ниже цнтра
else ugol:=2*pi-arccos(c);  //выше или = y1
end;
procedure strelka(x1,y1,x2,y2:integer;cv:TCanvas);
var p:array[1..4] of TPoint;
    u:double;
begin
u:=ugol(x1,y1,x2,y2);
p[1].X:=x2;
p[1].Y:=y2;
p[2].X:=p[1].X+round(-20*cos(u+pi/8));
p[2].Y:=p[1].Y-round(-20*sin(u+pi/8));
p[3].X:=p[1].X+round(-20*cos(u-pi/8));
p[3].Y:=p[1].Y-round(-20*sin(u-pi/8));
p[4]:=p[1];
cv.polygon(p); //рисуем стрелку
end;
procedure TForm1.FormMouseDown(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
begin
  Canvas.Pen.Color:=clBlack;
  Canvas.Pen.Width:=2;
  Canvas.Brush.color:=clBlack;
  if button = mbLeft then
    begin
      x1:=x;
      y1:=y;
      Canvas.MoveTo(x,y);
      Canvas.Ellipse(x-1,y-1,x+1,y+1); //Создаю точку при нажатии на фон (Начало координат линии)
    end;
 if button = mbRight then
  begin
   x2:=x;
   y2:=y;
   Canvas.LineTo(x2,y2); //Стандартная линия
   if RadioGroup1.ItemIndex=1 then strelka(x1,y1,x2,y2,Canvas);
  end;
end;

Verevkin · 03.02.2019, 19:16

У меня для тебя есть готовая халява. Дарю.

Кликните здесь для просмотра всего текста

Delphi

unit uCanvasUtils;
 
interface
 
uses
  //============================== Модули проекта ==============================
  //=============================== Левые модули ===============================
  //=================== Системные модули, добавленные вручную ==================
  Types, UITypes, Classes, Controls, ComCtrls, StdCtrls, Math,
  Graphics, Generics.Collections;
 
const
  COLOR_SINUS = clRed;
  COLOR_AXIS  = clYellow;
  COLOR_GRID  = clGreen;
 
type
  TArrowStyle = (asToP1, asToP2, asBoth);
 
procedure Connect2Points(cv: TCanvas; p1, p2: TPoint);
procedure DiagonLBRT(cv: TCanvas; const r: TRect);
procedure Diameter(cv: TCanvas; const cp: TPoint; const radius: Integer; const angle: Single);
procedure DrawAxis(cv: TCanvas; const r: TRect; const cp: TPoint);
procedure DrawWave(cv: TCanvas; const R: TRect; const Freq, Phs, Scale: Single);
procedure DrawCross(cv: TCanvas; x, y, radius: Integer);
procedure DrawMarkerC(cv: TCanvas; x, y, radius: Integer);
procedure DrawMarkerR(cv: TCanvas; x, y, radius: Integer);
procedure PaintConnect(cv: TCanvas; Rect1, Rect2: TRect);
procedure DrawArrow(Canvas: TCanvas; X1, Y1, X2, Y2: Integer; LW: Extended); overload; // рисование стрелки
procedure DrawArrow(cv: TCanvas; p1, p2: TPoint; LW: Extended); overload; // рисование стрелки
 
procedure DrawBackgroundGrid(ACanvas: TCanvas;
                             const AArea: TRect;
                             const AStep: Integer;
                             const AColor1, AColor2: TColor);
function GetTextPosition(const Text: string;                            // текст
                         const Canvas: TCanvas;                         // канва
                         const Rect: TRect;                             // прямоугольник отрисовки
                         const TextMarginHrz: Integer;                  // размер гориз. отступов
                         const TextMarginVrt: Integer;                  // размер вертик. отступов
                         const Alignment: TAlignment= taCenter;         // гориз. выравнивание
                         const Layout: TTextLayout = tlCenter): TPoint; // верт. выравнивание
procedure DrawTextPosition(const Text: string;                            // текст
                           const Canvas: TCanvas;                         // канва
                           const Rect: TRect;                             // прямоугольник отрисовки
                           const TextMarginHrz: Integer;                  // размер гориз. отступов
                           const TextMarginVrt: Integer;                  // размер вертик. отступов
                           const Alignment: TAlignment = taCenter;        // гориз. выравнивание
                           const Layout: TTextLayout = tlCenter);         // верт. выравнивание
 
function NewPen(const AColor: TColor = clBlack;
                const AWidth: int32 = 1;
                const AStyle: TPenStyle = psSolid;
                const AMode: TPenMode = pmCopy): TPen;
function NewBrush(const AColor: TColor = clWhite;
                  const AStyle: TBrushStyle = bsSolid): TBrush;
 
implementation
 
procedure Connect2Points(cv: TCanvas; p1, p2: TPoint);
begin
  cv.MoveTo(p1.X, p1.Y);
  cv.LineTo(p2.X, p2.Y);
end;
 
procedure DiagonLBRT(cv: TCanvas; const r: TRect);
begin
  Connect2Points(cv, Point(r.Left, r.Bottom), Point(r.Right, r.Top));
end;
 
function RotatePoint(const APt, ASc: TPoint; const AAngle: Single): TPoint;
var
  r: Single;
  psi: Single;
begin
  r:= ASc.Distance(APt);
  psi:= ASc.Angle(APt) + AAngle;
  Result.X:= Round(ASc.X - r * cos(psi));
  Result.Y:= Round(ASc.Y - r * sin(psi));
end;
 
procedure Diameter(cv: TCanvas; const cp: TPoint; const radius: Integer; const angle: Single);
var
  p1, p2: TPoint;
begin
  p1:= RotatePoint(Point(cp.X + radius, cp.Y), cp, angle);
  p2:= RotatePoint(Point(cp.X - radius, cp.Y), cp, angle);
  Connect2Points(cv, p1, p2);
end;
 
procedure DrawAxis(cv: TCanvas; const r: TRect; const cp: TPoint);
begin
  Connect2Points(cv, Point(cp.X, r.Top), Point(cp.X, r.Bottom));
  Connect2Points(cv, Point(r.Left, cp.Y), Point(r.Right, cp.Y));
end;
 
procedure DrawWave(cv: TCanvas; const R: TRect; const Freq, Phs, Scale: Single);
var
  x, y, idx: Integer;
  psi: Single;
  mult: Single;
begin
  if (R.Width < 2) or (Freq < 0)
    then Exit;
 
  // grid
  cv.Pen.Color:= COLOR_GRID;
  cv.Pen.Width:= 1;
  for idx:= 1 to 9 do
    begin
      x:= Round(idx * R.Width / 10);
      Connect2Points(cv, Point(x, R.Top), Point(x, R.Bottom));
    end;
 
  for idx:= 1 to 7 do
    begin
      y:= Round(idx * R.Height / 8);
      Connect2Points(cv, Point(R.Left, y), Point(R.Right, y));
    end;
  // axis
  cv.Pen.Color:= COLOR_AXIS;
  Connect2Points(cv, Point(R.Left, R.CenterPoint.Y), Point(R.Right, R.CenterPoint.Y));
  Connect2Points(cv, Point(R.CenterPoint.X, R.Top), Point(R.CenterPoint.X, R.Bottom));
 
  mult:= Freq / 100.0;
  //cv.MoveTo(-2, R.CenterPoint.Y);
  cv.Pen.Color:= COLOR_SINUS;
  cv.Pen.Width:= 2;
 
  for x:= 0 to R.Width - 1 do
    begin
      psi:= 2 * pi * (x - R.CenterPoint.X) * mult / (R.Width - 1);
      y:= R.CenterPoint.Y + Trunc(Scale * 0.5 * R.Height * -sin(psi + Phs));
 
      if x <> 0
        then cv.LineTo(x, y)
        else cv.MoveTo(x, y);
    end;
end;
 
 
procedure DrawCross(cv: TCanvas; x, y, radius: Integer);
begin
  Connect2Points(cv, Point(x - radius, y), Point(x + radius, y));
  Connect2Points(cv, Point(x, y - radius), Point(x, y + radius));
end;
 
procedure DrawMarkerC(cv: TCanvas; x, y, radius: Integer);
var
  r: TRect;
begin
  r:= Rect(x - radius + 1, y - radius + 1, x + radius, y + radius);
  //cv.Brush.Color:= COLOR_MARKER;
  cv.Ellipse(r);
end;
 
procedure DrawMarkerR(cv: TCanvas; x, y, radius: Integer);
var
  pts: array[0..3] of TPoint;
begin
  pts[0]:= Point(x - radius, y); // L
  pts[1]:= Point(x, y - radius); // T
  pts[2]:= Point(x + radius, y); // R
  pts[3]:= Point(x, y + radius); // B
  //cv.Brush.Color:= COLOR_MARKER;
  cv.Polygon(pts);
end;
 
function Square(const cp: TPoint; const radius: int32): TRect;
begin
  Result:= Rect(cp.X - radius, cp.Y - radius, cp.X + radius, cp.Y + radius);
end;
 
{-------------------------- Прорисовка соединения -----------------------------}
procedure PaintConnect(cv: TCanvas; Rect1, Rect2: TRect);
const
  SArrow = 7;
  LArrow = 9;
var
  R1, R2, x1, x2, y1, y2, Lx1, Lx2, Ly1, Ly2: Integer;
 //----------- Окружность, описанная около прямоугольника -----------
 
  procedure _Circle(Rect: TRect);
  var
    x1, y1, x2, y2, r: Integer;
  begin
    with Rect do
    begin
      r := Round((SqRt(SqR(Bottom - Top) + SqR(Right - Left)) / 2));
      x1 := Left + Round((Right - Left) / 2) - r;
      x2 := Left + Round((Right - Left) / 2) + r;
      y1 := Top + Round((Bottom - Top) / 2) - r;
      y2 := Top + Round((Bottom - Top) / 2) + r;
    end;
    cv.Ellipse(x1, y1, x2, y2);
  end;
//---------- Линия-коннектор между двумя окружностями -----------
 
  procedure _CutLine(x1, y1, x2, y2, R1, R2: Integer);
  var
    dx1, dx2, dy1, dy2, L: Integer;
  begin
    L := Round(SqRt(SqR(x2 - x1) + SqR(y2 - y1)));
    dx1 := Round((x2 - x1) * (R1 / L));
    dy1 := -Round((y1 - y2) * (R1 / L));
    dx2 := -Round((x2 - x1) * (R2 / L));
    dy2 := Round((y1 - y2) * (R2 / L));
    Lx1 := x1 + dx1;
    Ly1 := y1 + dy1;
    Lx2 := x2 + dx2;
    Ly2 := y2 + dy2;
    cv.MoveTo(Lx1, Ly1);
    cv.LineTo(Lx2, Ly2);
  end;
//------------- Отрезок --------------
 
  procedure _Line(x1, y1, x2, y2: Integer);
  begin
    cv.MoveTo(x1, y1);
    cv.LineTo(x2, y2);
  end;
//--------- Наконечники стрелки -----------
 
  procedure _Arrow(x1, y1, x2, y2: Integer; Style: TArrowStyle);
  var
    B, C: TPoint;
    Sinus, Cosinus: Single;
    L, H: Integer;
  begin
    L := Round(SqRt(SqR(x2 - x1) + SqR(y2 - y1)));
    Sinus := (y1 - y2) / L;
    Cosinus := (x2 - x1) / L;
    B.x := Round(LArrow * Cosinus - SArrow * Sinus / 2);
    B.y := Round(LArrow * Sinus + SArrow * Cosinus / 2);
    C.x := Round(LArrow * Cosinus + SArrow * Sinus / 2);
    C.y := Round(LArrow * Sinus - SArrow * Cosinus / 2);
    H := Round(SqRt(SqR(LArrow) + SqR(SArrow) / 4));
 
    case Style of
      asToP1:
        cv.Pie(x1 - H, y1 - H, x1 + H, y1 + H, x1 + C.x, y1 - C.y, x1 + B.x, y1 - B.y);
      asToP2:
        cv.Pie(x2 - H, y2 - H, x2 + H, y2 + H, x2 - C.x, y2 + C.y, x2 - B.x, y2 + B.y);
      asBoth:
        begin
          cv.Pie(x1 - H, y1 - H, x1 + H, y1 + H, x1 + C.x, y1 - C.y, x1 + B.x, y1 - B.y);
          cv.Pie(x2 - H, y2 - H, x2 + H, y2 + H, x2 - C.x, y2 + C.y, x2 - B.x, y2 + B.y);
        end;
    end; //case
  end;
 
  // Вычисление радиуса окружности, описывающей прямоугольник
  function _RectRadius(Rect:TRect):Integer;
  begin
   with Rect do
    Result:=Round(SqRt(SqR(Right-Left)+SqR(Bottom-Top))/2);
  end;
 
begin //PaintConnect
  //C := cv.Pen.Color;
  //OldStyle := cv.Brush.Style;
  //OldMode := cv.Pen.Mode;
  //cv.Pen.Color := Color;
  //cv.Brush.Style := bsClear;
  //cv.Brush.Color:=Color;
  //cv.Pen.Mode := pmNotXor;
  //CorrectRect(Rect1, ScrollBox.HorzScrollBar.Position, ScrollBox.VertScrollBar.Position);
  //CorrectRect(Rect2, ScrollBox.HorzScrollBar.Position, ScrollBox.VertScrollBar.Position);
  R1 := _RectRadius(Rect1);
  R2 := _RectRadius(Rect2);
  x1 := Rect1.CenterPoint().x;
  y1 := Rect1.CenterPoint().y;
  x2 := Rect2.CenterPoint().x;
  y2 := Rect2.CenterPoint().y;
  _Circle(Rect1);
  _Circle(Rect2);
  _CutLine(x1, y1, x2, y2, R1, R2);
  //cv.Brush.Style := bsSolid;
  //cv.Brush.Color := Color;
 // _Arrow(Lx1, Ly1, Lx2, Ly2, asBoth);
  //cv.Brush.Style := OldStyle;
  //cv.Pen.Color := C;
  //cv.Brush.Color := C;
  //cv.Pen.Mode := OldMode;
end;
 
 
procedure DrawArrowHead(Canvas: TCanvas; X,Y: Integer; Angle, LW: Extended);
var
  A1,A2:    Extended;
  Arrow:    array[0..3] of TPoint;
  OldWidth: Integer;
const
  Beta     =  0.322;
  LineLen  =   4.74;
  CentLen  =      3;
begin
  Angle:=Pi+Angle;
  Arrow[0]:=Point(X,Y);
  A1:=Angle-Beta;
  A2:=Angle+Beta;
  Arrow[1]:=Point(X+Round(LineLen*LW*Cos(A1)),Y-Round(LineLen*LW*Sin(A1)));
  Arrow[2]:=Point(X+Round(CentLen*LW*Cos(Angle)),Y-Round(CentLen*LW*Sin(Angle)));
  Arrow[3]:= Point(x + Round(LineLen * LW * cos(A2)),
    y - Round(LineLen * LW * sin(A2)));
  OldWidth        := Canvas.Pen.Width;
  Canvas.Pen.Width:= 1;
  Canvas.Polygon(Arrow);
  Canvas.Pen.Width:= OldWidth
end;
 
procedure DrawArrow(Canvas: TCanvas; X1, Y1, X2, Y2: Integer; LW: Extended);
var
  angle: Extended;
begin
  //спёр отсюда: http://www.programmersclub.ru/нарисовать-стрелку-на-делфи/
  angle:= ArcTan2(Y1 - Y2, X2 - X1);
  Canvas.MoveTo(X1, Y1);
  Canvas.LineTo(X2 - Round(2 * LW * cos(angle)),
    Y2 + Round(2 * LW * sin(angle)));
  DrawArrowHead(Canvas, X2, Y2, angle, LW);
end;
 
procedure DrawArrow(cv: TCanvas; p1, p2: TPoint; LW: Extended);
begin
  DrawArrow(cv, p1.x, p1.y, p2.x, p2.y, LW);
end;
 
//рисование клеток фона
procedure DrawBackgroundGrid(ACanvas: TCanvas; const AArea: TRect;
  const AStep: Integer; const AColor1, AColor2: TColor);
var
 Row, Col, RW, RH: Integer;
 Colors:           array [Boolean] of TColor;
 ColorSwitcher:    Boolean;
begin
  Colors[False]:= AColor1;
  Colors[True]:= AColor2;
 
//  ColorSwitcher:= False;
 
  RW:= RectWidth(AArea);
  RH:= RectHeight(AArea);
 
  ACanvas.Brush.Style:= bsSolid;
  //ACanvas.Brush.Color:= AColor1;
  //ACanvas.Rectangle(AArea); а не тут ли?
 
  Row:= 0;
  repeat
    Col:= 0;
    ColorSwitcher:= Boolean(Row and 1);
    ACanvas.Brush.Color:= Colors[ColorSwitcher]; // начальный цвет (серый $C0C0C0)
    ACanvas.Pen.Color:= ACanvas.Brush.Color;
 
    repeat
      //ACanvas.Brush.Color:= Colors[ColorSwitcher];
      //ACanvas.Pen.Color:= ACanvas.Brush.Color;
      //ColorSwitcher:= not ColorSwitcher;
 
      ACanvas.Rectangle(AArea.Left + Col * AStep,
                        AArea.Top  + Row * AStep,
                        AArea.Left + (Col + 1) * AStep,
                        AArea.Top  + (Row + 1) * AStep);
      Inc(Col);
 
      ColorSwitcher:=       not ColorSwitcher;
      ACanvas.Brush.Color:= Colors[ColorSwitcher];
      ACanvas.Pen.Color:=   ACanvas.Brush.Color;
    until Col * AStep > RW;
 
    Inc(Row);
  until Row * AStep > RH;
end;
 
// Начальная точка вывода текста на канве внутри прямоугольника Rect
// с выравниванием горизонтальным и вертикальным
// для вывода предельных величин графика функции (по углам)
function GetTextPosition(const Text: string;                 // текст
                         const Canvas: TCanvas;              // канва
                         const Rect: TRect;                  // прямоугольник отрисовки
                         const TextMarginHrz: Integer;       // размер гориз. отступов
                         const TextMarginVrt: Integer;       // размер вертик. отступов
                         const Alignment: TAlignment;        // гориз. выравнивание
                         const Layout: TTextLayout): TPoint; // верт. выравнивание
var
  th, tw: Integer;
begin
  tw:= Canvas.TextWidth(Text);
  th:= Canvas.TextHeight(Text);
 
  case Alignment of
    taLeftJustify  : Result.x:= TextMarginHrz;
    taCenter       : Result.x:= ((Rect.Right - Rect.Left) div 2) - (tw div 2);
    taRightJustify : Result.x:= (Rect.Right - Rect.Left) - tw - TextMarginHrz;
  end; //case
 
  case Layout of
    tlTop:    Result.y:= TextMarginVrt;
    tlCenter: Result.y:= ((Rect.Bottom - Rect.Top) div 2) - (th div 2);
    tlBottom: Result.y:= (Rect.Bottom - Rect.Top) - th - TextMarginVrt;
  end; // case
end;
 
procedure DrawTextPosition(const Text: string;                 // текст
                           const Canvas: TCanvas;              // канва
                           const Rect: TRect;                  // прямоугольник отрисовки
                           const TextMarginHrz: Integer;       // размер гориз. отступов
                           const TextMarginVrt: Integer;       // размер вертик. отступов
                           const Alignment: TAlignment;        // гориз. выравнивание
                           const Layout: TTextLayout);         // верт. выравнивание
var
  tp: TPoint;
begin
  tp:= GetTextPosition(Text, Canvas, Rect, TextMarginHrz, TextMarginVrt, Alignment, Layout);
  Canvas.TextRect(Rect, Rect.Left + tp.X, Rect.Top + tp.Y, Text);
  //Canvas.TextOut(Rect.Left + tp.X, Rect.Top + tp.Y, Text);
end;
 
function NewPen(const AColor: TColor = clBlack;
                   const AWidth: int32 = 1;
                   const AStyle: TPenStyle = psSolid;
                   const AMode: TPenMode = pmCopy): TPen;
begin
  result:= TPen.Create();
  result.Color:= AColor;
  result.Width:= AWidth;
  result.Style:= AStyle;
  result.Mode:=  AMode;
end;
 
function NewBrush(const AColor: TColor = clWhite;
                     const AStyle: TBrushStyle = bsSolid): TBrush;
begin
  result:= TBrush.Create();
  result.Color:= AColor;
  result.Style:= AStyle;
end;
 
end.

@krapotkin · 03.02.2019, 22:11

хорошая либа)
а вот мой жизненный путь отучил меня давать объектам модели ссылки на канвас, как и возможности рисовать себя любимых

для этого лучше делать отдельный объект, который в том числе определяет взаимное расположение объектов, масштаб всей картины и т.п.
иначе получается что каждый самый маленький объект должен знать все о всей картине и всех остальных объектах
а это приводит к монолитной немасштабируемой архитектуре ((

так что в моем мире это был бы объект, который просто хранит массив своих точек, рассчитанных на основании некоего алгоритма
а отрисовка этих точек происходит в другом месте

@Kirchberg · 04.02.2019, 11:21 **[ТС]**

Сообщение от Verevkin

procedure DrawArrow(Canvas: TCanvas; X1, Y1, X2, Y2: Integer; LW: Extended); overload; // рисование стрелки
procedure DrawArrow(cv: TCanvas; p1, p2: TPoint; LW: Extended); overload;

Извините пожалуйста, но какую из этих процедур мне нужно в мою программу? И что такое LW?

Добавлено через 46 секунд
Извините, но у меня стрелка некорректно работает (Она наклонена не на том углу)

Добавлено через 9 минут
Соре затупил все работает

Verevkin · 04.02.2019, 11:24

Сообщение от Kirchberg

Извините пожалуйста

Я тебя прощаю.

Сообщение от Kirchberg

но какую из этих процедур мне нужно в мою программу?

Любую. Первая всё равно вызывается из 2-й.

Сообщение от Kirchberg

И что такое LW?

А я ХЗ. Экспериментируй. Эти 2 функции писал не я. Я их где-то в интернетах скопипастил 100500 лет назад ещё.

Сообщение от Kirchberg

Извините, но...

Я тебя прощаю ещё раз.

Сообщение от Kirchberg

...у меня стрелка некорректно работает (Она наклонена не на том углу)

Почему у меня работает? Что я делаю не так?

Добавлено через 19 секунд

Сообщение от Kirchberg

Соре затупил все работает

Я тебя прощаю 3-й раз.

Линия со стрелкой (ООП)

Решение

Решение

Решение

@krapotkin 5860 / 4588 / 1448 Регистрация: 14.04.2014 Сообщений: 20,352 Записей в блоге: 20
	03.02.2019, 22:11	4
	Сообщение было отмечено Kirchberg как решение Решение хорошая либа) а вот мой жизненный путь отучил меня давать объектам модели ссылки на канвас, как и возможности рисовать себя любимых для этого лучше делать отдельный объект, который в том числе определяет взаимное расположение объектов, масштаб всей картины и т.п. иначе получается что каждый самый маленький объект должен знать все о всей картине и всех остальных объектах а это приводит к монолитной немасштабируемой архитектуре (( так что в моем мире это был бы объект, который просто хранит массив своих точек, рассчитанных на основании некоего алгоритма а отрисовка этих точек происходит в другом месте 0

@Kirchberg 0 / 0 / 0 Регистрация: 23.12.2018 Сообщений: 15
	04.02.2019, 11:21 [ТС]	5
	Сообщение от Verevkin procedure DrawArrow(Canvas: TCanvas; X1, Y1, X2, Y2: Integer; LW: Extended); overload; // рисование стрелки procedure DrawArrow(cv: TCanvas; p1, p2: TPoint; LW: Extended); overload; Извините пожалуйста, но какую из этих процедур мне нужно в мою программу? И что такое LW? Добавлено через 46 секунд Извините, но у меня стрелка некорректно работает (Она наклонена не на том углу) Добавлено через 9 минут Соре затупил все работает 0

Verevkin Злостный нарушитель 9507 / 5151 / 1175 Регистрация: 12.03.2015 Сообщений: 24,281
	04.02.2019, 11:24	6
	Сообщение от Kirchberg Извините пожалуйста Я тебя прощаю. Сообщение от Kirchberg но какую из этих процедур мне нужно в мою программу? Любую. Первая всё равно вызывается из 2-й. Сообщение от Kirchberg И что такое LW? А я ХЗ. Экспериментируй. Эти 2 функции писал не я. Я их где-то в интернетах скопипастил 100500 лет назад ещё. Сообщение от Kirchberg Извините, но... Я тебя прощаю ещё раз. Сообщение от Kirchberg ...у меня стрелка некорректно работает (Она наклонена не на том углу) Почему у меня работает? Что я делаю не так? Добавлено через 19 секунд Сообщение от Kirchberg Соре затупил все работает Я тебя прощаю 3-й раз. 0