Сделать так, чтобы в фиксированные поля грида можно было записывать значения

unit Unit3;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, Grids;
 
type
  TForm3 = class(TForm)
    StringGrid1: TStringGrid;
    Edit1: TEdit;
    procedure FormCreate(Sender: TObject);
    procedure StringGrid1FixedCellClick(Sender: TObject; ACol, ARow: Integer);
    procedure Edit1Exit(Sender: TObject);
    procedure Edit1KeyDown(Sender: TObject; var Key: Word; Shift: TShiftState);
  end;
 
var
  Form3: TForm3;
  edCol,edRow: integer;
 
implementation
 
{$R *.dfm}
 
procedure TForm3.Edit1Exit(Sender: TObject);
begin
  // потеря фокуса Эдитом
  Edit1.Hide;
  StringGrid1.Cells[edCol,edRow]:= Edit1.Text;
end;
 
procedure TForm3.Edit1KeyDown(Sender: TObject; var Key: Word;
  Shift: TShiftState);
begin
  // при нажатии Энтер или Искейп переводим фокус на грид
  // тем самым вызывая обработчик Edit1Exit
  if Key in [VK_RETURN,VK_ESCAPE] then StringGrid1.SetFocus;
end;
 
procedure TForm3.FormCreate(Sender: TObject);
begin
  // Привязываем Эдит к Гриду
  Edit1.Parent:= StringGrid1;
end;
 
procedure TForm3.StringGrid1FixedCellClick(Sender: TObject; ACol,
  ARow: Integer);
var
  R: TRect;
begin
  // Щелчок на фиксированной ячейке
  edCol:= ACol;  // запоминаем столбец
  edRow:= ARow;  // запоминаем строку
  Edit1.Show;
  R:= StringGrid1.CellRect(ACol,ARow);
  Edit1.SetBounds(R.Left,R.Top,StringGrid1.ColWidths[ACol],StringGrid1.RowHeights[ARow]);
  Edit1.Text:= StringGrid1.Cells[ACol,ARow];
  Edit1.SetFocus;
end;
 
end.

var
  Form3: TForm3;
  edCol,edRow: integer;
  EditExitKey: Word;                      // доработка 1
 
implementation
 
{$R *.dfm}
 
procedure TForm3.Edit1Exit(Sender: TObject);
begin
  // потеря фокуса Эдитом
  Edit1.Hide;
  if EditExitKey = VK_RETURN then         // доработка 1
  StringGrid1.Cells[edCol,edRow]:= Edit1.Text;
end;
 
procedure TForm3.Edit1KeyDown(Sender: TObject; var Key: Word;
  Shift: TShiftState);
begin
  // при нажатии Энтер или Искейп переводим фокус на грид
  // тем самым вызывая обработчик Edit1Exit
  if Key in [VK_RETURN,VK_ESCAPE] then
  begin
    EditExitKey:= Key;                    // доработка 1
    StringGrid1.SetFocus;
  end;
end;
 
procedure TForm3.FormCreate(Sender: TObject);
begin
  // Привязываем Эдит к Гриду, чтобы координаты отрисовки Эдита
  // были привязаны к координатам Грида
  Edit1.Parent:= StringGrid1;
end;
 
procedure TForm3.StringGrid1FixedCellClick(Sender: TObject; ACol,
  ARow: Integer);
var
  R: TRect;
begin
  // Щелчок на фиксированной ячейке
  if (ACol = 0) and (ARow = 0) then Exit; // доработка 2
  EditExitKey:= 0;                        // доработка 1
  edCol:= ACol;  // запоминаем столбец
  edRow:= ARow;  // запоминаем строку
  Edit1.Show;
  R:= StringGrid1.CellRect(ACol,ARow);
  Edit1.SetBounds(R.Left,R.Top,StringGrid1.ColWidths[ACol],StringGrid1.RowHeights[ARow]);
  Edit1.Text:= StringGrid1.Cells[ACol,ARow];
  Edit1.SetFocus;
end;
 
end.