Раскидать файлы по папкам, соответствующим датам создания этих файлов

:: Скрипт копирования файлов рекурсивно из заданной директории в каталоги, имя которых будет = дате создания файлов
@echo off
:: В скрипт включена поддержка файлов-папок с буквами украинского алфавита
setlocal EnableDelayedExpansion
::Искомое расширение файлов
set Ext=*.jpg *.gif *.bmp *.png
::Откуда копировать
set From=l:\Bash\address
::Куда копировать
set To=l:\Bash\CopyByDate
 
:: Если целевой папки нет - создаем ее
if not exist "%To%" md "%To%"
 
:: Поддержка символов кодовой страницы 1251
chcp 1251>nul& set LanguageFlag=true
 
:: Задействуем рекурсивный обход папок/файлов двумя циклами, чтобы знать в какой папке находимся в цикле № 2,
:: не используя ключ /B. :: 1-й - dir /b /s /ad. 2-й - dir /a-d (цикл № 2 - вынес в подпрограмму)
for /F "delims=" %%F in ('dir /B /S /AD "%From%"') do call :GetFiles "%%F"
:: Проверяем файлы в самом корне каталога
call :GetFiles "%From%"
::Возвращаем исходную кодировку
chcp 866>nul& Set LanguageFlag=
:: Ожидаем действия пользователя
pause
:: Выход из пакетного файла
goto :eof
 
:GetFiles
  rem Сформируем специальную строку быстрого обхода нескольких расширений файлов
  set curFrom=%~1
  rem Формируем путь вида c:\path\*.1,c:\path\*.2, ...
  call set St="!curFrom!\%%ext: =","!curFrom!\%%"
  rem Предварительный подсчет кол-ва строк в выводе (нужен чтобы исключить последние 2)
  set CountLines=0
  rem Читаю все файлы по заданным расширениям текущей папки, фильтруя междя выводами лишние строки с путями
  for /F "skip=4" %%A in ('dir /A-D /-C /T:C !St! 2^>nul ^|find /v /i "!curFrom!"') do set /A CountLines+=1
  set /A CountLines-=1
  set CurLines=0
  echo Читаю каталог: !curFrom!
  rem Пропускаем первые 5 строк вывода dir, убираем разделитель рядов, сортируем по дате (необязательно)
  for /F "skip=4 tokens=1,3*" %%A in ('dir /A-D /-C /T:C !St! 2^>nul ^|find /v /i "!curFrom!"') do (
    :: Читаем без последних 2 строк
    set /A CurLines+=1
    if !CurLines! LSS !CountLines! (
      rem Восстанавливаем кодовую страницу 866, чтобы получать вывод консоли в читабельном виде.
      if defined LanguageFlag (chcp 866>nul& Set LanguageFlag=)
      rem Получаем конечный путь с датой текущего файла
      set ToReal=%To%\%%A
      rem Создаем конечную папку, если ее нет
      if not exist "!ToReal!" md "!ToReal!"
      rem Проверяем не занят ли полный путь. Если занят, получаем свободное имя с добавкой цифры в скобках +1
      call :GetEmptyNameMod "!ToReal!" "!curFrom!\%%C" NewName
      rem Копируем файл
      copy /Y "!curFrom!\%%C" "!ToReal!\!NewName!" >nul
    )
  )
  rem Вложенный цикл! Требуется повторное переключение кодовой страницы для входа в цикл № 2
  chcp 1251>nul& set LanguageFlag=true
)
exit /B
 
:GetEmptyNameMod %1-Folder %2-FullFileName %3-Var.Return %4-Optional.System.Num
:: Рекурсивная функция для получения сбободного имени файла по заданной директории
:: Модификация: если файл совпадает по содержимому с одним из одноименных файлов,
:: новый индекс не выдается (предотвращение дубликатов).
if "%~4"=="" (
    Set "NewFileName=%~nx2"
  ) else (
    Set "NewFileName=%~n2(%~4)%~x2"
)
if exist "%~1\%NewFileName%" (
    FC /B "%~1\%NewFileName%" "%~2" >nul && (
      Set "%~3=%NewFileName%"
      Exit /B
    ) || (
      Set Num=%~4
      Set /A Num+=1
      Call :GetEmptyNameMod "%~1" "%~2" "%~3" "!Num!"
    )
  ) else (
    Set "%~3=%NewFileName%"
    Exit /B
)
Exit /B

