Неправильно работает ..класс....

@Тытьяна Brabus) · Регистрация: 18.10.2009

Author24 — интернет-сервис помощи студентам

Нужно было создать класс "домашняя библиотека" Чтобы осуществлялось: поиск книги в биб-ке, удаление, сортировка, добавление в конец.....откомпиллировала её..но ..работает неправильно....кроме процедуры Vvod ) Четвёртую неделю мучаюсь..ищу ошибки...

вот сама программа:

Delphi

program Biblioteka;
 
 {$APPTYPE CONSOLE}
 
 uses
  SysUtils,
 
  Myb in 'Myb.pas';
 
var N: TDom_Biblioteka ;
   begin
N:= TDom_Biblioteka.Create;
N.Vvod;//ввод книг в библ-ку
N. Poisk;//поиск кники в биб-ке по автору
N. Ydalenie_Knigi;//удаление книги
N. Dobavlenie;//добавление в конец
N. Sortirovka;//сортировка по году издания
readln;
 end.
 
//А вот модуль:
 
unit Myb;
 
interface
 
uses  Classes, SysUtils;
const delta = 2;
type TBibl = record
  Avtor :  string;
  Nazvanie : string;
  God :  integer; end;
 
  Bibl = array of TBibl; //массив записей
 
  TDom_Biblioteka = class
 
  Private
 
  b: Bibl;  //переменная массива Bibl
 
  Public
Constructor Create;
procedure Ydalenie_Knigi;
procedure Sortirovka;
procedure Poisk;
procedure Dobavlenie;
Procedure Vvod;
 end;
 
   Implementation
 
   Constructor TDom_Biblioteka.Create ;
begin
inherited Create;
Setlength (B, delta); end;
 
     Procedure TDom_Biblioteka.Vvod;//вводим авторов, названия,год издания
var                                    //и выводим библиотеку на экран
i:integer;
begin
writeln('           Vvod novoi knigi'); readln;
 Setlength(b,delta);
  for i:=0 to delta-1 do begin
  writeln ('Avtor:');
  readln(b[i].Avtor);//вводим автора
  writeln('Nazvanie:');
  readln(b[i].Nazvanie);//вводим название
  writeln('God:');
  readln (b[i].God);//вводим год издания
end;
  for i := 0 to delta-1 do begin  //выводим полученную библиотеку
  writeln('Avtor:' , b[i].Avtor);
  writeln('Nazvanie:' , b[i].Nazvanie);
  writeln('God:' , b[i].God);
  end;
end;
 
 procedure TDom_Biblioteka.Dobavlenie;
 var
i,k:integer;
begin
writeln('                Dobavim knigy'); readln;
setlength(b,1);
i:= high(b);
  writeln ('Avtor:');
  readln(b[i].Avtor);//вводим автора
  writeln('Nazvanie:');
  readln(b[i].Nazvanie);//вводим название
  writeln('God:');
  readln (b[i].God);//вводим год издания
for k:=0 to high(b) do begin
writeln('Avtor:' , b[k].Avtor);
writeln('Nazvanie:' , b[k].Nazvanie);
writeln('God:' , b[k].God); readln end; end;
 
 
 
 
   Procedure TDom_Biblioteka.Sortirovka;//сортируем по году издания
 
 var
i,t,m, min:integer;
b: Bibl;
begin
for i := 0 to delta-1  do
begin
min:=b[i].God;
t:=i;
for m := (i+1) to high(bibl) do
    if min > b[i].God then begin
    min:=b[i].God ;
    t:=m;
    b[t].God:=b[i].God;
    b[i].God:=min;
  writeln('Avtor:' , b[i].Avtor);
  writeln('Nazvanie:' , b[i].Nazvanie);
  writeln('God:' , b[i].God); end
else writeln('Avtora ne obnaryjeno') end; end;
 
 
   Procedure TDom_Biblioteka.Poisk; //поиск книги по автору
var
i:integer;
m:string;
b: Bibl;
begin
writeln('              Poisk');
writeln('Vvedite avtora');  readln;
readln(m);
while i<= high(b) do
  begin
  if m = b[i].Avtor then
   begin
  writeln('Avtor:' , b[i].Avtor);
  writeln('Nazvanie:' , b[i].Nazvanie);
  writeln('God:' , b[i].God);  readln
   end
  else
