Как получить относительный путь к файлу?

@Eva Rosalene · Регистрация: 06.01.2013

Студворк — интернет-сервис помощи студентам

Комментарий модератора

Сообщение выделено из темы: Как создать обычную проверку на наличие файла и его размер?

Сообщение от Dragokas

Будет выдавать полный путь к файлу.

Это самое печальное. Правда, если захотеть, можно использовать %%~nxA (для вывода в лог, например)
А вот как выводить ОТНОСИТЕЛЬНЫЙ путь (относительно %cd% естессна) - я не додумался пока.
Вернее есть два сложных способа:
1) Парсить полный путь, отбрасывая с начала ровно столько символов, сколько содержит %cd%
2) Писать свою рекурсивную функцию.

@sov44 · 22.04.2013, 22:58

Сообщение от FraidZZ

как выводить ОТНОСИТЕЛЬНЫЙ путь (относительно %cd% естессна)

Bash
1
2
3
4
5
6
@Echo Off
Set oldipforsite=%~dp0
For /D %%a In ("%oldipforsite:~0,-1%.txt") Do Set oldipforsite=%%~na
Echo %oldipforsite%
Pause>nul
Exit

Dragokas · 23.04.2013, 01:27

Можно обойтись простой текстовой заменой. Знак двоеточия не будет больше нигде встречаться.

c:\users\alex
c:\users\alex\desktop\file.txt
Берем заменяем во второй строке искомую первую на ничто.

Тоже самое с dir в цикле:

Bash
1
2
3
4
5
6
7
@echo off
SetLocal EnableExtensions EnableDelayedExpansion
 
cd /d c:\users\alex\desktop
 
for /f "delims=" %%a in ('dir /b /s /a') do set fn=%%a& echo !fn:%cd%=!
pause

или

Bash
1
for /r "test" %%A in (*.cmd) do set x=%%A& echo !x:%~dp0=!

(test - путь или подкаталог, начиная с текущего, в котором ищем файлы с маской *.cmd)

Добавлено через 20 минут
sov44, ну это ты узнаешь имя папки, в которой лежит батник.
Тоже решение интересное. Единственная практическая польза, которую увидел в ключе /D.

А допустим такая задача: нужно перечислить файлы, которые лежат на не более N уровней подкаталогов, начиная с текущего.

Вот как варианты:
1) можно запарсить \
2) можно перейти в каталог найденного файла. Потом спускаться cd.. пока %cd% не станет равно пути исходного каталога. (пока спускаемся считаем кол-во переходов). На сколько это тормозно? - надо еще провести пост-тесты.

Добавлено через 2 минуты
3) я задумывал обойти дерево Tree (в прямом смысле команда Tree) - да заснул, пока продумовал алгоритм

)

Добавлено через 1 час 36 минут
Использовал алгоритм:
Узнать длину переменной с полным путем к файлу,
Удалить все \, проверить снова длину.
Получить разницу = кол-во уровней.

Вот такой монстрик получился

:

Кликните здесь для просмотра всего текста

Bash
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
@echo off
SetLocal EnableExtensions EnableDelayedExpansion
::Задаем ограничение на вывод только не более N уровней подкаталогов, начиная с указанного в переменной Here
Set MaxLevel=0
::В какой папке просматриваем файлы
Set Here=l:\Bash\Pathes\Test
::Длина полного пути к сценарию
Call :var_count "%Here%" LenDef
Set "HereNoSlash=%Here:\=%"
::Длина без слешей
Call :var_count "%HereNoSlash%" LenDefNoSlash
::Сколько уровней папок к сценарию = DefSlashCount - 1
Set /A DefSlashCount=LenDef - LenDefNoSlash + 1
::А теперь перебираем файлы/папки в подкаталоге Test, начиная с текущего
for /r "%Here%" %%a in (*) do (
  set "Cur=%%a"
  rem Длина найденного пути
  Call :var_count "%%a" LenCur
  set "CurNoSlash=!Cur:\=!"
  rem Длина найденного пути без слешей
  Call :var_count "!CurNoSlash!" LenCurNoSlash
  rem Сколько уровней относительно текущего каталога
  Set /A Levels=!LenCur! - !LenCurNoSlash! - DefSlashCount 
  rem Если кол-во ровней <= установленному, выводим на экран полный путь
  if !Levels! LEQ %MaxLevel% echo %%a
)
 
