Где найти мануал по парсингу XML? Как работать с XML в Delphi (в частности, TXMLDocument)?

...
 
{ IXMLNode }
 
  IXMLNode = interface
    ['{395950C0-7E5D-11D4-83DA-00C04F60B2DD}']
    { Property Accessors }
    function GetAttribute(const AttrName: DOMString): OleVariant;
    function GetAttributeNodes: IXMLNodeList;
    function GetChildNodes: IXMLNodeList;
    function GetChildValue(const IndexOrName: OleVariant): OleVariant;
    function GetCollection: IXMLNodeCollection;
    function GetDOMNode: IDOMNode;
    function GetHasChildNodes: Boolean;
    function GetIsTextElement: Boolean;
    function GetLocalName: DOMString;
    function GetNamespaceURI: DOMString;
    function GetNodeName: DOMString;
    function GetNodeType: TNodeType;
    function GetNodeValue: OleVariant;
    function GetOwnerDocument: IXMLDocument;
    function GetParentNode: IXMLNode;
    function GetPrefix: DOMString;
    function GetReadOnly: Boolean;
    function GetText: DOMString;
    function GetXML: DOMString;
    procedure SetAttribute(const AttrName: DOMString; const Value: OleVariant);
    procedure SetChildValue(const IndexOrName: OleVariant; const Value: OleVariant);
    procedure SetNodeValue(const Value: OleVariant);
    procedure SetReadOnly(const Value: Boolean);
    procedure SetText(const Value: DOMString);
    { Methods }
    function AddChild(const TagName: DOMString; Index: Integer = -1): IXMLNode; overload;
    function AddChild(const TagName, NamespaceURI: DOMString;
      GenPrefix: Boolean = False; Index: Integer = -1): IXMLNode; overload;
    function CloneNode(Deep: Boolean): IXMLNode;
    procedure DeclareNamespace(const Prefix, URI: DOMString);
    function FindNamespaceURI(const TagOrPrefix: DOMString): DOMString;
    function FindNamespaceDecl(const NamespaceURI: DOMString): IXMLNode;
    function GetAttributeNS(const AttrName, NamespaceURI: DOMString): OleVariant;
    function HasAttribute(const Name: DOMString): Boolean; overload;
    function HasAttribute(const Name, NamespaceURI: DOMString): Boolean; overload;
    function NextSibling: IXMLNode;
    procedure Normalize; 
    function PreviousSibling: IXMLNode;
    procedure Resync;
    procedure SetAttributeNS(const AttrName, NamespaceURI: DOMString; const Value: OleVariant);
    procedure TransformNode(const stylesheet: IXMLNode; var output: WideString); overload;
    procedure TransformNode(const stylesheet: IXMLNode; const output: IXMLDocument); overload;
    { Properties }
    property Attributes[const AttrName: DOMString]: OleVariant read GetAttribute write SetAttribute;
    property AttributeNodes: IXMLNodeList read GetAttributeNodes;
    property ChildNodes: IXMLNodeList read GetChildNodes;
    property ChildValues[const IndexOrName: OleVariant]: OleVariant read GetChildValue write SetChildValue; default;
    property Collection: IXMLNodeCollection read GetCollection;
    property DOMNode: IDOMNode read GetDOMNode;
    property OwnerDocument: IXMLDocument read GetOwnerDocument;
    property HasChildNodes: Boolean read GetHasChildNodes;
    property IsTextElement: Boolean read GetIsTextElement;
    property LocalName: DOMString read GetLocalName;
    property NamespaceURI: DOMString read GetNameSpaceURI;
    property NodeName: DOMstring read GetNodeName;
    property NodeType: TNodeType read GetNodeType;
    property NodeValue: OleVariant read GetNodeValue write SetNodeValue;
    property ParentNode: IXMLNode read GetParentNode;
    property Prefix: DOMString read GetPrefix;
    property ReadOnly: Boolean read GetReadOnly write SetReadOnly;
    property Text: DOMString read GetText write SetText;
    property XML: DOMString read GetXML;
  end;
 