if m<> b[i].Avtor then 
  writeln('Avtora ne obnarujeno'); readln
 end;
end;
 
  Procedure TDom_Biblioteka.Ydalenie_knigi;//удаляем книгу из массива
var
i, last:integer;
k:string;
b: Bibl;
begin
writeln('Vvedite nazvanie knigi, kotoryu xotite ydalit');
readln(k);
while i<= high(b) do
begin
if k<> (b[i].Nazvanie) then  writeln ('Knigi ne obnarujeno')
else if k=b[i].Nazvanie then
begin
  writeln('Ydalyaemaya kniga:');
  writeln('Avtor:' , b[i].Avtor);
  writeln('Nazvanie:' , b[i].Nazvanie);
  writeln('God:' , b[i].God);  readln;
end; end; end; end.

//пожалуйста!!!!!!!!!!!!

@Mawrat · 21.10.2009, 21:48

Добавил свои комменты:

Delphi

unit Myb;
 
interface
 
uses  Classes, SysUtils;
 
const delta = 2;
 
type TBibl = record
  Avtor :  string;
  Nazvanie : string;
  God :  integer;
end;
 
Bibl = array of TBibl; //массив записей
 
TDom_Biblioteka = class
  Private
    b: Bibl;  //переменная массива Bibl
 
  Public
    Constructor Create;
    procedure Ydalenie_Knigi;
    procedure Sortirovka;
    procedure Poisk;
    procedure Dobavlenie;
    Procedure Vvod;
end;
 
Implementation
 
//Правильно.
Constructor TDom_Biblioteka.Create ;
begin
  inherited Create;
  Setlength (B, delta);
end;
 
//Синтаксически верно. Но с точки зрения проектирования логики класса - надо делать по другому.
Procedure TDom_Biblioteka.Vvod;//вводим авторов, названия,год издания
var                                    //и выводим библиотеку на экран
  i:integer;
begin
  writeln('           Vvod novoi knigi'); readln;
  Setlength(b,delta);
  for i:=0 to delta-1 do begin
    writeln ('Avtor:');
    readln(b[i].Avtor);//вводим автора
    writeln('Nazvanie:');
    readln(b[i].Nazvanie);//вводим название
    writeln('God:');
    readln (b[i].God);//вводим год издания
  end;
  for i := 0 to delta-1 do begin  //выводим полученную библиотеку
    writeln('Avtor:' , b[i].Avtor);
    writeln('Nazvanie:' , b[i].Nazvanie);
    writeln('God:' , b[i].God);
  end;
end;
 
//Здесь не верно.
procedure TDom_Biblioteka.Dobavlenie;
var
  i,k:integer;
begin
  writeln('                Dobavim knigy'); readln;
  //Ошибка. Переопределили длину массива. - Таким образом, если в массиве было
  //несколько книг, то все они пропадут, кроме самой первой!
  //Память для массива надо наращивать в этой процедуре, а не освобождать!
  setlength(b,1); //Вместо этого надо делать так: setlength(b, Length(b) + 1);
  i:= high(b);
  writeln ('Avtor:');
  readln(b[i].Avtor);//вводим автора
  writeln('Nazvanie:');
  readln(b[i].Nazvanie);//вводим название
  writeln('God:');
  readln (b[i].God);//вводим год издания
  for k:=0 to high(b) do begin
    writeln('Avtor:' , b[k].Avtor);
    writeln('Nazvanie:' , b[k].Nazvanie);
    writeln('God:' , b[k].God);
    readln;
  end;
end;
 
//Ошибка. Эту процедуру надо полностью переписать.
Procedure TDom_Biblioteka.Sortirovka;//сортируем по году издания
var
  i,t,m, min:integer;
  b: Bibl;
