Ввод значения переменной в команду консоли CMD

WinExec('cmd /c "start fastboot.exe flash  recovery' +edt1.text+ ', 0);

WinExec('cmd /c "start fastboot.exe flash  recovery ' +quotedstr(edt1.text)+ ', 0);

WinExec(PChar('cmd /c "start fastboot.exe flash  recovery ' +quotedstr(edt1.text)), 0);

unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;
 
type
  TForm1 = class(TForm)
    Button1: TButton;
    Memo1: TMemo;
    Edit1: TEdit;
    Label1: TLabel;
    OpenDialog1: TOpenDialog;
    procedure Button1Click(Sender: TObject);
  private
{ Private declarations }
  public
{ Public declarations }
  end;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.dfm}
 
function GetDosOutput(const CommandLine, Parametrs: string): string;
var
  SA: TSecurityAttributes;
  SI: TStartupInfo;
  PI: TProcessInformation;
  StdOutPipeRead, StdOutPipeWrite: THandle;
  WasOK: Boolean;
  Buffer: array[0..255] of Char;
  BytesRead: Cardinal;
  WorkDir, Line: string;
begin
  Application.ProcessMessages;
  with SA do
  begin
    nLength := SizeOf(SA);
    bInheritHandle := True;
    lpSecurityDescriptor := nil;
  end;
  // создаём пайп для перенаправления стандартного вывода
  CreatePipe(StdOutPipeRead,  // дескриптор чтения
    StdOutPipeWrite, // дескриптор записи
    @SA,              // атрибуты безопасности
    0                // количество байт принятых для пайпа - 0 по умолчанию
  );
  try
    // Создаём дочерний процесс, используя StdOutPipeWrite в качестве стандартного вывода,
    // а так же проверяем, чтобы он не показывался на экране.
    with SI do
    begin
      FillChar(SI, SizeOf(SI), 0);
      cb := SizeOf(SI);
      dwFlags := STARTF_USESHOWWINDOW or STARTF_USESTDHANDLES;
      wShowWindow := SW_HIDE;
      hStdInput := GetStdHandle(STD_INPUT_HANDLE); // стандартный ввод не перенаправляем
      hStdOutput := StdOutPipeWrite;
      hStdError := StdOutPipeWrite;
    end;
    // Запускаем компилятор из командной строки
    WorkDir := ExtractFilePath(CommandLine);
    WasOK := CreateProcess(nil, PChar(CommandLine + ' ' + Parametrs), nil, nil, True, 0, nil, PChar(WorkDir), SI, PI);
    // Теперь, когда дескриптор получен, для безопасности закрываем запись.
    // Нам не нужно, чтобы произошло случайное чтение или запись.
    CloseHandle(StdOutPipeWrite);
    // если процесс может быть создан, то дескриптор, это его вывод
    if not WasOK then //raise Exception.Create('Could not execute command line!')
 
    else
    try
        // получаем весь вывод до тех пор, пока DOS-приложение не будет завершено
      Line := '';
      repeat
        Application.ProcessMessages;
          // читаем блок символов (могут содержать возвраты каретки и переводы строки)
        WasOK := ReadFile(StdOutPipeRead, Buffer, 255, BytesRead, nil);
          // есть ли что-нибудь ещё для чтения?
        if BytesRead > 0 then
        begin
              // завершаем буфер PChar-ом
          Buffer[BytesRead] := #0;
              // добавляем буфер в общий вывод
          Line := Line + Buffer;
        end;
      until not WasOK or (BytesRead = 0);
        // ждём, пока завершится консольное приложение
      WaitForSingleObject(PI.hProcess, INFINITE);
    finally
        // Закрываем все оставшиеся дескрипторы
      CloseHandle(PI.hThread);
      CloseHandle(PI.hProcess);
    end;
  finally
    result := utf8toansi(Line); // перекодируем UTF-8 в ANSI
    CloseHandle(StdOutPipeRead);
  end;
end;
 
procedure TForm1.Button1Click(Sender: TObject);
var
  FBPar: string;
begin
  if OpenDialog1.Execute then
    // Выводим полный путь к файлу
    Edit1.Text := OpenDialog1.FileName;
  // Формируем команду для FastBoot с параметрами
  FBPar := ' flash  recovery ' + Edit1.Text;
  // Выполняем всё и выводим результат в Memo
  Memo1.Text := GetDosOutput(extractfilepath(paramstr(0)) + 'fastboot.exe ', FBPar);
end;
 
end.