Работа с отфильтрованными строками в Excel

procedure TForm1.Button1Click(Sender: TObject);
var
m: array[1..100] of string;
i,j,colcount,rowcount: integer;
s: string;
begin
Try
Ap:= CreateOleObject('Excel.Application');
Ap.Workbooks.Open(OpenDialog1.FileName);
Ap.Sheets[1].Cells.Range['B1:B500'].AutoFilter(2,RGB(255,255,0),8,EmptyParam,True);
//Ap.Sheets[1].Cells.SpecialCells(xlCellTypeLastCell).Activate;
rowcount:=Ap.Sheets[1].UsedRange.Rows.Count;
//XL.Sheets[1].Cells.Range[Range].AutoFilter(8,RGB(255,255,0),8,EmptyParam,True);
Ap.Visible:=true;
      colcount:=Ap.Sheets[1].AutoFilter.Range.Columns[2].SpecialCells(xlVisible).Count;
       for i:=3 to colcount do
        begin
         [COLOR="Red"] s:=Ap.Sheets[1].Cells.Range['B2:B100','B'].End[xlUp].SpecialCells(xlCellTypeVisible).value
          //s:=Ap.Sheets[1].Cells.Range['B2:'+'B'+inttostr(i)].End[xlUp].SpecialCells(xlCellTypeVisible).value
          //m[i-3]:=VarToStr(Ap.Sheets[1].Cells.Range['B2:'+'B'+inttostr(i)].End[xlUp].SpecialCells(xlCellTypeVisible).value)
        end; [/COLOR]
//    ShowMessage(Ap.Sheets[1].AutoFilter.Range.Columns[2].SpecialCells(xlVisible).Row[1].value);
  Except
    ShowMessage('Что-то пошло не так');
    Ap.Application.Quit;
    Ap.Unassigned;
  end;
end;

program jmTstExcel;
 
uses
  Windows, ActiveX, OleServer, OleCtrls, ADOInt, Variants, Classes, SysUtils, Dialogs,
  Excel_TLB, Office_TLB;
 
var
  LCID :Cardinal;
  od :TOpenDialog;
  ExcelBookName :string;
 
  oExcel :TExcelApplication;
  oWBook :_Workbook;
  oWSheet :_Worksheet;
{$warn symbol_platform off}
  oRng :ExcelRange; {$warn symbol_platform on}
  varArray :OleVariant;
  n, m :Integer;
 