begin
  //Использовать здесь поле delta - это неправильно.
  //delta - это поле должно задавать ПРИРАЩЕНИЕ размера массива, а не его оконцательную длину.
  for i := 0 to delta-1  do //Надо делать так: for i := 0 to High(Self.b)  do
  begin
    min:=b[i].God;
    t:=i;
    //Ошибка. Массива bibl не существует - для него не выделена память.
    //Кроме этого массив bibl здесь и не нужен. :)
    for m := (i+1) to high(bibl) do //Надо делать так: for m := (i+1) to High(Self.b)
      //Ошибка.
      if min > b[i].God then begin //Надо делать так: if min > b[m].God then begin
        //Ошибка.
        min:=b[i].God; //Надо делать так: min:=b[m].God;
        //Неверно. Меняются местами не сами записи,
        //а только их поле год. - Дальше вообще получается каша-малаша. :)
        //Эту процедуру надо переписывать всю.
        t:=m;
        b[t].God:=b[i].God;
        b[i].God:=min;
        writeln('Avtor:' , b[i].Avtor);
        writeln('Nazvanie:' , b[i].Nazvanie);
        writeln('God:' , b[i].God);
      end
      else writeln('Avtora ne obnaryjeno')
  end;
end;
 
//Ошибка.
Procedure TDom_Biblioteka.Poisk; //поиск книги по автору
var
  i:integer;
  m:string;
  b: Bibl;
begin
  writeln('              Poisk');
  writeln('Vvedite avtora');
  readln;
  readln(m);
  //Ошибка в организации цикла.
  //Добавить это: i := 0;
  while i<= high(b) do
  begin
    if m = b[i].Avtor then
    begin
      writeln('Avtor:' , b[i].Avtor);
      writeln('Nazvanie:' , b[i].Nazvanie);
      writeln('God:' , b[i].God);  readln
    end
    else
    if m<> b[i].Avtor then
      writeln('Avtora ne obnarujeno');
    readln;
    //Здесь добавить это: Inc(i); //Иначе произойдёт зацикливание.
  end;
end;
 
//
Procedure TDom_Biblioteka.Ydalenie_knigi;//удаляем книгу из массива
var
  i, last:integer;
  k:string;
  b: Bibl;
begin
  writeln('Vvedite nazvanie knigi, kotoryu xotite ydalit');
  readln(k);
  //Здесь добавить: i := 0;
  //Далее идёт неверное алгоритмическое решение, которое не приводит к нужному
  //результату - если первая книга не та, то делается вывод, что книга не обнаружена.
  while i<= high(b) do
  begin
    if k<> (b[i].Nazvanie) then  writeln ('Knigi ne obnarujeno')
    else if k=b[i].Nazvanie then
    begin
      writeln('Ydalyaemaya kniga:');
      writeln('Avtor:' , b[i].Avtor);
      writeln('Nazvanie:' , b[i].Nazvanie);
      writeln('God:' , b[i].God);  readln;
    end;
    //Здесь добавить: Inc(i); //Иначе произойдёт зацикливание.
  end;
end;
 
end.

Потратил некоторое время на форматирование кода. Так форматировать код (как это в оригинале представлено) - нельзя. - Код должен быть чётко структурированным и легко читаемым. Нельзя из строк кода делать "лесоповал".
---
В общем, ты молодец, что попыталась сделать свою реализацию. Но класс надо переписывать.

Я помогу. Но лучше это перенести на выходные - в четверг и пятницу скорее всего не смогу уделить этому достаточно времени.

@Тытьяна Brabus) · 21.10.2009, 22:03 **[ТС]**

Ой..так быстро откликнулись..) спасибо вам огромное, что уделили время!!!!!! Согласна, что программа записана как "лесоповал"..я пока учусь) и наконец-то мне стало это по-настоящему интересно

спасибо, я буду ждать =)) буду ооочень вам признательна

@Mawrat · 25.10.2009, 02:40

Готово. Сделал на основе динамического массива. Добавил методы загрузки/выгрузки библиотеки из/в файл(а).

В приложенный архив я ещё файл ярлыка положил - если через этот файл программу запустить, то работать будет удобнее - там увеличено число строк и столбцов для консольного окна.

Delphi

program HomeLibrary;
 
{$APPTYPE CONSOLE}
 