dir /b /s /ad "диск:\путь" |find /c /v ""

@set @x=0 /*
:: Скрипт копирования файлов рекурсивно из заданной директории в каталоги, имя которых будет = дате модификации файлов
@echo off
:: В скрипт включена поддержка файлов-папок с буквами украинского алфавита
setlocal EnableDelayedExpansion EnableExtensions
::Искомое расширение файлов
set Ext=*.jpg *.gif *.bmp *.png
::Откуда копировать
set From=l:\Bash\222
::Куда копировать
::set To=l:\Bash\CopyByDate
set /p "x=Выберите целевую папку" < nul
for /F "delims=" %%F in ('cscript //nologo /e:jscript "%~f0"') do set To=%%F
if not defined To exit /B
echo : %To%
 
:: Если целевой папки нет - создаем ее
if not exist "%To%" md "%To%"
 
:: Поддержка символов кодовой страницы 1251
chcp 1251>nul& set LanguageFlag=true
 
rem Сформируем специальную строку быстрого обхода нескольких расширений файлов - путь вида c:\path\*.1,c:\path\*.2, ...
call set St="!From!\%%ext: =","!From!\%%"
 
for /F "delims=" %%A in ('dir /B /S /A-D %St%') do (
  rem Индикация текущей копируемой папки
  if "!curFolder!" neq "%%~dpA" (echo Читаю %%~dpA& set curFolder=%%~dpA)
  rem Получаем конечный путь с датой текущего файла (выделяю с формата дата-время только дату)
  for /F %%D in ("%%~tA") do set ToReal=%%D
  rem Обход ошибки в имени файла, если в настройках стандарта системы установлен формат даты через знаки /
  set ToReal=%To%\!ToReal:/=.!
  rem Создаем конечную папку, если ее нет
  if not exist "!ToReal!" md "!ToReal!"
  rem Проверяем не занят ли полный путь. Если занят, получаем свободное имя с добавкой цифры в скобках +1
  call :GetEmptyNameMod "!ToReal!" "%%A" NewName
  rem Копируем файл
  if not errorlevel 1 copy /Y "%%A" "!ToReal!\!NewName!" >nul
)
chcp 866 >nul
:: Ожидаем действия пользователя
pause
:: Выход из пакетного файла
goto :eof
 
:GetEmptyNameMod %1-Folder %2-FullFileName %3-Var.Return %4-Optional.System.Num
:: Рекурсивная функция для получения сбободного имени файла по заданной директории
:: Модификация: если файл совпадает по содержимому с одним из одноименных файлов,
:: новый индекс не выдается (предотвращение дубликатов).
if "%~4"=="" (
    Set "NewFileName=%~nx2"
  ) else (
    Set "NewFileName=%~n2(%~4)%~x2"
)
if exist "%~1\%NewFileName%" (
    FC /B "%~1\%NewFileName%" "%~2" >nul && (
      Set "%~3=%NewFileName%"
      Exit /B 1
    ) || (
      Set Num=%~4
      Set /A Num+=1
      Call :GetEmptyNameMod "%~1" "%~2" "%~3" "!Num!"
    )
  ) else (
    Set "%~3=%NewFileName%"
    Exit /B 0
)
Exit /B 0
 
:ChooseFolder JScript */
var objShellApp = new ActiveXObject('Shell.Application');
var Folder = objShellApp.BrowseForFolder(0, 'SELECT FOLDER',1, '::{20D04FE0-3AEA-1069-A2D8-08002B30309D}');
try {
  new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1).Write(Folder.Self.Path)
};
catch (e) {};