begin
  od := TOpenDialog.Create(nil);
  with od do
    try
      InitialDir := ExtractFilePath(ParamStr(0));
      FileName := '*';
      if not Execute then
        Exit;
      { end if }
 
      ExcelBookName := FileName;
    finally Free;
    end; { end try }
  { end with }
 
  LCID := GetSystemDefaultLCID;
  if not Succeeded(CoInitializeEx(nil, COINIT_MULTITHREADED)) then
    Writeln('CoInitializeEx - error!')
  else begin
    oExcel := TExcelApplication.Create(nil);
    try
      oExcel.ConnectKind := ckNewInstance;
      oExcel.Connect;
      oExcel.AutoQuit := False;
      oExcel.Visible[LCID] := True;
      oExcel.DisplayAlerts[LCID] := False;
 
      oExcel.Workbooks.Open(  //function Open(
        ExcelBookName,        //  const Filename: WideString;
        EmptyParam,           //  UpdateLinks: OleVariant;
        EmptyParam,           //  ReadOnly: OleVariant;
        EmptyParam,           //  Format: OleVariant;
        EmptyParam,           //  Password: OleVariant;
        EmptyParam,           //  WriteResPassword: OleVariant;
        EmptyParam,           //  IgnoreReadOnlyRecommended: OleVariant;
        EmptyParam,           //  Origin: OleVariant;
        EmptyParam,           //  Delimiter: OleVariant;
        EmptyParam,           //  Editable: OleVariant;
        EmptyParam,           //  Notify: OleVariant;
        EmptyParam,           //  Converter: OleVariant;
        EmptyParam,           //  AddToMru: OleVariant;
        EmptyParam,           //  Local: OleVariant;
        EmptyParam,           //  CorruptLoad: OleVariant;
        LCID                  //  lcid: Integer): ExcelWorkbook; safecall;
      );
 
      oWBook := oExcel.ActiveWorkbook as _Workbook;
      // работаем с первым листом книги
      oWSheet := oWBook.Worksheets.Item[1] as _Worksheet;
 
      // выделим диапазон с данными из второго столбца
      oRng := oWSheet.Range[
          oWSheet.Cells.Item[1, 2],     // строка: 1, колонка: 2, т.е. начальная ячейка диапазона в терминах Excel: [B2]
          oWSheet.Range[                // этот диапазон состоит из одной ячейки (B2)
              oWSheet.Cells.Item[1, 2],
              oWSheet.Cells.Item[1, 2]
          ].End_[xlDown]                // и затем вниз по этой колонке до конца данных
      ];
 
      // отберем в этом диапазоне все ячейки закрашенные красным цветом
      oRng.AutoFilter(      //function AutoFilter(
        1,                  //  Field: OleVariant;
        rgb(255, 0, 0),     //  Criteria1: OleVariant;
        xlFilterCellColor,  //  Operator: XlAutoFilterOperator;
        EmptyParam,         //  Criteria2: OleVariant;
        EmptyParam          //  VisibleDropDown: OleVariant): OleVariant; dispid 793;
      );
      // добавим один лист в книгу в конец списка листов
      oWBook.Sheets.Add(                          //function Add(
        EmptyParam,                               //  Before: OleVariant;
        oWBook.Sheets.Item[oWBook.Sheets.Count],  //  After: OleVariant;
        1,                                        //  Count: OleVariant;
        xlWorksheet,                              //  Type_: OleVariant;
        LCID                                      //  lcid: Integer): IDispatch; safecall;
      );
      // переименуем добавленный лист, просто для прикола
      (oWBook.Sheets.Item[oWBook.Sheets.Count] as _Worksheet).Name := 'Добавленный';
 
      // скопируем отфильтрованные ячейки из нашего диапазона на добавленный лист, начиная с верхней левой ячейки: ... Cells.Item[1, 1]
      oRng.Copy(
        (oWBook.Sheets.Item[oWBook.Sheets.Count] as _Worksheet).Cells.Item[1, 1]
      );
 
      // исключаем из копии ячейки заголовка (заголовок из одной строки)
      oRng := oExcel.Intersect(
          (oWBook.Sheets.Item[oWBook.Sheets.Count] as _Worksheet).UsedRange[LCID],          // 1 - одна строка заголовка
          (oWBook.Sheets.Item[oWBook.Sheets.Count] as _Worksheet).UsedRange[LCID].Cells.Offset[1, 0]
      );
      varArray := oRng.Value[xlRangeValueDefault];
 
      // можно сразу получить вариантный массив не прибегая к промежуточному range, но громоздко
      //varArray := oExcel.Intersect(
      //    (oWBook.Sheets.Item[oWBook.Sheets.Count] as _Worksheet).UsedRange[LCID],
      //    (oWBook.Sheets.Item[oWBook.Sheets.Count] as _Worksheet).UsedRange[LCID].Cells.Offset[1, 0]
      //).Value[xlRangeValueDefault];
 
      // печать содержимого вариантного массива
      if VarIsArray(varArray) then begin
        for m := 1 to VarArrayHighBound(varArray, 1) do
          for n := 1 to VarArrayHighBound(varArray, 2) do
            case VarType(varArray[m, n]) of
              varOleStr:  Writeln('olestr  :', varArray[m, n]);
              varDouble:  Writeln('double  :', FloatToStr(varArray[m, n]));
              varDate:    Writeln('date    :', FormatDateTime('dd.mm.yyyy', varArray[m, n]));
              varInteger: Writeln('integer :', IntToStr(varArray[m, n]));
            else
              Writeln('<?>'); // хрен пойми что
            end; { end case }
          { end for }
        { end for }
      end; { end if }
 
    {$warn symbol_platform off}
      if DebugHook = 1 then begin
        Writeln('Do not close "Excel", press <Enter> here to continue....');
        Readln; // для организации паузы, чтобы можно было посмотреть на Excel-книгу
      end; { end if }
    {$warn symbol_platform on}
 
      // добавленный лист не удаляем, т.к. книгу не сохраняем
      oWBook.Saved[LCID] := True; { установим (True)!, якобы книга уже сохранена и закроем ее }
      oWBook.Close(               //procedure Close(
          False,                  //  SaveChanges: OleVariant;
          EmptyParam,             //  Filename: OleVariant;        { для якобы УЖЕ сохраненной книге имя не нужно }
          False,                  //  RouteWorkbook: OleVariant;
          LCID                    //  lcid: Integer); safecall;
      );
 
    finally
      // подчищаем за собой
      oWSheet._Release;  { Sheet }
      oWBook._Release;   { Books }
      oExcel.UserControl := True;
      oExcel.Quit;
      oExcel.Disconnect;
      CoUninitialize;
    end; { end try }
  end; { end if }
end.

Try
//  ADOCOnnection1.ConnectionString:='Provider =Microsoft.ACE.OLEDB.12.0; Data Source =' + FN1 + '; Extended Properties ="Excel 8.0 Xml;HDR=YES";';
  ADOConnection1.ConnectionString:='Driver={Microsoft Excel Driver (*.xls, *.xlsx, *.xlsm, *.xlsb)};DBQ=' + FN1;
  ShowMessage(Adoconnection1.ConnectionString);
  ADOCOnnection1.Connected:=true;
  ADODataset1.EnableBCD:=true;
  DataSource1.Enabled:=true;
  ADOQuery1.SQL.Text:='SELECT * FROM "2"';
  ADOQuery1.Open;
  DBGrid1.Enabled:=true;
 
Except
   On Exception do;
 
End;