uses
  SysUtils,
  uTHomeLib in 'uTHomeLib.pas';
 
var
  HomeLib : THomeLib;
begin
  HomeLib := THomeLib.Create;
  HomeLib.ConsoleMain;
  HomeLib.Destroy;
end.

Delphi

unit uTHomeLib;
 
interface
 
type
 
  //Книга.
  TBook = record
    //Название книги.
    Name            : String;
    //Автор.
    Author          : String;
    //Год издания.
    Year            : Integer;
 
    //Индекс в массиве.
    Index           : Integer;
  end;
 
  //Тип, задающий динамический массив для хранения книг.
  TArrBook          = array of TBook;
 
  //Книга пригодная для записи в типизированный файл.
  TBookPack = record
    //Название книги.
    Name            : String[50];
    //Автор.
    Author          : String[50];
    //Год издания.
    Year            : Integer;
 
    //Индекс в массиве.
    Index           : Integer;
  end;
 
  THomeLib = class (TObject)
  private
    //Массив для хранения сведений о книгах библиотеки. Вид массива - динамический.
    FArrBook        : TArrBook;
    //Количество книг в библиотеке. Это количество значимых элементов (книг) в массиве FArrBook.
    FCountBook      : Integer;
    //Этот параметр задаёт шаг увеличения длины массива FArrBook.
    //Т. е. когда нам нужно увеличить длину массива FArrBook, тогда мы будем увеличивать
    //её (длину массива) на величину FCapacity.
    FCapacity       : Integer;
  protected
    //Метод для сравнения двух книг. Этот метод применяется в процедурах сортировки.
    //True, если: aBook1 > aBook2
    //False, если: aBook1 <= aBook2
    function CompareBook(aBook1, aBook2 : TBook) : Boolean;
  public
    //Конструктор класса.
    constructor Create;
    //Деструктор класса.
    destructor Destroy; override;
 
    //Показывает количество книг в библиотеке.
    function GetCountBook() : Integer;
    //Добавляет новую книгу в конец списка.
    procedure AddBook(aBook : TBook);
    //Возвращает книгу по её индексу.
    function GetBook(aIndex : Integer) : TBook;
    //Удаление книги из библиотеки.
    procedure DeleteBook(aIndex : Integer);
    //Удаление всех книг из массива (из библиотеки).
    procedure Clear();
    //Сортировка книг библиотеки по автору / имени / году издания.
    procedure Sort();
 
    //--------------------------------------------------------------------------
    //Методы, которые не обращаются напрямую к private полям.
    //--------------------------------------------------------------------------
 
    //Поиск книг по названию и автору.
    function FindBook(var aArrBook : TArrBook; aName : String; aAuthor : String = '') : Boolean;
 
    //Процедура записи библиотеки в файл.
    function SaveToFile(aFileName : String) : Boolean;
    //Процедура загрузки библиотеки из файла.
    function LoadFromFile(aFileName : String) : Boolean;
 
    //Методы для взаимодействия с пользователем через консоль.
 
    procedure ConsoleAddBook();
    procedure ConsoleDeleteBook();
    procedure ConsoleFindBook();
    procedure ConsoleSort();
    procedure ConsoleShowAllBook();
    procedure ConsoleClear();
    procedure ConsoleLoadFromFile();
    procedure ConsoleSaveToFile();
    procedure ConsoleMain();
  end;
 
implementation
 
uses
  SysUtils, Windows;
 
//Функция берёт строку в ANSI кодировке (Windows)
//и возвращает её перевод в OEM кодировку (DOS) в виде отдельной строки.
function AnsiToOem(aStr : String) : String;
begin
  Result := '';
  if Length(aStr) > 0 then begin
    SetLength(Result, Length(aStr));
    CharToOem(PChar(aStr), PChar(Result));
  end;
end;
 
{ THomeLib }
 
constructor THomeLib.Create;
begin
  inherited Create;
  FCapacity := 10;
  FCountBook := 0;
end;
 
destructor THomeLib.Destroy;
begin
  //Освобождаем память, выделенную для массива FArrBook;
  Finalize(FArrBook);
  inherited Destroy;