for /F "delims=" %%F in ('chcp 1251 ^>nul ^& cscript //nologo /e:jscript "%~f0"') do set To=%%F

:: Скрипт копирования файлов рекурсивно из заданной директории в каталоги, имя которых будет = дате модификации файлов
@echo off
:: В скрипт включена поддержка файлов-папок с буквами украинского алфавита
setlocal EnableDelayedExpansion EnableExtensions
 
::Искомое расширение файлов
set Ext=*.jpg *.gif *.bmp *.png
 
::Откуда копировать
set /p "x=Выберите исходную папку" < nul
call :GetFolder From
if not defined From exit /B
echo : %From%
 
::Куда копировать
set /p "x=Выберите целевую папку" < nul
call :GetFolder To
if not defined To exit /B
echo : %To%
 
:: Если целевой папки нет - создаем ее
if not exist "%To%" md "%To%"
 
:: Поддержка символов кодовой страницы 1251
chcp 1251>nul& set LanguageFlag=true
 
rem Сформируем специальную строку быстрого обхода нескольких расширений файлов - путь вида c:\path\*.1,c:\path\*.2, ...
call set St="!From!\%%ext: =","!From!\%%"
 
for /F "delims=" %%A in ('dir /B /S /A-D %St%') do (
  rem Восстанавливаем кодовую страницу 866, чтобы получать вывод консоли в читабельном виде.
  if defined LanguageFlag (chcp 866>nul& Set LanguageFlag=)
  rem Индикация текущей копируемой папки
  if "!curFolder!" neq "%%~dpA" (echo Читаю %%~dpA& set curFolder=%%~dpA)
  rem Получаем конечный путь с датой текущего файла (выделяю с формата дата-время только дату)
  for /F %%D in ("%%~tA") do set ToReal=%%D
  rem Обход ошибки в имени файла, если в настройках стандарта системы установлен формат даты через знаки /
  set ToReal=%To%\!ToReal:/=.!
  rem Создаем конечную папку, если ее нет
  if not exist "!ToReal!" md "!ToReal!"
  rem Проверяем не занят ли полный путь. Если занят, получаем свободное имя с добавкой цифры в скобках +1
  call :GetEmptyNameMod "!ToReal!" "%%A" NewName
  rem Копируем файл
  if not errorlevel 1 copy /Y "%%A" "!ToReal!\!NewName!" >nul
)
chcp 866 >nul
:: Ожидаем действия пользователя
pause
:: Выход из пакетного файла
goto :eof
 
:GetEmptyNameMod %1-Folder %2-FullFileName %3-Var.Return %4-Optional.System.Num
:: Рекурсивная функция для получения сбободного имени файла по заданной директории
:: Модификация: если файл совпадает по содержимому с одним из одноименных файлов,
:: новый индекс не выдается (предотвращение дубликатов).
if "%~4"=="" (
    Set "NewFileName=%~nx2"
  ) else (
    Set "NewFileName=%~n2(%~4)%~x2"
)
if exist "%~1\%NewFileName%" (
    FC /B "%~1\%NewFileName%" "%~2" >nul && (
      Set "%~3=%NewFileName%"
      Exit /B 1
    ) || (
      Set Num=%~4
      Set /A Num+=1
      Call :GetEmptyNameMod "%~1" "%~2" "%~3" "!Num!"
    )
  ) else (
    Set "%~3=%NewFileName%"
    Exit /B 0
)
Exit /B 0
 
:GetFolder %1-var.Where.Save.FolderName
chcp 1251 >nul
for /f "usebackq delims=" %%i in (
    `@"%systemroot%\system32\mshta.exe" "javascript:var objShellApp = new ActiveXObject('Shell.Application');var Folder = objShellApp.BrowseForFolder(0, 'SELECT FOLDER',1, '::{20D04FE0-3AEA-1069-A2D8-08002B30309D}');try {new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1).Write(Folder.Self.Path)};catch (e){};close();" ^
    1^|more`
) do set %~1=%%i
chcp 866 >nul
Exit /B

set "ToReal=!ToReal:~8!.!ToReal:~3,2!.!ToReal:~0,2!"