pause
goto :eof
 
 
:var_count %1-in.Text %2.out.Len.of.Text
  set _var=%~1& set _count=0
  :count--
  set _var=%_var:~1%
  set /a _count+=1
  if not defined _var (set %~2=%_count%& exit /b) else (goto :count--)
Exit /B

Добавлено через 14 минут
Немножко упростил/ускорил:

Кликните здесь для просмотра всего текста

Bash
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
@echo off
SetLocal EnableExtensions EnableDelayedExpansion
::Задаем ограничение на вывод только не более N уровней подкаталогов
Set MaxLevels=0
::В какой папке просматриваем файлы
Set Here=l:\Bash\Pathes\Test
Call :Symb_count "%Here%" "\" DefSlashCount
Set /A AbsoluteMaxLevels=DefSlashCount + MaxLevels + 1
 
for /r "%Here%" %%a in (*) do (
  Call :Symb_count "%%a" "\" CurLevels
  if !CurLevels! LEQ %AbsoluteMaxLevels% echo %%a
)
 
pause
goto :eof
 
 
:Symb_count %1-in.Text %2-in.Symbol.to.Seek %3.out.Count.of.Symbols
  set "_var=%~1"& set _count=0
  :count--
  if "%_var:~0,1%"=="%~2" set /a _count+=1
  set "_var=%_var:~1%"
  if not defined _var (set %~3=%_count%& exit /b) else (goto :count--)
Exit /B

@Eva Rosalene · 23.04.2013, 13:40 **[ТС]**

Сообщение от Dragokas

Берем заменяем во второй строке искомую первую на ничто.

Dragokas, Gracia!

Новые блоги и статьи Все статьи Все блоги /
Почему дизайн решает? Neotwalker 09.01.2026 В современном мире, где конкуренция за внимание потребителя достигла пика, дизайн становится мощным инструментом для успеха бренда. Это не просто красивый внешний вид продукта или сайта — это. . .	Модель микоризы: классовый агентный подход 3 anaschu 06.01.2026 aa0a7f55b50dd51c5ec569d2d10c54f6/ O1rJuneU_ls https:/ / vkvideo. ru/ video-115721503_456239114	Owen Logic: О недопустимости использования связки «аналоговый ПИД» + RegKZR ФедосеевПавел 06.01.2026 Owen Logic: О недопустимости использования связки «аналоговый ПИД» + RegKZR ВВЕДЕНИЕ Введу сокращения: аналоговый ПИД — ПИД регулятор с управляющим выходом в виде числа в диапазоне от 0% до. . .	Модель микоризы: классовый агентный подход 2 anaschu 06.01.2026 репозиторий https:/ / github. com/ shumilovas/ fungi ветка по-частям. коммит Create переделка под биомассу. txt вход sc, но sm считается внутри мицелия. кстати, обьем тоже должен там считаться. . . .
Расчёт токов в цепи постоянного тока igorrr37 05.01.2026 / * Дана цепь постоянного тока с сопротивлениями и напряжениями. Надо найти токи в ветвях. Программа составляет систему уравнений по 1 и 2 законам Кирхгофа и решает её. Последовательность действий:. . .	Новый CodeBlocs. Версия 25.03 palva 04.01.2026 Оказывается, недавно вышла новая версия CodeBlocks за номером 25. 03. Когда-то давно я возился с только что вышедшей тогда версией 20. 03. С тех пор я давно снёс всё с компьютера и забыл. Теперь. . .	Модель микоризы: классовый агентный подход anaschu 02.01.2026 Раньше это было два гриба и бактерия. Теперь три гриба, растение. И на уровне агентов добавится между грибами или бактериями взаимодействий. До того я пробовал подход через многомерные массивы,. . .	Советы по крайней бережливости. Внимание, это ОЧЕНЬ длинный пост. Programma_Boinc 28.12.2025 Советы по крайней бережливости. Внимание, это ОЧЕНЬ длинный пост. Налог на собак: https:/ / ********/ gallery/ V06K53e Финансовый отчет в Excel: https:/ / ********/ gallery/ bKBkQFf Пост отсюда. . .