end;
 
function THomeLib.GetCountBook: Integer;
begin
  Result := FCountBook;
end;
 
procedure THomeLib.AddBook(aBook: TBook);
begin
  //Подсчитываем общее количество книг в массиве.
  Inc(FCountBook);
  //Если требуется, увеличиваем длину массива FArrBook.
  if FCountBook > Length(FArrBook) then begin
    //Длину массива FArrBook увеличиваем на величину FCapacity элементов.
    SetLength(FArrBook, Length(FArrBook) + FCapacity);
  end;
  //Добавляем в массив новую книгу.
  FArrBook[FCountBook - 1] := aBook;
end;
 
function THomeLib.GetBook(aIndex: Integer): TBook;
begin
  Result := FArrBook[aIndex];
  Result.Index := aIndex;
end;
 
procedure THomeLib.DeleteBook(aIndex: Integer);
var
  i : Integer;
begin
  //Удаляем книгу с индексом aIndex.
  //Удаление заключается в сдвиге всех книг, расположенных правее этого индекса
  //на одну позицию влево.
  for i := aIndex to FCountBook - 1 do begin
    FArrBook[i] := FArrBook[i + 1];
  end;
  //Подсчитываем общее количество книг в массиве.
  Dec(FCountBook);
  //Если требуется, уменьшаем длину массива FArrBook.
  if FCountBook + 2 * FCapacity < Length(FArrBook) then begin
    SetLength(FArrBook, FCountBook + FCapacity);
  end;
end;
 
procedure THomeLib.Clear;
begin
  //Освобождаем память, выделенную ранее для массива FArrBook.
  Finalize(FArrBook);
  //Количество книг теперь равно нулю.
  FCountBook := 0;
end;
 
function THomeLib.CompareBook(aBook1, aBook2: TBook): Boolean;
const
  //Массив весовых коэффициентов.
  ArrWeight : array[1..3] of Integer = (2, 4, 8);
var
  //Баланс веса при сравнении двух книг.
  Weight : Integer;
begin
  Weight := 0;
 
  if aBook1.Author > aBook2.Author then begin
    Weight := Weight + ArrWeight[3];
  end else begin
    Weight := Weight - ArrWeight[3];
  end;
 
  if aBook1.Name > aBook2.Name then begin
    Weight := Weight + ArrWeight[2];
  end else begin
    Weight := Weight - ArrWeight[2];
  end;
 
  if aBook1.Name > aBook2.Name then begin
    Weight := Weight + ArrWeight[1];
  end else begin
    Weight := Weight - ArrWeight[1];
  end;
 
  if Weight > 0 then begin
    //aBook1 > aBook2.
    Result := True;
  end else begin
    //aBook1 <= aBook2.
    Result := False;
  end;
 
end;
 
//Сортировка книг по возрастанию.
//Применён метод перестановок "наименьших".
procedure THomeLib.Sort;
var
  i, j, jMin  : Integer;
  Book       : TBook;
begin
  for i := 0 to FCountBook - 1 - 1 do begin
    jMin := i;
    for j := i + 1 to FCountBook - 1 do begin
      if CompareBook(FArrBook[jMin], FArrBook[j]) then begin
        jMin := j;
      end;
    end;
    if i < jMin then begin
      Book := FArrBook[i];
      FArrBook[i] := FArrBook[jMin];
      FArrBook[jMin] := Book;
    end;
  end;
end;
 
//------------------------------------------------------------------------------
//Методы, которые не обращаются напрямую к private переменным.
//------------------------------------------------------------------------------
 
function THomeLib.FindBook(var aArrBook: TArrBook; aName,
  aAuthor : String) : Boolean;
const
  Capacity    : Integer = 10;
var
  i            : Integer;
  Compare      : Boolean;
  Count        : Integer;