{ IXMLNodeList }
 
  IXMLNodeList = interface
    ['{395950C1-7E5D-11D4-83DA-00C04F60B2DD}']
    { Property Accessors }
    function GetCount: Integer;
    function GetNode(const IndexOrName: OleVariant): IXMLNode;
    function GetUpdateCount: Integer;
    { Methods }
    function Add(const Node: IXMLNode): Integer;
    procedure BeginUpdate;
    procedure Clear;
    function Delete(const Index: Integer): Integer; overload;
    function Delete(const Name: DOMString): Integer; overload;
    function Delete(const Name, NamespaceURI: DOMString): Integer; overload;
    procedure EndUpdate;
    function First: IXMLNode;
    function FindNode(NodeName: DOMString): IXMLNode; overload;
    function FindNode(NodeName, NamespaceURI: DOMString): IXMLNode; overload;
    function FindNode(ChildNodeType: TGuid): IXMLNode; overload;
    function FindSibling(const Node: IXMLNode; Delta: Integer): IXMLNode;
    function Get(Index: Integer): IXMLNode;
    function IndexOf(const Node: IXMLNode): Integer; overload;
    function IndexOf(const Name: DOMString): Integer; overload;
    function IndexOf(const Name, NamespaceURI: DOMString): Integer; overload;
    procedure Insert(Index: Integer; const Node: IXMLNode);
    function Last: IXMLNode;
    function Remove(const Node: IXMLNode): Integer;
    function ReplaceNode(const OldNode, NewNode: IXMLNode): IXMLNode;
    { Properties }
    property Count: Integer read GetCount;
    property Nodes[const IndexOrName: OleVariant]: IXMLNode read GetNode; default;
    property UpdateCount: Integer read GetUpdateCount;
  end;
 
{ IXMLNodeCollection }
 
  IXMLNodeCollection = interface(IXMLNode)
    ['{395950C2-7E5D-11D4-83DA-00C04F60B2DD}']
    { Property Accessors }
    function GetCount: Integer;
    function GetNode(Index: Integer): IXMLNode;
    { Public properties }
    procedure Clear;
    procedure Delete(Index: Integer);
    function Remove(const Node: IXMLNode): Integer;
    property Count: Integer read GetCount;
    property Nodes[Index: Integer]: IXMLNode read GetNode; default;
  end;
 