:: Скрипт копирования файлов рекурсивно из заданной директории в каталоги, имя которых будет = дате модификации файлов
@echo off
:: В скрипт включена поддержка файлов-папок с буквами украинского алфавита
setlocal EnableDelayedExpansion EnableExtensions
 
::Искомое расширение файлов
set Ext=*.jpg *.gif *.bmp *.png *.mp4
 
::Откуда копировать
set /p "x=Source folder" < nul
call :GetFolder From
if not defined From exit /B
echo : %From%
 
::Куда копировать
set /p "x=Folder to write" < nul
call :GetFolder To
if not defined To exit /B
echo : %To%
 
:: Если целевой папки нет - создаем ее
if not exist "%To%" md "%To%"
 
:: Поддержка символов кодовой страницы 1251
chcp 1251>nul& set LanguageFlag=true
 
rem Сформируем специальную строку быстрого обхода нескольких расширений файлов - путь вида c:\path\*.1,c:\path\*.2, ...
call set St="!From!\%%ext: =","!From!\%%"
 
for /F "delims=" %%A in ('dir /B /S /A-D %St%') do (
  rem Восстанавливаем кодовую страницу 866, чтобы получать вывод консоли в читабельном виде.
  if defined LanguageFlag (chcp 866>nul& Set LanguageFlag=)
  rem Индикация текущей копируемой папки
  if "!curFolder!" neq "%%~dpA" (echo Читаю %%~dpA& set curFolder=%%~dpA)
  rem Получаем конечный путь с датой текущего файла (выделяю с формата дата-время только дату)
  for /F %%R in ("%%~tA") do set ToReal=%%R
  rem Обход ошибки в имени файла, если в настройках стандарта системы установлен формат даты через знаки /
  set "ToReal=!ToReal:~8!.!ToReal:~3,2!.!ToReal:~0,2!"
  set ToReal=%To%\!ToReal:/=.!
  rem Создаем конечную папку, если ее нет
  if not exist "!ToReal!" md "!ToReal!"
  rem Проверяем не занят ли полный путь. Если занят, получаем свободное имя с добавкой цифры в скобках +1
  call :GetEmptyNameMod "!ToReal!" "%%A" NewName
  rem Копируем файл
  if not errorlevel 1 copy /Y "%%A" "!ToReal!\!NewName!" >nul
)
chcp 866 >nul
:: Ожидаем действия пользователя
pause
:: Выход из пакетного файла
goto :eof
 
:GetEmptyNameMod %1-Folder %2-FullFileName %3-Var.Return %4-Optional.System.Num
:: Рекурсивная функция для получения сбободного имени файла по заданной директории
:: Модификация: если файл совпадает по содержимому с одним из одноименных файлов,
:: новый индекс не выдается (предотвращение дубликатов).
if "%~4"=="" (
    Set "NewFileName=%~nx2"
  ) else (
    Set "NewFileName=%~n2(%~4)%~x2"
)
if exist "%~1\%NewFileName%" (
    FC /B "%~1\%NewFileName%" "%~2" >nul && (
      Set "%~3=%NewFileName%"
      Exit /B 1
    ) || (
      Set Num=%~4
      Set /A Num+=1
      Call :GetEmptyNameMod "%~1" "%~2" "%~3" "!Num!"
    )
  ) else (
    Set "%~3=%NewFileName%"
    Exit /B 0
)
Exit /B 0
 
:GetFolder %1-var.Where.Save.FolderName
chcp 1251 >nul
for /f "usebackq delims=" %%i in (
    `@"%systemroot%\system32\mshta.exe" "javascript:var objShellApp = new ActiveXObject('Shell.Application');var Folder = objShellApp.BrowseForFolder(0, 'SELECT FOLDER',1, '::{20D04FE0-3AEA-1069-A2D8-08002B30309D}');try {new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1).Write(Folder.Self.Path)};catch (e){};close();" ^
    1^|more`
) do set %~1=%%i
chcp 866 >nul
Exit /B