begin
  Result := False;
  SetLength(aArrBook, 0);
 
  //Ищем книги, которые подходят по названию и автору.
  Count := 0;
  for i := 0 to Pred(GetCountBook) do begin
 
    //Определяем: подходит ли текущая книга под заданный шаблон.
    Compare :=
      ( aName = Copy( GetBook(i).Name, 1, Length(aName) ) )
      and ( aAuthor = Copy( GetBook(i).Author, 1, Length(aAuthor) ) )
    ;
 
    //Если текущая книга соответствует заданному шаблону,
    //то добавляем её в результирующий массив.
    if Compare then begin
      Inc(Count);
      //Увеличиваем длину результирующего массива, если требуется.
      if Length(aArrBook) < Count then begin
        SetLength(aArrBook, Length(aArrBook) + Capacity);
      end;
      //Добавляем книгу в результирующий массив.
      aArrBook[Count - 1] := GetBook(i);
    end;
 
  end;
 
  //Корректируем длину результирующего массива в соответствии с количеством
  //добавленных в него книг.
  SetLength(aArrBook, Count);
  Result := True;
end;
 
//Загрузка книг из файла.
function THomeLib.LoadFromFile(aFileName : String) : Boolean;
var
  //Файловая переменная.
  f           : file of TBookPack;
  //Книга пригодная для записи в типизированный файл.
  BookPack    : TBookPack;
  //Книга библиотеки.
  Book        : TBook;
begin
  //Связываем файловую переменную с именем файла.
  AssignFile(f, aFileName);
  try
    //Открываем файл в режиме "только чтение".
    Reset(f);
    //Очищаем библиотеку.
    Clear;
    //Последовательно читаем из файла книги и помещаем их в библиотеку.
    while not Eof(f) do begin
      //Чтение очредной книги.
      Read(f, BookPack);
      //Преобразование книги.
      Book.Name := BookPack.Name;
      Book.Author := BookPack.Author;
      Book.Year := BookPack.Year;
      Book.Index := BookPack.Index;
      //Запись книги в библиотеку.
      AddBook(Book);
    end;
    //Закрываем файл
    CloseFile(f);
    //Успешное завершение операции.
    Result := True;
  except
    //При выполнении возникли ошибки.
    Result := False;
  end;
end;
 
//Запись книг библиотеки в файл.
function THomeLib.SaveToFile(aFileName : String) : Boolean;
var
  //Файловая переменная.
  f           : file of TBookPack;
  //Книга пригодная для записи в типизированный файл.
  BookPack    : TBookPack;
  //Счётчик.
  i           : Integer;
begin
  //Связыаем файловую переменную с именем файла.
  AssignFile(f, aFileName);
  try
    //Перезаписываем файл (создаём файл). И открываем его в режиме "только запись".
    Rewrite(f);
    //Записываем в файл последовательно все книги библиотеки.
    for i := 0 to GetCountBook - 1 do begin
      //Преобразовываем книгу.
      BookPack.Name := GetBook(i).Name;
      BookPack.Author := GetBook(i).Author;
      BookPack.Year := GetBook(i).Year;
      BookPack.Index := GetBook(i).Index;
      //Записываем книгу в файл.
      Write(f, BookPack);
    end;
    //Закрываем файл.
    CloseFile(f);
    //Успешное завершение операции.
    Result := True;
  except
    //При выполнении возникли ошибки.
    Result := False;
  end;
end;
 
//Консольный диалог добавления книги.
procedure THomeLib.ConsoleAddBook;
var
  StrTmp : String;
  Book   : TBook;
begin
  repeat
    Writeln('------------------------------');
    Writeln(AnsiToOem( 'Добавление книги в библиотеку.' ));
    Write(AnsiToOem( 'Введите автора:' ));
    Readln(Book.Author);
    Write(AnsiToOem( 'Введите название книги:' ));
    Readln(Book.Name);
    Write(AnsiToOem( 'Введите год издания:' ));
    Readln(Book.Year);
    AddBook(Book);
    Write(AnsiToOem( 'Продолжить добавление книг: пробел + ENTER. Выход - только ENTER.:' ));
    Readln(StrTmp);
  until StrTmp = '';
end;
 
//Консольный диалог удаления книги.
procedure THomeLib.ConsoleDeleteBook;
var
  StrTmp : String;
