VLC + Opengl

unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, dglOpenGL, PasLibVlcUnit, StdCtrls, System.SyncObjs;
 
// hxw текстуры
const
  textureWidth = 934;
  textureHeight = 563;
 
type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  private
    { Private declarations }
    p_li : libvlc_instance_t_ptr;
    p_mi : libvlc_media_player_t_ptr;
    p_md : libvlc_media_t_ptr;
 
    argv : packed array[0..254] of AnsiString;
    args : packed array[0..254] of PAnsiChar;
    argc : Integer;
    // массив данных кадра
    vlcBuffer: array [0 .. textureWidth*textureHeight*4+32] of GLbyte;
 
    procedure AddArg(value : AnsiString);
    procedure SetupGL;
    procedure IdleHandler(Sender : TObject; var Done : Boolean);
    procedure Render;
  public
    { Public declarations }
  end;
 
 
  function libvlc_video_lock(opaque : Pointer; var planes : Pointer) : Pointer; cdecl;
  function libvlc_video_unlock(opaque : Pointer; picture : Pointer; planes : Pointer) : Pointer; cdecl;
  function libvlc_video_display(opaque : Pointer; picture : Pointer) : Pointer; cdecl;
 
var
  Form1: TForm1;
  DC: HDC;
  RC: HGLRC;
 
  glTexture: GLuint;
implementation
 
{$R *.dfm}
 
function libvlc_video_lock(opaque : Pointer; var planes : Pointer) : Pointer; cdecl;
begin
  planes :=@(Form1.vlcBuffer[0]);
  Result:=nil;
end;
 
function libvlc_video_unlock(opaque : Pointer; picture : Pointer; planes : Pointer) : Pointer; cdecl;
begin
  Result:=nil;
end;
 
function libvlc_video_display(opaque : Pointer; picture : Pointer) : Pointer; cdecl;
begin
  Result:=nil;
end;
 
procedure TForm1.AddArg(value: AnsiString);
begin
  if (argc < 255) then
  begin
    argv[argc] := value;
    args[argc] := PAnsiChar(argv[argc]);
    Inc(argc);
  end;
end;
 
procedure TForm1.FormCreate(Sender: TObject);
var
  pMedia, pMediaPlayer: Pointer;
begin
  InitOpenGL;
  DC:= GetDC(Handle);
  rc := CreateRenderingContext(dc,[opDoubleBuffered],32,24,0,0,0,0);
 
  ActivateRenderingContext(DC, RC);
  SetupGL;
  Application.OnIdle := IdleHandler;
 
  // VSync - disable
  wglSwapIntervalEXT(0);
 
 
  glEnable(GL_TEXTURE_2D);
  glGenTextures( 1, @glTexture );
  glActiveTexture( GL_TEXTURE0 );
  glBindTexture( GL_TEXTURE_2D, glTexture );
  // mip-map
  glTexParameteri( GL_TEXTURE_2D, GL_TEXTURE_MAG_FILTER, GL_LINEAR );
  glTexParameteri( GL_TEXTURE_2D, GL_TEXTURE_MIN_FILTER, GL_LINEAR_MIPMAP_LINEAR );
  glTexParameteri( GL_TEXTURE_2D, GL_TEXTURE_WRAP_S, GL_CLAMP );
  glTexParameteri( GL_TEXTURE_2D, GL_TEXTURE_WRAP_T, GL_CLAMP );
  glTexParameteri( GL_TEXTURE_2D, GL_GENERATE_MIPMAP, GL_TRUE );
  glTexParameterf( GL_TEXTURE_2D, GL_TEXTURE_MAX_ANISOTROPY_EXT, 8.0 );
  // Выделяем память для текстуры
  glTexImage2D( GL_TEXTURE_2D, 0, GL_RGB8, textureWidth, textureHeight, 0, GL_RGBA, GL_UNSIGNED_BYTE, nil);
 
  // загрузка dll
  libvlc_dynamic_dll_init();
 
  // передача аргументов
  argc := 0;
  AddArg(libvlc_dynamic_dll_path);
  AddArg('--no-xlib');
  AddArg('-q');
  AddArg('--no-video-title-show');
  AddArg('--quiet');
  AddArg('--ignore-config');
  AddArg('--vout');
  AddArg('vmem');
  AddArg('-I');
  AddArg('dumy');
 
  p_li := libvlc_new(argc, @args);
  p_mi := NIL;
 
  p_md := libvlc_media_new_path(p_li, '1.mp4');
 
  if (p_md <> NIL) then
  begin
    p_mi := libvlc_media_player_new_from_media(p_md);
    if (p_mi <> NIL) then
    begin
      // RV32 тоже, что и RGBA
      libvlc_video_set_format(p_mi, 'RV32', textureWidth, textureHeight, textureWidth*4);
      // callback'и для обработки кадров
      libvlc_video_set_callbacks(p_mi, @libvlc_video_lock, @libvlc_video_unlock, @libvlc_video_display, nil);
    end;
    // воспроизводим видео
    libvlc_media_player_play(p_mi);
    libvlc_media_release(p_md);
  end;
end;
 
procedure TForm1.IdleHandler(Sender: TObject; var Done: Boolean);
begin
 Render;
 Done := False;
end;
 
procedure TForm1.Render;
begin
 
  glClear(GL_COLOR_BUFFER_BIT or GL_DEPTH_BUFFER_BIT);
  glViewport(0,0,ClientWidth,ClientHeight);
  glMatrixMode(GL_PROJECTION);
  glLoadIdentity;
  glOrtho(0, ClientWidth, ClientHeight, 0, 0, 1);
  glTranslatef(1,1,0);
  glMatrixMode(GL_MODELVIEW);
 
 
 
{  glBindTexture(GL_TEXTURE_2D, glTexture);
 // glTexEnvf(GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_REPLACE);
 
  glTexSubImage2D(GL_TEXTURE_2D, 0, 0, 0, textureWidth, textureHeight, GL_BGRA, GL_UNSIGNED_BYTE, @vlcBuffer);
 
  glBegin( GL_QUADS );
    glTexCoord2d(0,0); glVertex2d(0, 0);
    glTexCoord2d(0,1); glVertex2d(textureWidth, 0);
    glTexCoord2d(1,1); glVertex2d(textureWidth, textureHeight);
    glTexCoord2d(1,0); glVertex2d(0, textureHeight);
  glEnd(); }
 
  glRasterPos2i(-1, 1);
  glPixelZoom(1, -1);
  glDrawPixels(textureWidth, textureHeight, GL_BGRA, GL_UNSIGNED_BYTE, @vlcBuffer);
 
  SwapBuffers(dc);
end;
 
procedure TForm1.SetupGL;
begin
  glClearColor(0.3,0.4,0.7,0.0);
  glEnable(GL_DEPTH_TEST);
  glEnable(GL_CULL_FACE);
end;
 
procedure TForm1.FormDestroy(Sender: TObject);
begin
  DeactivateRenderingContext;
  wglDeleteContext(RC);
  ReleaseDC(Handle, DC);
end;
 
end.