{ IXMLDocument }
 
  TXMLDocOption = (doNodeAutoCreate, doNodeAutoIndent, doAttrNull,
    doAutoPrefix, doNamespaceDecl, doAutoSave);
  TXMLDocOptions = set of TXMLDocOption;
 
  TParseOption = (poResolveExternals, poValidateOnParse, poPreserveWhiteSpace,
    poAsyncLoad);
  TParseOptions = set of TParseOption;
 
  TXMLEncodingType = (xetUnknown, xetUCS_4BE, xetUCS_4LE, xetUCS_4Order2134,
    xetUCS_4Order3412, xetUTF_16BE, xetUTF_16LE, xetUTF_8, xetUCS_4Like,
    xetUTF_16BELike, xetUTF_16LELike, xetUTF_8Like, xetEBCDICLike);
 
  IXMLDocument = interface(IInterface)
    ['{395950C3-7E5D-11D4-83DA-00C04F60B2DD}']
    { Property Accessors }
    function GetActive: Boolean;
    function GetAsyncLoadState: Integer;
    function GetChildNodes: IXMLNodeList;
    function GetDocumentElement: IXMLNode;
    function GetDocumentNode: IXMLNode;
    function GetDOMDocument: IDOMDocument;
    function GetEncoding: DOMString;
    function GetFileName: DOMString;
    function GetModified: Boolean;
    function GetNodeIndentStr: DOMString;
    function GetOptions: TXMLDocOptions;
    function GetParseOptions: TParseOptions;
    function GetSchemaRef: DOMString;
    function GetStandAlone: DOMString;
    function GetVersion: DOMString;
    function GetXML: TStrings;
    procedure SetActive(const Value: Boolean);
    procedure SetDocumentElement(const Value: IXMLNode);
    procedure SetDOMDocument(const Value: IDOMDocument);
    procedure SetEncoding(const Value: DOMString);
    procedure SetFileName(const Value: DOMString);
    procedure SetNodeIndentStr(const Value: DOMString);
    procedure SetOptions(const Value: TXMLDocOptions);
    procedure SetParseOptions(const Value: TParseOptions);
    procedure SetStandAlone(const Value: DOMString);
    procedure SetVersion(const Value: DOMString);
    procedure SetXML(const Value: TStrings);
    { Methods }
    function AddChild(const TagName: DOMString): IXMLNode; overload;
    function AddChild(const TagName, NamespaceURI: DOMString): IXMLNode; overload;
    function CreateElement(const TagOrData, NamespaceURI: DOMString): IXMLNode;
    function CreateNode(const NameOrData: DOMString;
      NodeType: TNodeType = ntElement; const AddlData: DOMString = ''): IXMLNode;
    function GeneratePrefix(const Node: IXMLNode): DOMString;
    function GetDocBinding(const TagName: DOMString;
      DocNodeClass: TClass; NamespaceURI: DOMString = ''): IXMLNode;
    function IsEmptyDoc: Boolean;
    procedure LoadFromFile(const AFileName: DOMString);
    procedure LoadFromStream(const Stream: TStream; EncodingType:
      TXMLEncodingType = xetUnknown);
    procedure LoadFromXML(const XML: string); overload;
    procedure LoadFromXML(const XML: DOMString); overload;
    procedure Refresh;
    procedure RegisterDocBinding(const TagName: DOMString;
      DocNodeClass: TClass; NamespaceURI: DOMString = '');
    procedure Resync;
    procedure SaveToFile(const AFileName: DOMString);
    procedure SaveToStream(const Stream: TStream);
    procedure SaveToXML(var XML: DOMString); overload;
    procedure SaveToXML(var XML: string); overload;
    procedure SetOnAsyncLoad(const Value: TAsyncEventHandler);
    { Properties }
    property Active: Boolean read GetActive write SetActive;
    property AsyncLoadState: Integer read GetAsyncLoadState;
    property ChildNodes: IXMLNodeList read GetChildNodes;
    property DocumentElement: IXMLNode read GetDocumentElement write SetDocumentElement;
    property DOMDocument: IDOMDocument read GetDOMDocument write SetDOMDocument;
    property Encoding: DOMString read GetEncoding write SetEncoding;
    property FileName: DOMString read GetFileName write SetFileName;
    property Modified: Boolean read GetModified;
    property Node: IXMLNode read GetDocumentNode;
    property NodeIndentStr: DOMString read GetNodeIndentStr write SetNodeIndentStr;
    property Options: TXMLDocOptions read GetOptions write SetOptions;
    property ParseOptions: TParseOptions read GetParseOptions write SetParseOptions;
    property SchemaRef: DOMString read GetSchemaRef;
    property StandAlone: DOMString read GetStandAlone write SetStandAlone;
    property Version: DOMString read GetVersion write SetVersion;
    property XML: TStrings read GetXML write SetXML;
  end;
 
...

var
  Node : IXMLNode;
begin
...
  Node := XMLDocument1.DocumentElement;

var
parent, child1: IXMLNode;
 
begin
XMLDocument1.LoadFromFile('f:\filename.xml');
XMLDocument1.Active:=true;
.
.
.
end

//Загрузить XML документ из файла.
procedure TForm1.Button1Click(Sender: TObject);
var
  S : AnsiString;
  Ws : WideString;
  Fs : TFileStream;
  Od : TOpenDialog;
