Отображение html-страницы в WebBrowser из текстовой переменной

@spydark91 · Регистрация: 03.03.2011

Студворк — интернет-сервис помощи студентам

как открыть браузером страницу,созданную прямо во время выполнения программы
т.е.

Delphi
1
2
3
4
var s:string;
begin
s:='<html><H1>text</H1></html>';
webbrowser.navigate(s);

что то типо такого

@Mawrat · 31.12.2011, 18:37

Delphi
1
2
3
4
5
6
7
procedure TForm1.Button1Click(Sender: TObject);
begin
  //Создаём документ с пустым содержанием.
  WebBrowser1.Navigate('about:blank');
  //Загружаем в документ нужный HTML код.
  WebBrowser1.OleObject.Document.Write('<html><H1>text</H1></html>');
end;

@spydark91 · 03.01.2012, 19:05 **[ТС]**

Delphi
1
2
3
4
5
6
7
var
s:string;
begin
s:='<html><h1>text1</h2></html>';
 WebBrowser1.Navigate('about:blank');
  WebBrowser1.OleObject.Document.Write(s);
s:='<html><h1>text1</h2><b>text2</b></html>';

как обновить содержание веббраузера? т.е. подгрузить <b>text2</b>?
не делая так

Delphi
1
2
3
4
5
6
7
8
s:='<html><h1>text1</h2></html>';
 WebBrowser1.Navigate('about:blank');
  WebBrowser1.OleObject.Document.Write(s);
s:='<html><h1>text1</h2><b>text2</b></html>';
s:='<html><h1>text1</h2></html>';
 WebBrowser1.Navigate('about:blank');
  WebBrowser1.OleObject.Document.Write(s);
s:='<html><h1>text1</h2><b>text2</b></html>';

Добавлено через 24 минуты
все,догадался сам

@pHOMM · 03.01.2012, 20:14

Не по теме:

Хороший тон предполагает запостить решение после нахождения, вдруг кому понадобится

@spydark91 · 03.01.2012, 20:37 **[ТС]**

вспомня что я читал о js понял,что write не переписывает,а вписывает в документ что-то,т.е. добавить это WebBrowser1.OleObject.Document.Write(s); без вызова about:blank

@Mawrat · 04.01.2012, 05:43

Более универсально - действовать через DOM (объектная модель документа).
Например, у нас есть начальная версия HTML кода:

XML
1
2
3
4
5
6
7
<html>
<body>
  <div id="div1">
    <h1>text1</h1>
  </div>
</body>
</html>

Создаём документ с этим кодом:

Delphi
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
//Создание документа и загрузка начальной версии HTML кода.
procedure TForm1.Button1Click(Sender: TObject);
var
  Doc : Variant;
begin
  Doc := WebBrowser1.OleObject.document;
  if TVarData(Doc).VDispatch = nil then begin
    //Создаём новый документ с пустым содержанием.
    WebBrowser1.Navigate('about:blank');
    Doc := WebBrowser1.OleObject.document;
  end;
  //Загружаем в документ нужный HTML код.
  //Почему-то если вместо <div> использовать тег <p>, то работает неверно.
  //Так происходит здесь и в JavaScript при проверке на [url]www.w3schools.com[/url].
  Doc.open('text/html', 'replace');
  Doc.write(
    '<html><body>'
    + '<div id="div1">'
    + '<h1>text1</h1>'
    + '</div>'
    + '</body></html>'
  );
  Doc.close;
end;

Теперь, нам надо в код добавить часть:

XML
1
<b>text2</b>

Чтобы получилось так:

XML
1
2
3
4
5
6
7
<html>
<body>
  <div id="div1">
    <h1>text1</h1><b>text2</b>
  </div>
</body>
</html>

Это можно сделать, например так. Но здесь код не оптимален по скорости выполнения:

Delphi
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
//Добавление элемента НЕ оптимальным способом.
procedure TForm1.Button2Click(Sender: TObject);
var
  Doc, Elem : Variant;
begin
  //Ссылка на интерфейс документа.
  Doc := WebBrowser1.OleObject.document;
  //Находим элемент с ID="div1".
  Elem := Unassigned;
  Elem := Doc.getElementById('div1');
  if TVarData(Elem).VDispatch = nil then begin
    ShowMessage('Не найден элемент с ID="div1". Действие отменено.');
    Exit;
  end;
  //Добавляем к содержимому элемента дополнительный код.
  Elem.innerHTML := Elem.innerHTML + '<b>text2</b>';
end;

В этом коде ресурсоёмкой является строка:

Delphi
1
2
  //Добавляем к содержимому элемента дополнительный код.
  Elem.innerHTML := Elem.innerHTML + '<b>text2</b>';

Здесь, для того, чтобы добавить новую часть к коду элемента, производится чтение всего текста элемента, потом, добавляется новая часть и весь код элемента перезаписывается. Если элемент содержит большой код, то такие действия замедлят работу.
Поэтому, наиболее эффективным будет приём с добавлением дочернего элемента:

Delphi
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
//Добавление элемента оптимальным способом.
procedure TForm1.Button3Click(Sender: TObject);
var
  Doc, Elem1, Elem2 : Variant;