begin
  repeat
    Writeln('------------------------------');
    Write(AnsiToOem( 'Удаление книги: индекс удаляемой книги + ENTER. Выход - только ENTER.:' ));
    Readln(StrTmp);
    if StrTmp <> '' then begin
      DeleteBook(StrToInt(StrTmp));
      Writeln(AnsiToOem( 'Книга удалена.' ));
    end;
  until StrTmp = '';
end;
 
//Консольный диалог поиска книг.
procedure THomeLib.ConsoleFindBook;
var
  StrTmp    : String;
  Book      : TBook;
  ArrBook   : TArrBook;
  i          : Integer;
begin
  repeat
    Writeln('------------------------------');
    Writeln(AnsiToOem( 'Поиск книг в библиотеке.' ));
    Write(AnsiToOem( 'Первые буквы в строке автора:' ));
    Readln(Book.Author);
    Write(AnsiToOem( 'Первые буквы названия книги:' ));
    Readln(Book.Name);
    if FindBook(ArrBook, Book.Name, Book.Author) then begin
      Writeln(AnsiToOem( 'Найдено книг: ' + IntToStr(Length(ArrBook)) ));
      //Показываем найденные книги по одной.
      for i := Low(ArrBook) to High(ArrBook) do begin
        Writeln('------------------------------');
        Write(AnsiToOem( 'Автор:' ));
        Writeln(ArrBook[i].Author);
        Write(AnsiToOem( 'Название книги:' ));
        Writeln(ArrBook[i].Name);
        Write(AnsiToOem( 'Год издания:' ));
        Writeln( IntToStr(ArrBook[i].Year) );
        Write(AnsiToOem( 'Индекс в библиотеке:' ));
        Writeln( IntToStr(ArrBook[i].Index) );
        if i < High(ArrBook) then begin
          Write(AnsiToOem( 'Следующая книга: пробел + ENTER. Выход - только ENTER.:' ));
          Readln(StrTmp);
          if StrTmp = '' then begin
            Break;
          end;
        end;
      end;
      Finalize(ArrBook);
    end else begin
      Writeln(AnsiToOem( 'По вашему запросу не найдено ни одной книги.' ));
    end;
    Writeln('------------------------------');
    Write(AnsiToOem( 'Повторить поиск: пробел + ENTER. Выход - только ENTER.:' ));
    Readln(StrTmp);
  until StrTmp = '';
end;
 
//Консольный диалог сортировки книг в библиотеке.
procedure THomeLib.ConsoleSort;
begin
  Sort;
  Writeln('------------------------------');
  Writeln(AnsiToOem( 'Сортировка произведена.' ));
end;
 
//Консольный диалог показа всех книг библиотеки.
procedure THomeLib.ConsoleShowAllBook;
var
  i        : Integer;
  StrTmp   : String;
begin
  if GetCountBook = 0 then begin
    Writeln('------------------------------');
    Writeln(AnsiToOem( 'В библиотеке нет ни одной книги.' ));
    Exit;
  end;
  //Показываем книги последовательно, по одной.
  for i := 0 to GetCountBook - 1 do begin
    Writeln('------------------------------');
    Write(AnsiToOem( 'Автор:' ));
    Writeln(GetBook(i).Author);
    Write(AnsiToOem( 'Название книги:' ));
    Writeln(GetBook(i).Name);
    Write(AnsiToOem( 'Год издания:' ));
    Writeln( IntToStr(GetBook(i).Year) );
    Write(AnsiToOem( 'Индекс в библиотеке:' ));
    Writeln( IntToStr(GetBook(i).Index) );
    if i < GetCountBook - 1 then begin
      Write(AnsiToOem( 'Следующая книга: пробел + ENTER. Выход - только ENTER.:' ));
      Readln(StrTmp);
      if StrTmp = '' then begin
        Break;
      end;
    end;
  end;
end;
 
//Консольный диалог удаления всех книг из библиотеки.
procedure THomeLib.ConsoleClear;
begin
  Clear;
  Writeln('------------------------------');
  Writeln(AnsiToOem( 'Из библиотеки удалены все книги.' ));
end;
 
//Консольный диалог загрузки библиотеки из файла.
procedure THomeLib.ConsoleLoadFromFile;
var
  //Имя файла.
  FileName : String;