begin
  //Диалог выбора файла.
  Od := OpenDialog1; //OpenDialog1 уже должен быть на форме.
  if Od.InitialDir = '' then
    Od.InitialDir := ExtractFilePath( ParamStr(0) );
  if not Od.Execute then Exit;
  if not FileExists(Od.FileName) then begin
    MessageBox(0, 'Файл с заданным именем не найден. Действие отменено.'
      ,'Файл не найден!', MB_OK + MB_ICONWARNING + MB_APPLMODAL);
  end;
 
  //Загрузка содержимого из файла в XMLDocument.
  XMLDocument1.LoadFromFile(Od.FileName);
  {Настраиваем XML документ.
  -[doNodeAutoCreate] - запрет на автоматическое  создание узлов при попытке чтения.
  -[doAutoSave] - запрет на автоматическое сохранение изменений при закрытии документа.
  +[doNodeAutoIndent] - при соохранении в файл автоматическая установка отступов согласно структуре XML.
  +[doAttrNull - чтение несуществующего узла возвращает значение NULL (NULL : Variant).}
  XMLDocument1.Options := XMLDocument1.Options - [doNodeAutoCreate, doAutoSave]
    + [doNodeAutoIndent, doAttrNull];
  //Единица отступа перед тегами при сохранении в файл. У меня не сработало.
  XMLDocument1.NodeIndentStr := '  ';
  XMLDocument1.Active := True; //Включаем разбор DOM модели.
 
  //Загрузка содержимого из файла в Memo.
  Fs := TFileStream.Create(Od.FileName, fmOpenRead + fmShareDenyWrite);
  try
    if XMLDocument1.Encoding = 'UTF-8' then begin
      SetLength(S, Fs.Size);
      Fs.Read(S[1], Fs.Size);
      Memo1.Text := Utf8ToAnsi(S);
    end
    else if XMLDocument1.Encoding = 'UTF-16' then begin
      SetLength(Ws, Fs.Size div 2);
      Fs.Read(Ws[1], Fs.Size);
      Memo1.Text := WideCharLenToString(PWideChar(Ws), Length(Ws));
    end else begin
      SetLength(S, Fs.Size);
      Fs.Read(S[1], Fs.Size);
      Memo1.Text := S;
    end;
  finally
    FreeAndNil(Fs);
  end;
end;

//Запись XML кода из XMLDocument в файл.
procedure TForm1.Button2Click(Sender: TObject);
var
  Sd : TSaveDialog;
  Res : Integer;
begin
  //Диалог записи в файл.
  Sd := SaveDialog1; //SaveDialog1 уже должен быть на форме.
  if Sd.InitialDir = '' then
    Sd.InitialDir := ExtractFilePath( ParamStr(0) );
  if not Sd.Execute then Exit;
  if FileExists(Sd.FileName) then begin
    Res := MessageBox(0, 'Файл с заданным именем уже существует. Перезаписать?'
      ,'Перезаписать?', MB_YESNO + MB_ICONQUESTION + MB_APPLMODAL);
    if Res <> IDYES then
      Exit;
  end;
 
  //Загрузка содержимого из файла в XMLDocument.
  XMLDocument1.SaveToFile(Sd.FileName);
end;

//Получить сведения о корневом элементе и о его атрибутах.
procedure TForm1.Button3Click(Sender: TObject);
var
  INode : IXMLNode;
  i : Integer;
begin
  if XMLDocument1.IsEmptyDoc then begin
    ShowMessage('Документ пуст. Действие отменено.');
    Exit;
  end;
 
  INode := XMLDocument1.DocumentElement;
  Memo2.Lines.Add('------------------------------');
  Memo2.Lines.Add('Корневой элемент, тег: ' + INode.NodeName);
  Memo2.Lines.Add('Атрибуты:');
  for i := 0 to INode.AttributeNodes.Count - 1 do
    Memo2.Lines.Add(INode.AttributeNodes[i].NodeName
      + '="' + INode.AttributeNodes[i].NodeValue + '"');
  Memo2.Lines.Add('Всего атрибутов: ' + IntToStr(INode.AttributeNodes.Count));
end;

{Получить сведения о тех элементах, которые являются дочерними по отношению к
корневому элементу.}
procedure TForm1.Button4Click(Sender: TObject);
var
  INode : IXMLNode;
  i : Integer;
begin
  if XMLDocument1.IsEmptyDoc then begin
    ShowMessage('Документ пуст. Действие отменено.');
    Exit;
  end;
 
  INode := XMLDocument1.DocumentElement;
  Memo2.Lines.Add('------------------------------');
  Memo2.Lines.Add('Корневой элемент, тег: ' + INode.NodeName);
  Memo2.Lines.Add('Дочерние элементы:');
  for i := 0 to INode.ChildNodes.Count - 1 do
    Memo2.Lines.Add(INode.ChildNodes[i].NodeName);
  Memo2.Lines.Add('Всего дочерних элементов: ' + IntToStr(INode.ChildNodes.Count));
end;

type
  TArrNodes = array of IXMLNode;
 
//Рекурсивная процедура для перебора элементов с заданным тегом в поддереве с корнем aRoot.
//Корень aRoot - это любой узел XML
procedure EnumNodes(aRoot : IXMLNode; const aTag : String;
  var aArr : TArrNodes; var aCnt : Integer);
const
  Capacity = 10; //Величина приращения длины динамического массива.
var
  INode : IXMLNode;
  i : Integer;
begin
  if VarIsNull(aRoot) then Exit;
 
  for i := 0 to aRoot.ChildNodes.Count - 1 do begin
    INode := aRoot.ChildNodes[i];
    //Если обнаружен элемент с заданным тегом.
    if INode.NodeName = aTag then begin
      //Если требуется, увеличиваем размер массива.
      if Length(aArr) = aCnt then
        SetLength(aArr, aCnt + Capacity);
      //Добавляем элемент в массив.
      aArr[aCnt] := INode;
      Inc(aCnt);
    end;
    //Рекурсивный вызов.
    EnumNodes(INode, aTag, aArr, aCnt);
  end;
end;
 
//Поиск всех элементов с заданным тегом.
procedure TForm1.Button5Click(Sender: TObject);
var
  Arr : TArrNodes;
  INode : IXMLNode;
  Tag : String;
  i, j, Cnt : Integer;
begin
  if XMLDocument1.IsEmptyDoc then begin
    ShowMessage('Документ пуст. Действие отменено.');
    Exit;
  end;
  Tag := InputBox('Поиск элементов с заданным тегом.',
    'Задайте тег:', '');
  if Tag = '' then begin
    MessageBox(Handle, 'Тег не должен быть пустой строкой. Действие отменено.',
      'Отмена', MB_OK + MB_ICONINFORMATION + MB_APPLMODAL);
    Exit;
  end;
 
  {Ищем все элементы с заданным тегом, начиная с корневого элемента.
  Найденные элементы будут записаны в массив Arr.}
  EnumNodes(XMLDocument1.DocumentElement, Tag, Arr, Cnt);
  if Cnt < Length(Arr) then
    SetLength(Arr, Cnt);
  {Перебор найденных элементов и вывод сведений о них.}
  Memo2.Lines.Add('------------------------------');
  Memo2.Lines.Add('Поиск элементов с тегом: ' + Tag);
  for i := 0 to High(Arr) do begin
    INode := Arr[i];
    Memo2.Lines.Add('----------');
    Memo2.Lines.Add('Элемент, тег: ' + INode.NodeName);
    Memo2.Lines.Add('Атрибуты:');
    for j := 0 to INode.AttributeNodes.Count - 1 do
      Memo2.Lines.Add(INode.AttributeNodes[j].NodeName
        + '="' + INode.AttributeNodes[j].NodeValue + '"');
    Memo2.Lines.Add('Всего атрибутов: ' + IntToStr(INode.AttributeNodes.Count));
  end;
end;

var
  INode : IXMLNode;
...
begin
...
  {Если элемент INode имеет атрибут с именем "style", то значение этого атрибута
  заменяется на "style_value". Если элемент не имеет атрибута с таким именем, то
  для этого элемента создаётся новый атрибут с именем "style" и его значение
  устанавливается равным "style_value".}
  INode.SetAttribute('style', 'style_value');
...
  {Если элемент INode имеет атрибут с именем 'style', то этот атрибут удаляется.}
  INode.AttributeNodes.Delete('style');
...
end;

var
  INode : IXMLNode;
begin
...
  INode.NodeValue := 'value';
...
end;

var
  INode, INodeNew : IXMLNode;
begin
...
  {К элементу INode добавляем дочерний элемент с тегом 'tag_new'. Новый дочерний
  элемент располагаем под индексом 0 - т. е. он становится первым в списке
  дочерних элементов.}
  INodeNew := INode.AddChild('tag_new', 0);
  INodeNew.NodeValue := 'value';
 
  {Или так:}
  INodeNew := XMLDocument1.CreateNode('tag_new', ntElement, 'value');
  INode.ChildNodes.Insert(0, INodeNew);
 
  {К элементу INode добавляем дочерний элемент с тегом 'tag_new'. Новый дочерний
  элемент располагаем в конце списка дочерних элементов.}
  INodeNew := INode.AddChild('tag_new');
  INodeNew.NodeValue := 'value';
 
  {Или так:}
  INodeNew := XMLDocument1.CreateNode('tag_new', ntElement, 'value');
  INode.ChildNodes.Add(INodeNew);
...
end;

var
  INode : IXMLNode;
begin
...
  {Если элемент INode имеет дочерний элемент с тегом 'tag_delete', то этот дочерний
  элемент удаляется.}
  INode.ChildNodes.Delete('tag_delete');
...
end;