begin
  //Ссылка на интерфейс документа.
  Doc := WebBrowser1.OleObject.document;
  //Находим элемент с ID="div1".
  Elem1 := Unassigned;
  Elem1 := Doc.getElementById('div1');
  if TVarData(Elem1).VDispatch = nil then begin
    ShowMessage('Не найден элемент с ID="div1". Действие отменено.');
    Exit;
  end;
  //Создаём элемент, представленный тегами: <b></b>.
  Elem2 := Doc.createElement('b');
  //Задаём код элемента: "text2".
  Elem2.innerHTML := 'text2';
  //Добавляем элемент Elem2 в коллекцию дочерних элементов для Elem1.
  Elem1.appendChild(Elem2);
end;

Если надо добавить простой текст, то это можно сделать так:

Delphi
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
//Добавление текста оптимальным способом.
procedure TForm1.Button4Click(Sender: TObject);
var
  Doc, Elem, NodeTxt : Variant;
begin
  //Ссылка на интерфейс документа.
  Doc := WebBrowser1.OleObject.document;
  //Находим элемент с ID="div1".
  Elem := Unassigned;
  Elem := Doc.getElementById('div1');
  if TVarData(Elem).VDispatch = nil then begin
    ShowMessage('Не найден элемент с ID="div1". Действие отменено.');
    Exit;
  end;
  //Создаём текстовый узел с текстом: "_Это добавленный текст."
  NodeTxt := Doc.createTextNode('_Это добавленный текст.');
  //Добавляем в элемент текстовый узел в качестве дочернего узла.
  Elem.appendChild(NodeTxt);
end;

Для проверки, можно положить на форму 4 кнопки, оформить их обработчики события OnClick так, как показано выше и пощёлкать их.

Новые блоги и статьи Все статьи Все блоги /
PhpStorm 2025.3: WSL Terminal всегда стартует в ~ and_y87 14.12.2025 PhpStorm 2025. 3: WSL Terminal всегда стартует в ~ (home), игнорируя директорию проекта Симптом: После обновления до PhpStorm 2025. 3 встроенный терминал WSL открывается в домашней директории. . .	Access VikBal 11.12.2025 Помогите пожалуйста !! Как объединить 2 одинаковые БД Access с разными данными.	Новый ноутбук volvo 07.12.2025 Всем привет. По скидке в "черную пятницу" взял себе новый ноутбук Lenovo ThinkBook 16 G7 на Амазоне: Ryzen 5 7533HS 64 Gb DDR5 1Tb NVMe 16" Full HD Display Win11 Pro	Музыка, написанная Искусственным Интеллектом volvo 04.12.2025 Всем привет. Некоторое время назад меня заинтересовало, что уже умеет ИИ в плане написания музыки для песен, и, собственно, исполнения этих самых песен. Стихов у нас много, уже вышли 4 книги, еще 3. . .	От async/await к виртуальным потокам в Python IndentationError 23.11.2025 Армин Ронахер поставил под сомнение async/ await. Создатель Flask заявляет: цветные функции - провал, виртуальные потоки - решение. Не threading-динозавры, а новое поколение лёгких потоков. Откат?. . .
Поиск "дружественных имён" СОМ портов Argus19 22.11.2025 Поиск "дружественных имён" СОМ портов На странице: https:/ / norseev. ru/ 2018/ 01/ 04/ comportlist_windows/ нашёл схожую тему. Там приведён код на С++, который показывает только имена СОМ портов, типа,. . .	Сколько Государство потратило денег на меня, обеспечивая инсулином. Programma_Boinc 20.11.2025 Сколько Государство потратило денег на меня, обеспечивая инсулином. Вот решила сделать интересный приблизительный подсчет, сколько государство потратило на меня денег на покупку инсулинов. . . .	Ломающие изменения в C#.NStar Alpha Etyuhibosecyu 20.11.2025 Уже можно не только тестировать, но и пользоваться C#. NStar - писать оконные приложения, содержащие надписи, кнопки, текстовые поля и даже изображения, например, моя игра "Три в ряд" написана на этом. . .	Мысли в слух kumehtar 18.11.2025 Кстати, совсем недавно имел разговор на тему медитаций с людьми. И обнаружил, что они вообще не понимают что такое медитация и зачем она нужна. Самые базовые вещи. Для них это - когда просто люди. . .	Создание Single Page Application на фреймах krapotkin 16.11.2025 Статья исключительно для начинающих. Подходы оригинальностью не блещут. В век Веб все очень привыкли к дизайну Single-Page-Application . Быстренько разберем подход "на фреймах". Мы делаем одну. . .

@pHOMM
	03.01.2012, 20:14
	Не по теме: Хороший тон предполагает запостить решение после нахождения, вдруг кому понадобится 1

@spydark91 86 / 86 / 13 Регистрация: 03.03.2011 Сообщений: 1,873
	03.01.2012, 20:37 [ТС]
	вспомня что я читал о js понял,что write не переписывает,а вписывает в документ что-то,т.е. добавить это WebBrowser1.OleObject.Document.Write(s); без вызова about:blank 1

Отображение html-страницы в WebBrowser из текстовой переменной

Решение