begin
  Writeln('------------------------------');
  Writeln(AnsiToOem( 'Загрузка библиотеки из файла: имя файла + ENTER. Выход - только ENTER.:' ));
  Readln(FileName);
  if not FileExists(FileName) then begin
    Writeln(AnsiToOem( 'Ошибка. Файла с таким именем не существует. Загрузка отменена.' ));
  end else begin
    if LoadFromFile(FileName) then begin
      Writeln(AnsiToOem( 'Загрузка произведена. Загружено книг: ' + IntToStr(GetCountBook) ));
    end else begin
      Writeln(AnsiToOem( 'Ошибка. Не удалось выполнить загрузку.' ));
    end;
  end;
end;
 
//Консольный диалог записи библиотеки в файл.
procedure THomeLib.ConsoleSaveToFile;
var
  //Имя файла.
  FileName : String;
begin
  Writeln('------------------------------');
  Writeln(AnsiToOem( 'Запись библиотеки в файл: имя файла + ENTER. Выход - только ENTER.:' ));
  Readln(FileName);
  if SaveToFile(FileName) then begin
    Writeln(AnsiToOem( 'Запись произведена. Записано книг: ' + IntToStr(GetCountBook) ));
  end else begin
    Writeln(AnsiToOem( 'Ошибка. Не удалось выполнить запись в файл.' ));
  end;
end;
 
//Главный консольный диалог. Управляет работой с библиотекой.
procedure THomeLib.ConsoleMain;
var
  Num : Integer;
begin
  repeat
    Writeln('------------------------------');
    Write(AnsiToOem( 'Всего книг в библиотеке: ' ));
    Writeln(IntToStr(GetCountBook));
    Writeln(AnsiToOem( 'Главное меню. Введите номер действия и нажмите ENTER:' ));
    Writeln(AnsiToOem( '1. Добавить книгу.' ));
    Writeln(AnsiToOem( '2. Удалить книгу.' ));
    Writeln(AnsiToOem( '3. Поиск книг.' ));
    Writeln(AnsiToOem( '4. Сортировка.' ));
    Writeln(AnsiToOem( '5. Показать все книги.' ));
    Writeln(AnsiToOem( '6. Удалить все книги.' ));
    Writeln(AnsiToOem( '7. Загрузить библиотеку из файла.' ));
    Writeln(AnsiToOem( '8. Записать библиотеку в файл.' ));
    Writeln(AnsiToOem( '9. Выход.' ));
    Readln(Num);
    case Num of
      1 : ConsoleAddBook;
      2 : ConsoleDeleteBook;
      3 : ConsoleFindBook;
      4 : ConsoleSort;
      5 : ConsoleShowAllBook;
      6 : ConsoleClear;
      7 : ConsoleLoadFromFile;
      8 : ConsoleSaveToFile;
    end;
  until Num = 9;
end;
 
end.

По ходу изучения кода, задавай вопросы - отвечу.

@Тытьяна Brabus) · 25.10.2009, 15:40 **[ТС]**

ААА!!!)))) Спасибо спасибо спасибо!!)))))) Уже запустила - ооочень всё удобно и здорово!!!))))) Сейчас потихоньку начну разбирать...может что непонятно будет...СПАСИБО!!)))

@Тытьяна Brabus) 0 / 0 / 0 Регистрация: 18.10.2009 Сообщений: 5
	21.10.2009, 22:03 [ТС]	3
	Ой..так быстро откликнулись..) спасибо вам огромное, что уделили время!!!!!! Согласна, что программа записана как "лесоповал"..я пока учусь) и наконец-то мне стало это по-настоящему интересно спасибо, я буду ждать =)) буду ооочень вам признательна 0

@Тытьяна Brabus) 0 / 0 / 0 Регистрация: 18.10.2009 Сообщений: 5
	25.10.2009, 15:40 [ТС]	5
	ААА!!!)))) Спасибо спасибо спасибо!!)))))) Уже запустила - ооочень всё удобно и здорово!!!))))) Сейчас потихоньку начну разбирать...может что непонятно будет...СПАСИБО!!))) 0